User:PAC2/Tour de France

List of stages in 2021 Tour de France (Q61778309) edit

The following query uses these:

Items: 2021 Tour de France (Q61778309)

Properties: part of (P361)   , start point (P1427)   , destination point (P1444)   , point in time (P585)  
```
#title: List of all stages
SELECT * WHERE {
  ?item wdt:P361 wd:Q61778309;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P1427 ?depart.
  ?depart rdfs:label ?departLabel.
  FILTER((LANG(?departLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P1444 ?arrivee. 
  ?arrivee rdfs:label ?arriveeLabel. 
  FILTER((LANG(?arriveeLabel)) = "[AUTO_LANGUAGE]" )
  ?item wdt:P585 ?date. 
}
ORDER BY ?date
```

List of all stages

List of all stage winners in 2021 Tour de France (Q61778309) edit

The following query uses these:

Items: 2021 Tour de France (Q61778309)   , stage winner (Q20882747)

Properties: part of (P361)   , point in time (P585)   , country of citizenship (P27)   , winner (P1346)   , of (P642)  
```
#title: List of all winners
SELECT ?item ?itemLabel ?date ?winner ?winnerLabel ?country ?countryLabel WHERE {
  ?item wdt:P361 wd:Q61778309;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P585 ?date. 
  ?item p:P1346 ?statement.
  ?statement ps:P1346 ?winner.
  ?statement pq:P642 wd:Q20882747 .
  ?winner rdfs:label ?winnerLabel.
  FILTER((LANG(?winnerLabel)) = "[AUTO_LANGUAGE]" )
  ?winner wdt:P27 ?country.
  ?country rdfs:label ?countryLabel.
  FILTER((LANG(?countryLabel)) = "[AUTO_LANGUAGE]" )

}
ORDER BY ?date
```

List of all winners

List of stage winners by country edit

The following query uses these:

Items: 2021 Tour de France (Q61778309)   , stage winner (Q20882747)

Properties: part of (P361)   , point in time (P585)   , country of citizenship (P27)   , winner (P1346)   , of (P642)  
```
#title: List of all stage winners by country
SELECT  ?country ?countryLabel (COUNT(*) as ?count) WHERE {
  ?item wdt:P361 wd:Q61778309;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P585 ?date. 
  ?item p:P1346 ?statement.
  ?statement ps:P1346 ?winner.
  ?statement pq:P642 wd:Q20882747 .
  ?winner rdfs:label ?winnerLabel.
  FILTER((LANG(?winnerLabel)) = "[AUTO_LANGUAGE]" )
  ?winner wdt:P27 ?country.
  ?country rdfs:label ?countryLabel.
  FILTER((LANG(?countryLabel)) = "[AUTO_LANGUAGE]" )

}
GROUP BY ?country ?countryLabel
ORDER BY DESC(?count)
```

List of all stage winners by country

List of all stages of all tours de France edit

The following query uses these:

Items: Tour de France (Q33881)

Properties: instance of (P31)   , part of (P361)   , start point (P1427)   , destination point (P1444)   , point in time (P585)  
```
#title: List of all stages
SELECT * WHERE {
  ?tour wdt:P31 wd:Q33881;
        rdfs:label ?tourLabel.
  FILTER(LANG(?tourLabel) = "[AUTO_LANGUAGE]" )
 ?item wdt:P361 ?tour;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P1427 ?depart.
  ?depart rdfs:label ?departLabel.
  FILTER((LANG(?departLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P1444 ?arrivee. 
  ?arrivee rdfs:label ?arriveeLabel. 
  FILTER((LANG(?arriveeLabel)) = "[AUTO_LANGUAGE]" )
  ?item wdt:P585 ?date. 
}
ORDER BY ?date
```

List of all stages

List of all stage winners of all tours de France edit

The following query uses these:

Items: Tour de France (Q33881)   , stage winner (Q20882747)

Properties: instance of (P31)   , part of (P361)   , point in time (P585)   , country of citizenship (P27)   , winner (P1346)   , of (P642)  
```
#title: List of all stage winners
SELECT ?tour ?tourLabel ?item ?itemLabel ?date ?winner ?winnerLabel ?country ?countryLabel WHERE {
  ?tour wdt:P31 wd:Q33881;
        rdfs:label ?tourLabel.
  FILTER(LANG(?tourLabel) = "[AUTO_LANGUAGE]" )
 ?item wdt:P361 ?tour;
    rdfs:label ?itemLabel.
  FILTER(LANG(?itemLabel) = "[AUTO_LANGUAGE]" )
  ?item wdt:P585 ?date. 
  ?item p:P1346 ?statement.
  ?statement ps:P1346 ?winner.
  ?statement pq:P642 wd:Q20882747 .
  ?winner rdfs:label ?winnerLabel.
  FILTER((LANG(?winnerLabel)) = "[AUTO_LANGUAGE]" )
  ?winner wdt:P27 ?country.
  ?country rdfs:label ?countryLabel.
  FILTER((LANG(?countryLabel)) = "[AUTO_LANGUAGE]" ) 
}
ORDER BY ?date
```

List of all stage winners

Number of stages winners by country and by tour edit

The following query uses these:

Items: Tour de France (Q33881)   , stage winner (Q20882747)

