User:Hjart/SPARQL queries

Emner der er menneske/flertydig side edit

SELECT ?menneske ?menneskeLabel WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
   ?menneske wdt:P31 wd:Q5.
   ?menneske wdt:P31 wd:Q4167410.
 }

Try it!

danske byer med mere end 1 sæt koordinater med samme rang edit

SELECT ?item ?itemLabel ?coord1 ?coord2 ?distance ?rank1 ?rank2 WITH {
SELECT DISTINCT ?item ?coord1 ?coord2 ?rank1 ?rank2 WHERE {
    ?item wdt:P17 wd:Q35 . # in Denmark
    ?item wdt:P31/wdt:P279* wd:Q486972 . # settlement
    hint:Prior hint:gearing "forward".
    ?item p:P625 ?stat1 . ?stat1 ps:P625 ?coord1 . ?stat1 wikibase:rank ?rank1 . 
    ?item p:P625 ?stat2 . ?stat2 ps:P625 ?coord2 . ?stat2 wikibase:rank ?rank2 . 
    filter ( str(?stat1)  < str(?stat2) ) . # not the same
    filter ( str(?rank1)  = str(?rank2) ) . # are the same
} 
} AS %if WHERE {
  include %if
  BIND(geof:distance(?coord1, ?coord2) as ?distance)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en,[AUTO_LANGUAGE]". }
}
ORDER BY ?itemLabel

Try it!

gader i Kbh med koordinatpræcision over 0.005 edit

SELECT ?item ?itemLabel ?coord ?geoprecision WHERE {
  ?item wdt:P31 wd:Q79007 .
  ?item wdt:P131 wd:Q504125 .
  ?item p:P625 ?p625 .
  ?p625 ps:P625 ?coord .
  ?p625 psv:P625
  [ wikibase:geoPrecision ?geoprecision ]
  FILTER(?geoprecision>0.005)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
  }
ORDER BY DESC (?geoprecision)

Try it!

Danske statsborgere uden dansk etiket edit

SELECT ?item ?itemLabel WHERE {  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,fr,nb,sv,es,it". }
  FILTER(NOT EXISTS {
    ?item rdfs:label ?lang_label.
    FILTER((LANG(?lang_label)) = "da")
  })
  ?item wdt:P27 wd:Q35.
}
ORDER BY (?itemLabel)

Try it!

personer i DBL uden statsborgerskab edit

SELECT ?menneske ?menneskeLabel ?menneskeDescription WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
   ?menneske wdt:P31 wd:Q5;
     wdt:P8341 ?Dansk_Biografisk_Leksikon_ID.
   MINUS { ?menneske wdt:P27 ?statsborgerskab.
 } } LIMIT 10000

Try it!

Personer i gravsted.dk edit

SELECT ?afdød ?afdødLabel ?afdødDescription ?gravsted_dk_person ?fødselsdato ?dødsdato WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
  ?afdød wdt:P4359 ?gravsted_dk_person.
  OPTIONAL { ?afdød wdt:P569 ?fødselsdato. }
  OPTIONAL { ?afdød wdt:P570 ?dødsdato. }
}

Try it!

danske fortidsminder med artikler på tysk wikipedia edit

SELECT ?fortidsminde ?fortidsmindeLabel ?fortidsmindeDescription ?article ?type ?geografiske_koordinater ?billede WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
   ?fortidsminde wdt:P3596 ?Fund_og_Fortidsminder_ID.
   ?article schema:about ?fortidsminde;
     schema:isPartOf <https://de.wikipedia.org/>.
   OPTIONAL { ?fortidsminde wdt:P31 ?type }
   OPTIONAL { ?fortidsminde wdt:P625 ?geografiske_koordinater. }
   OPTIONAL { ?fortidsminde wdt:P18 ?billede. }

Try it!

}

ting i Kbh med et fbb-sagsnr edit