Properties: instance of (P31)   , part of (P361)   , point in time (P585)   , country of citizenship (P27)   , winner (P1346)   , of (P642)  
```
#title: List of all stage winners by country
SELECT ?tour ?tourLabel ?country ?countryLabel (COUNT(*) AS ?count) WHERE {
  ?tour wdt:P31 wd:Q33881;
        rdfs:label ?tourLabel.
  FILTER(LANG(?tourLabel) = "[AUTO_LANGUAGE]" )
 ?item wdt:P361 ?tour;
    rdfs:label ?itemLabel.
  FILTER(LANG(?itemLabel) = "[AUTO_LANGUAGE]" )
  ?item wdt:P585 ?date. 
  ?item p:P1346 ?statement.
  ?statement ps:P1346 ?winner.
  ?statement pq:P642 wd:Q20882747 .
  ?winner rdfs:label ?winnerLabel.
  FILTER((LANG(?winnerLabel)) = "[AUTO_LANGUAGE]" )
  ?winner wdt:P27 ?country.
  ?country rdfs:label ?countryLabel.
  FILTER((LANG(?countryLabel)) = "[AUTO_LANGUAGE]" ) 
}
GROUP BY ?tour ?tourLabel ?country ?countryLabel
ORDER BY DESC(?count)
```

List of all stage winners by country

List of all stage winners by number of win edit

The following query uses these:

Items: Tour de France (Q33881)   , stage winner (Q20882747)

Properties: instance of (P31)   , part of (P361)   , point in time (P585)   , country of citizenship (P27)   , winner (P1346)   , of (P642)  
```
#title: List of all stage winners by country
SELECT ?winner ?winnerLabel (COUNT(*) AS ?count) WHERE {
  ?tour wdt:P31 wd:Q33881;
        rdfs:label ?tourLabel.
  FILTER(LANG(?tourLabel) = "[AUTO_LANGUAGE]" )
 ?item wdt:P361 ?tour;
    rdfs:label ?itemLabel.
  FILTER(LANG(?itemLabel) = "[AUTO_LANGUAGE]" )
  ?item wdt:P585 ?date. 
  ?item p:P1346 ?statement.
  ?statement ps:P1346 ?winner.
  ?statement pq:P642 wd:Q20882747 .
  ?winner rdfs:label ?winnerLabel.
  FILTER((LANG(?winnerLabel)) = "[AUTO_LANGUAGE]" )
  ?winner wdt:P27 ?country.
  ?country rdfs:label ?countryLabel.
  FILTER((LANG(?countryLabel)) = "[AUTO_LANGUAGE]" ) 
}
GROUP BY ?winner ?winnerLabel
ORDER BY DESC(?count)
```

List of all stage winners by country

List of stages won by Tour de France (Q33881) edit

The following query uses these:

Items: Tour de France (Q33881)   , Mark Cavendish (Q207713)   , stage winner (Q20882747)

Properties: instance of (P31)   , part of (P361)   , point in time (P585)   , winner (P1346)   , of (P642)  
```
#title: List of satge winners, ordered by number of wins
SELECT ?tour ?tourLabel ?item ?itemLabel ?date WHERE {
  ?tour wdt:P31 wd:Q33881;
    rdfs:label ?tourLabel.
  FILTER((LANG(?tourLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P361 ?tour;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "[AUTO_LANGUAGE]")
  ?item wdt:P585 ?date;
    p:P1346 ?statement.
  ?statement ps:P1346 wd:Q207713;
    pq:P642 wd:Q20882747.
}
ORDER BY ?date
```

List of satge winners, ordered by number of wins

List of stage winners with links to their list of wins edit

The following query uses these:

Items: Tour de France (Q33881)   , stage winner (Q20882747)

Properties: instance of (P31)   , part of (P361)   , point in time (P585)   , winner (P1346)   , of (P642)  
```
#title: List of all stage winners by number of wins
SELECT ?winner ?winnerLabel (COUNT(*) AS ?count) ?wins WHERE {
  ?tour wdt:P31 wd:Q33881;
        rdfs:label ?tourLabel.
  FILTER(LANG(?tourLabel) = "[AUTO_LANGUAGE]" )
 ?item wdt:P361 ?tour;
    rdfs:label ?itemLabel.
  FILTER(LANG(?itemLabel) = "[AUTO_LANGUAGE]" )
  ?item wdt:P585 ?date. 
  ?item p:P1346 ?statement.
  ?statement ps:P1346 ?winner.
  ?statement pq:P642 wd:Q20882747 .
  ?winner rdfs:label ?winnerLabel.
  FILTER((LANG(?winnerLabel)) = "[AUTO_LANGUAGE]" )
  BIND(
    URI(
      CONCAT(
        "https://query.wikidata.org/embed.html#%23title%3A%20List%20of%20satge%20winners%2C%20ordered%20by%20number%20of%20wins%0ASELECT%20%3Ftour%20%3FtourLabel%20%3Fitem%20%3FitemLabel%20%3Fdate%20WHERE%20%7B%0A%20%20%3Ftour%20wdt%3AP31%20wd%3AQ33881%3B%0A%20%20%20%20rdfs%3Alabel%20%3FtourLabel.%0A%20%20FILTER%28%28LANG%28%3FtourLabel%29%29%20%3D%20%22%5BAUTO_LANGUAGE%5D%22%29%0A%20%20%3Fitem%20wdt%3AP361%20%3Ftour%3B%0A%20%20%20%20rdfs%3Alabel%20%3FitemLabel.%0A%20%20FILTER%28%28LANG%28%3FitemLabel%29%29%20%3D%20%22%5BAUTO_LANGUAGE%5D%22%29%0A%20%20%3Fitem%20wdt%3AP585%20%3Fdate%3B%0A%20%20%20%20p%3AP1346%20%3Fstatement.%0A%20%20%3Fstatement%20ps%3AP1346%20wd%3A",
        SUBSTR(STR(?winner),32), 
        "%3B%0A%20%20%20%20pq%3AP642%20wd%3AQ20882747.%0A%7D%0AORDER%20BY%20%3Fdate"
        )
    ) AS ?wins)
}
GROUP BY ?winner ?winnerLabel ?wins
ORDER BY DESC(?count)
```

List of all stage winners by number of wins