SELECT ?Københavns_Kommune ?Københavns_KommuneLabel ?Fredede_bygningers_sagsnummer WHERE {
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
 ?Københavns_Kommune wdt:P131 wd:Q504125;
 wdt:P2783 ?Fredede_bygningers_sagsnummer. }
LIMIT 1000

Try it!

danske kirker uden billede edit

SELECT ?kirke ?kirkeLabel ?billede ?geografiske_koordinater WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
   ?kirke wdt:P31 wd:Q16970.
   ?kirke wdt:P17 wd:Q35.
   MINUS { ?kirke wdt:P18 ?billede. }
   OPTIONAL { ?kirke wdt:P625 ?geografiske_koordinater. }
 }
 LIMIT 10000
#defaultView:Map

Try it!

Tidligere jernbanestationer i DK med commonshenvisning, men intet billede (P18) edit

SELECT ?Danmark ?DanmarkLabel ?DanmarkDescription ?article ?billede WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
   ?Danmark wdt:P17 wd:Q35;
     wdt:P31 wd:Q4663385.
   ?article schema:about ?Danmark;
     schema:isPartOf <https://commons.wikimedia.org/>.
   MINUS { ?Danmark wdt:P18 ?billede. }
  }

Try it!

Modtagere af Eckersbergmedaljen edit

SELECT ?Eckersbergmedaljen ?EckersbergmedaljenLabel ?EckersbergmedaljenDescription ?tidspunkt WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da". }
  ?Eckersbergmedaljen wdt:P31 wd:Q5.
  ?Eckersbergmedaljen p:P166 ?statement.
  ?statement ps:P166 wd:Q3352524;
    pq:P585 ?tidspunkt.
}
ORDER BY (?tidspunkt)

Try it!

lister over mennesker med qualifier dødsdato - med præcision år/måned edit

SELECT ?item ?itemLabel ?tidspunkt
 (IF(?præc = 9, "år",
     IF(?præc = 10, "måned", "andet")
     ) AS ?præcision)
WHERE
{
  ?item p:P360 ?statement .
  ?statement ps:P360 wd:Q5 .
  ?statement pqv:P570 ?tidspunkt_v .
  ?tidspunkt_v wikibase:timeValue ?tidspunkt .
  ?tidspunkt_v wikibase:timePrecision ?præc .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en" . }
}

Try it!

kategorier for mennesker med qualifier dødsårsag edit

SELECT ?kategori ?kategoriLabel ?dødsårsagLabel WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "da,en". }
   ?kategori p:P4224 ?statement.
   ?statement ps:P4224 wd:Q5.
   ?statement pq:P509 ?dødsårsag .
 }

Try it!

Bebyggelser i Norge med kommuner uden sluttidspunkt edit

SELECT ?bebyggelse ?bebyggelseLabel ?bebyggelseDescription ?beliggende_i_det_administrative_områdeLabel WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
    ?bebyggelse wdt:P31 wd:Q486972;
      wdt:P17 wd:Q20.  ?bebyggelse p:P131 ?udsagn .
   ?udsagn ps:P131 ?beliggende_i_det_administrative_område .
   ?udsagn rdf:type wikibase:BestRank . # Brug kun udsagn med bedste rangering (samme som ved brug af wdt: præfix)
   OPTIONAL { ?udsagn pq:P582 ?sluttidspunkt }
   FILTER (! BOUND(?sluttidspunkt)) # Fjern resultater med et sluttidspunkt for P131  }

Try it!

Norske steder med SSB landsbynummer med kommuner uden sluttidspunkt edit

SELECT ?bebyggelse ?bebyggelseLabel ?bebyggelseDescription ?beliggende_i_det_administrative_områdeLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  ?bebyggelse wdt:P3992 ?SSB_landsbynummer.
  ?bebyggelse p:P131 ?udsagn.
   ?udsagn ps:P131 ?beliggende_i_det_administrative_område .
   ?udsagn rdf:type wikibase:BestRank . # Brug kun udsagn med bedste rangering (samme som ved brug af wdt: præfix)
   OPTIONAL { ?udsagn pq:P582 ?sluttidspunkt }
   FILTER (! BOUND(?sluttidspunkt)) # Fjern resultater med et sluttidspunkt for P131
}

Try it!

Engelske demonymer "Danish .." for diverse lande edit

SELECT ?land ?landLabel ?demonym WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   ?land wdt:P31 wd:Q6256.
   OPTIONAL { ?land wdt:P1549 ?demonym. FILTER (LANG(?demonym) = "en") }
 }

Try it!

Danske sognes koordinater farvelagt per stift edit

#defaultView:Map
SELECT ?item ?etikett_da ?coord ?layer {
  ?item wdt:P31 wd:Q814648; wdt:P625 ?coord; wdt:P708 [ rdfs:label ?layer ]; rdfs:label ?etikett_da . 
   FILTER(LANG(?etikett_da)='da' && LANG(?layer)='da') 
 }

Try it!

Skibsnavnskategorier + Commonskategorier edit

SELECT ?Wikimedia_kategori ?Wikimedia_kategoriLabel ?article WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   ?Wikimedia_kategori wdt:P31 wd:Q4167836.
   ?Wikimedia_kategori wdt:P971 wd:Q56351075.
    ?article schema:about ?Wikimedia_kategori;
      schema:isPartOf <https://commons.wikimedia.org/>.
   }

Try it!

"kategorien kombinerer emnerne"=skibsnavn uden Wikimedia-kategori edit

SELECT ?skibsnavn ?skibsnavnLabel WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   ?skibsnavn wdt:P971 wd:Q56351075.
   MINUS { ?skibsnavn wdt:P31 wd:Q4167836.}
 }

Try it!

Emner med kategori_for_skibsnavn, men uden IMO nummer edit

SELECT ?ship ?shipLabel ?article WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   ?ship wdt:P7782 ?kategori_for_skibsnavn.
    ?article schema:about ?ship;
      schema:isPartOf <https://commons.wikimedia.org/>.
   MINUS { ?ship wdt:P458 ?IMO_skibsnummer. }
 }

Try it!

Emner med kategori_for_skibsnavn, men uden ibrugtaget edit

SELECT ?ship ?shipLabel ?shipDescription ?kategori_for_skibsnavnLabel WHERE {
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   ?ship wdt:P7782 ?kategori_for_skibsnavn. 
  MINUS { ?ship wdt:P729 ?ibrugtaget. }
 }

Try it!

Emner med kategori_for_skibsnavn og underklasse edit

SELECT ?ship ?shipLabel ?shipDescription ?kategori_for_skibsnavnLabel ?underklasse_tilLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  ?ship wdt:P7782 ?kategori_for_skibsnavn.
  ?ship wdt:P279 ?underklasse_til.
}

Try it!

Skibsemner med IMO nummer og evt. kategori_for_skibsnavn edit

SELECT ?skib ?skibLabel ?skibDescription ?IMO_skibsnummer ?kategori_for_skibsnavnLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  ?skib wdt:P458 ?IMO_skibsnummer.
  MINUS { ?skib wdt:P31 wd:Q4167836. }
  OPTIONAL { ?skib wdt:P7782 ?kategori_for_skibsnavn. }
}

Try it!

Skibsemner med IMO nummer, ibrugtaget og tilfælde af edit

SELECT ?skib ?skibLabel ?skibDescription ?IMO_skibsnummer ?kategori_for_skibsnavnLabel ?ibrugtaget ?tilfælde_af ?tilfælde_afLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  ?skib wdt:P458 ?IMO_skibsnummer;
    wdt:P7782 ?kategori_for_skibsnavn.
  ?skib wdt:P729 ?ibrugtaget. 
  ?skib wdt:P31 ?tilfælde_af.
}

Try it!