TweetsFactsAndQueries

Welcome to Wikidata, WikidataFacts!

Wikidata is a free knowledge base that you can edit! It can be read and edited by humans and machines alike and you can go to any item page now and add to this ever-growing database!

Need some help getting started? Here are some pages you can familiarize yourself with:

• Introduction – An introduction to the project.
• Wikidata tours – Interactive tutorials to show you how Wikidata works.
• Community portal – The portal for community members.
• User options – including the 'Babel' extension, to set your language preferences.
• Contents – The main help page for editing and using the site.
• Project chat – Discussions about the project.
• Tools – A collection of user-developed tools to allow for easier completion of some tasks.

Please remember to sign your messages on talk pages by typing four tildes (~~~~); this will automatically insert your username and the date.

If you have any questions, please ask me on my talk page. If you want to try out editing, you can use the sandbox to try. Once again, welcome, and I hope you quickly feel comfortable here, and become an active editor for Wikidata.

Best regards! H^akan·IST 19:54, 14 May 2016 (UTC)

talk talk talk

Share your experience in this survey

Hi V7p6s3f2yhzy2br3,

A couple of weeks ago, we invited you to take the Community Insights Survey. It is the Wikimedia Foundation’s annual survey of our global communities. We want to learn how well we support your work on wiki. We are 10% towards our goal for participation. If you have not already taken the survey, you can help us reach our goal! Your voice matters to us.

Please take 15 to 25 minutes to give your feedback through this survey. It is available in various languages.

This survey is hosted by a third-party and governed by this privacy statement (in English).

Find more information about this project. Email us if you have any questions, or if you don't want to receive future messages about taking this survey.

Sincerely,

RMaung (WMF) 19:50, 20 September 2019 (UTC)

Share your experience in this survey

Hi V70czxktjx0haujj,

The Wikimedia Foundation is asking for your feedback in a survey about your experience with Wikidata and Wikimedia. The purpose of this survey is to learn how well the Foundation is supporting your work on wiki and how we can change or improve things in the future. The opinions you share will directly affect the current and future work of the Wikimedia Foundation.

Please take 15 to 25 minutes to give your feedback through this survey. It is available in various languages.

This survey is hosted by a third-party and governed by this privacy statement (in English).

Find more information about this project. Email us if you have any questions, or if you don't want to receive future messages about taking this survey.

Sincerely,

RMaung (WMF) 16:21, 9 September 2019 (UTC)

Hallo, ich bräuchte nochmal deine Hilfe: Ich würde gerne alle P709 mit einer End time finden. die P709 finde ich schon mit https://query.wikidata.org/#PREFIX%20xsd%3A%20%3Chttp%3A%2F%2Fwww.w3.org%2F2001%2FXMLSchema%23%3E%0A%0ASELECT%20DISTINCT%20%3Fitem%20%3FitemLabel%20%3Flb_num%20WHERE%20%7B%0A%20%20%3Fitem%20wdt%3AP31%20wd%3AQ811979.%0A%20%20%3Fitem%20wdt%3AP709%20%3Flb_num.%0A%0A%20%20SERVICE%20wikibase%3Alabel%20%7B%20bd%3AserviceParam%20wikibase%3Alanguage%20%22en%22.%20%7D%0A%0A%7D aber wie geht es da weiter? ~~~~↓

SELECT DISTINCT ?item ?itemLabel ?lb_num ?endTime WHERE {
  ?item wdt:P31 wd:Q811979.
  ?item p:P709 [
    ps:P709 ?lb_num;
    pq:P582 ?endTime
  ].
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Das sind jetzt nur noch Statements mit end time (P582) – wenn du auch andere Statements haben willst, die end time (P582) also nur optionale Zusatzinformation sein soll, sag Bescheid.

Vielen Dank, das war das was ich noch nicht verstanden habe. Jetzt habe ich nur noch das allgemeine Problem das nicht alle Elemente die richtigen "instance of" haben. Aber das ist eine andere Baustelle.

Hey :) I saw this tweet earlier and immediately wondered if we could make a similar map with a query. I also thought it sounded like the sort of query you'd like.

It seems we have links to country outlines and most flags have statements about colours, so it should be possible. So far I have

#defaultView:Map
select * {
  ?item wdt:P297 ?iso ;
        wdt:P163 ?flag ;
        wdt:P3896 ?geoshape .
  optional { ?flag wdt:P462 ?colour }
<nowiki>}</nowiki>

Try it!

but I'm not sure how to turn it into something that says "has red or blue", "doesn't have red or blue" or "no colour information available".

Here’s my implementation:

#defaultView:Map{"hide": ["?geoshape", "?rgb", "?layer"]}
SELECT DISTINCT ?item ?iso ?geoshape ?rgb ?layer WHERE {
  ?item wdt:P297 ?iso;
        wdt:P163 ?flag;
        wdt:P3896 ?geoshape.
  OPTIONAL {
    ?flag wdt:P462 ?color.
    BIND(true AS ?hasColor_)
  }
  BIND(COALESCE(?hasColor_, false) AS ?hasColor)
  OPTIONAL {
    ?flag wdt:P462/wdt:P279* wd:Q3142.
    BIND(true AS ?hasRed_)
  }
  BIND(COALESCE(?hasRed_, false) AS ?hasRed)
  OPTIONAL {
    ?flag wdt:P462/wdt:P279* wd:Q1088.
    BIND(true AS ?hasBlue_)
  }
  BIND(COALESCE(?hasBlue_, false) AS ?hasBlue)
  BIND(?hasRed|| ?hasBlue AS ?hasRedOrBlue)
  BIND(IF(?hasColor, IF(?hasRedOrBlue, "FF00FF", "33FF33"), "777777") AS ?rgb)
  BIND(IF(?hasColor, IF(?hasRedOrBlue, "has red or blue"@en, "does not have red or blue"@en), "no flag color information avaliable"@en) AS ?layer)
}

Try it!

It could be abbreviated a bit with BIND(EXISTS … AS ?hasRedOrBlue) if it weren’t for phabricator:T173243.

Fun fact: New Caledonia (Q33788) has two flags, and currently, flag of New Caledonia (Q693569) has no color statements, so the country is included twice in the query results.

Awesome, thanks! :D You have a typo in the last optional, P279 is lower case so it fails to find the subclasses of blue. With that fixed, our map is almost the same as the one in the tweet. We have the current flag for Mauritania though (which changed since the tweet). We also don't think Bhutan's flag has any blue, which seems to be correct... I can't find any blue on it, at least.

Oh, it just occurred to me that they could be treating the orange is a type of red. I was so busy looking for blue that I forgot about red.

Oops, thank you :) I didn’t look too closely into the differences, I kinda assumed Wikidata’s data might be incomplete :D

And in the tweet Ireland is marked as “flag has no red or blue”, so they can’t be counting orange as a red color.

SELECT ?item ?itemLabel ?bblid
WHERE {  
    ?item wdt:P2580 ?bblid .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }  
    FILTER (REGEX(STR(?bblid), "[\\.q]")) 
}

Try it!

1. NOT before REGEX results in error message, while for FILTER NOT EXISTS it is fine.
2. NOT FILTER results in error message

I would like to add FILTER and REGEX negation to the tutorial. Any idea?

Apart from that, during testing negation it was found that character class negation as describe at https://www.regular-expressions.info/refcharclass.html does not seem to work:

1. FILTER REGEX(STR(?bblid), "[0-9]") results in 4037 items listed
2. FILTER REGEX(STR(?bblid), "[^0-9]") results in 4239 items listed, and lists items where the ID contains [0-9]

The general expression negation operator is the exclamation mark, NOT is just for a few special operators (I think).

SELECT ?item ?itemLabel ?bblid
WHERE {  
    ?item wdt:P2580 ?bblid .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }  
    FILTER(!REGEX(STR(?bblid), "[\\.q]")) 
}

Try it!

The regex "[^0-9]" matches any string that contains at least one character other than 0 to 9, anywhere. To match IDs that do not contain those characters, you need "^[^0-9]*$" (from start to finish, contains only characters other than 0 to 9).

Thanks a lot. So to list values that violate the formatter constraint

[A-Za-z][-.0-9A-Za-z]{1,}

one has to write

FILTER(!REGEX(STR(?bblid), "^[A-Za-z][-.0-9A-Za-z]{1,}$"))

I will think about how to add it to the tutorial and confirm here when done. Thanks a lot!

Copied to https://www.wikidata.org/w/index.php?title=Wikidata:SPARQL_tutorial&diff=715802691&oldid=711088049 - now at least one example for regex is on the page, including negation.

Thanks again! Can be closed here.

A related one, BIND with REGEX on regex-groups, any idea? {{SELECT ?itemLabel ?bbld ?item WHERE {

   ?item wdt:P2580 ?bbld .
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }  
   FILTER (REGEX(STR(?bbld), "-[0-9]{4}-[0-9]{4}$"))
   #BIND year of birth and year of death
   #BIND(REGEX(STR(?bbld), "-([0-9]{4})-[0-9]{4}$") AS ?yob).
   #BIND(REGEX(STR(?bbld), "-[0-9]{4}-([0-9]{4})$") AS ?yod).

} }}

sorry, still struggling with the user interface...:

SELECT  ?item ?itemLabel ?bbld ?yob ?yod
WHERE {  
   ?item wdt:P2580 ?bbld .
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }  
   FILTER (REGEX(STR(?bbld), "-[0-9]{4}-[0-9]{4}$"))
   #BIND year of birth and year of death
   #BIND(REGEX(STR(?bbld), "-([0-9]{4})-[0-9]{4}$") AS ?yob).
   #BIND(REGEX(STR(?bbld), "-[0-9]{4}-([0-9]{4})$") AS ?yod).
}

Try it!

query requested, written, now used on Property talk:P213

ISNI (P213) went up from ~550 000 (2018-06-12) to ~970 000 (2018-06-18). The unique value constraint violations went up from ~340 to 3300. They can help to find duplicates, several have been found. Is it possible to write a SPARQL for Wikidata:Database_reports/Constraint_violations/P213#"Unique_value"_violations Columns: 1 the ISNI 2 item1 3 item1Label 4 item1P569 5 item2 6 item2Label 7 item2P569 It would already help to do it for two items that have the same ISNI or to only show two.

SELECT ?isni ?item1 ?item1Label ?item1DateOfBirth ?item2 ?item2Label ?item2DateOfBirth WITH {
  SELECT * WHERE {
    ?item1 wdt:P213 ?isni;
           wdt:P569 ?item1DateOfBirth.
    ?item2 wdt:P213 ?isni;
           wdt:P569 ?item2DateOfBirth.
    FILTER(STR(?item1) < STR(?item2))
  }
  LIMIT 1000
} AS %results WHERE {
  INCLUDE %results.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

two questions around VALUES

Wikidata:SPARQL_query_service/queries/examples#Simple_Queries

Maybe one can add an example for getting data by QID? I propose Einstein and Bach : Q937, Q1339 and something that normally should have a single value, e.g. P25 mother. SELECT ?item ?itemLabel ?mother ?motherLabel WHERE {

 ?item IN SET {????????}
 OPTIONAL { ?item wdt:P25 ?mother. }
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }

}

I think you’re looking for VALUES:

SELECT ?item ?itemLabel ?mother ?motherLabel WHERE {
  VALUES ?item { wd:Q937 wd:Q1339 }
  OPTIONAL { ?item wdt:P25 ?mother. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Thank you! Added to https://www.wikidata.org/w/index.php?title=Wikidata:SPARQL_tutorial&diff=680894390&oldid=666368722

I would like to add an example for selection by values of a specific property, but get "Query is malformed: Encountered " <PNAME_LN> "wdt:213 "" at line 2, column 16." for:

SELECT ?item ?itemLabel ?mother ?motherLabel ?ISNI WHERE {
  VALUES ?item wdt:213 { "0000 0001 2281 955X" "0000 0001 2276 4157"}
  OPTIONAL { ?item wdt:P25 ?mother. }
  OPTIONAL { ?item wdt:P213 ?ISNI. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

That works like this:

SELECT ?item ?itemLabel ?mother ?motherLabel ?ISNI WHERE {
  VALUES ?ISNI { "0000 0001 2281 955X" "0000 0001 2276 4157" }
  ?item wdt:P213 ?ISNI.
  OPTIONAL { ?item wdt:P25 ?mother. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

You first define the ISNI values you’re interested in and then search for items with those values.

Thanks a lot! Added https://www.wikidata.org/w/index.php?title=Wikidata:SPARQL_tutorial&diff=681170095&oldid=681037853

Query zu sächsischen Kulturdenkmalen

Wie könnte ich eine Einschränkung von [https://www.wikidata.org/w/index.php?title=Wikidata:Project_chat&diff=666634805&oldid=666632324] über Property:P131 erreichen? Dankende, ~~~~.

Du meinst, zum Beispiel nur alle Denkmäler in Mittelsachsen anzeigen? Das ginge so (siehe Zeile 5):

#Liste aller Kulturdenkmale in Sachsen
#defaultView:Map
SELECT ?item ?itemLabel ?itemDescription ?id ?image ?coord WHERE {
  ?item wdt:P1708 ?id;
        wdt:P131+ wd:Q6328;
        wdt:P625 ?coord.
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!

Oder meintest du etwas anderes?

Spitze, das hilft mir erstmal gut weiter. Vielen vielen Dank!

Super, gerne :)

Hallo,

ich bin gerade dabei, mit @Doc Taxon über zu erstellende weibliche Berufsbezeichnungen zu diskutieren. Es gibt ein Property dazu (P2521). In unserem Workshop im November habe ich ja gelernt, die Abfrage zu benutzen :). Der Doc hat mir nun ein Query zur Verfügung gestellt, was allerdings aktuell auch alle Berufsbezeichnungen in nicht-deutschen Sprachen beinhaltet:

Was ich wesentlich lieber hätte, wäre eine Liste von den bereits vorhandenen deutschen Berufsbezeichnungen. Ich poste gleich mal die Abfrage in einer separaten Nachricht, weil ich mir nicht sicher bin, dass die Form 1:1 als Beitrag in einer strukturierten Nachricht einzugeben ist (und weil ich nicht weiß, ob und wie ich die strukturierte Geschichte wieder ausschalten kann, die ich irgendwann mal eingeschaltet hatte)

Gruß ~~~~

Äh - das hat also schon mal nicht geklappt, das zu unterzeichnen mit vier Tilden... :( Gruß IvaBerlin

Hier jetzt erst mal das vom Doc erzeugte Query in der (hoffentlich) richtigen Form:

select distinct ?profession ?professionLabel where {
  values ?pro {wd:Q28640 wd:Q12737077}
  ?profession wdt:P31 ?pro.  
  optional {?profession wdt:P2521 ?female_form_of_label. filter(lang(?female_form_of_label) = 'de')}
  filter(!bound(?female_form_of_label)).
  service wikibase:label {bd:serviceParam wikibase:language "en,ceb,sv,de,fr,nl,ru,it,es,pl,war,vi,ja,zh,pt,uk,sr,fa,ca,ar,no,sh,fi,hu,id,ko,cs,ro,ms,tr,eu,eo,bg,hy,da,zh-min-nan,sk,min,kk,he,lt,hr,et,ce,sl,be,gl,el,nn,az,simple,uz,ur,la,hi,th,vo,ka,ta,cy,tg,mk,tl,mg,oc,lv,ky,bs,tt,sq,new,te,azb,zh-yue,pms,br,be-tarask,ast,bn,ml,jv,ht,lb,mr,sco,af,ga,pnb,is,ba,cv,fy,su,sw,my,lmo,an,yo,ne,nds,pa,gu,io,scn,bar,bpy,als,ku,kn,ckb,ia,qu,arz,mn,bat-smg,gd,wa,nap,si,yi,am,bug,cdo,or,map-bms,fo,mzn,hsb,xmf,mai,li,sah,sa,vec,ilo,os,mrj,hif,mhr,eml,bh,roa-tara,ps,diq,pam,sd,hak,nso,myv,zh-classical,se,bcl,ace,mi,wuu,nah,szl,nds-nl,frr,rue,gan,vls,km,bo,vep,crh,sc,glk,fiu-vro,co,lrc,tk,kv,csb,gv,as,lad,so,zea,nv,udm,ay,lez,stq,ie,kw,nrm,pcd,mwl,ug,rm,koi,ab,gn,gom,lij,mt,fur,dsb,sn,dv,ang,ln,ext,kab,cbk-zam,ksh,frp,lo,gag,dty,pag,olo,pi,av,bxr,pfl,xal,haw,krc,pap,kaa,rw,pdc,bjn,to,ha,nov,kl,arc,jam,kbd,tyv,tpi,tet,ki,ig,na,kbp,roa-rup,lbe,jbo,ty,mdf,za,kg,lg,wo,bi,srn,tcy,zu,chr,ltg,sm,om,xh,rmy,tn,cu,pih,rn,chy,tw,ts,tum,got,st,pnt,ss,bm,ch,fj,atj,ady,iu,ny,ee,ak,ks,ik,ve,sg,ff,dz,ti,cr,din,ng,cho,kj,mh,ho,ii,aa,mus,hz,kr".}
}order by ?profession ?professionLabel

Try it!

(da das jetzt offenbar noch nicht ganz die richtige Form war - gern richtig stellen - ich bin immer gern bereit, dazu zu lernen) :) Gruß Iva

Hi! Ich bin mir noch nicht sicher, welche Query du haben willst… die obige Query findet, wenn ich mich nicht irre, alle Berufe ohne female form of label (P2521) auf Deutsch. Das hier wären Berufe mit female form of label (P2521) auf Deutsch:

SELECT DISTINCT ?profession ?professionLabel ?femaleLabel WHERE {
  VALUES ?class { wd:Q28640 wd:Q12737077 }
  ?profession wdt:P31 ?class;
              wdt:P2521 ?femaleLabel.
  FILTER(LANG(?femaleLabel) = "de")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Try it!

Tja - Du irrst (leider). Da (oben) tauchen besagte 4.480 Berufe auf (keine Ahnung, weshalb die schließende geschweifte Klammer verschütt´ ging). Alle anderssprachigen auch. Und die meisten dieser Sprachen sind mir so fremd, dass ich da wenig Chancen sehe, kurzfristig konstruktiv tätig zu werden. Würde ich aber gern. Wenn ich das von Dir vorgeschlagene ausprobiere (try it), dann stelle ich fest, dass wir immerhin schon knapp 1.500 Datensätze haben, in denen sich ein solches Label findet. Ist doch auch immerhin schon ein Viertel! (Think positive - sprach die Taucherin - und versank... - in Grübeleien, wie es wohl wann weiter gehen wird.)

Sorry, ich verstehe immer noch nicht ganz, welche Query du gerne hättest bzw. was an den bisherigen falsch war. Ich rate nochmal :)

Berufe, die auf Deutsch eine Beschriftung haben:

SELECT DISTINCT ?profession ?professionLabel ?femaleLabel (BOUND(?femaleLabel) AS ?hasFemaleLabel) WHERE {
  VALUES ?class { wd:Q28640 wd:Q12737077 }
  ?profession wdt:P31 ?class;
              rdfs:label ?professionLabel.
  FILTER(LANG(?professionLabel) = "de")
  OPTIONAL {
    ?profession wdt:P2521 ?femaleLabel.
    FILTER(LANG(?femaleLabel) = "de")
  }
}

Try it!

Das sind jetzt 3165 Stück, davon 1427 mit female form of label (P2521) und 1738 ohne. (Du kannst die Tabelle nach der ?hasFemaleLabel-Spalte sortieren, um zuerst Ergebnisse mit oder ohne female form of label (P2521) anzuzeigen.)

Nebenbei bemerkt – dass wir die männliche Bezeichnung für die reguläre Beschriftung verwenden (und sie damit gewissermaßen zum Standard machen) und die weibliche mit female form of label (P2521) nachreichen, ist ohnehin fragwürdig… ich hoffe, sobald wir Unterstützung für lexikographische Daten haben (Wikidata:Lexicographical data), sollte eine bessere Lösung möglich sein.

Äh - sorry - MIR ist (war?;)) ganz klar, WAS ICH wollte ;) - tut mir ECHT Leid, dass ich mich so unklar ausgedrückt habe. Ich wollte einfach "nur" die OHNE female form of label haben. Das mit dem "Sortieren" teste ich dann morgen mal - bin jetzt offenbar zu müde, um das einfach zu "übertragen".

Deine "Nebenbei-Anmerkung" finde ich auch bemerkens-wert. Ich fand heute auch z.B. die Diakonin (weil die im Deutschsprachigen auch einen eigenen Artikel hat, gibt es dazu ein separates Label(?)) und hatte dann festzustellen, dass diese Bezeichnung im Englischen korrekt noch nicht vergeben ist, weil sie falsch verdrahtet ist mit dem englischsprachigen Artikel "Diakonisse", was ja etwas anderes ist. Wo ich dann auch noch dran gehen darf. Bei der Diakonin habe ich jetzt erst mal "alles" nachgetragen, was mir sinnvoll erschien und werde wohl demnächst noch weiteren "Wunderliche Feststellungen" begegnen, wenn ich das richtig einschätze. Ist dann aber auch so.

Okay :) alle Berufe ohne female form of label (P2521) wäre genau Doc Taxons Query. Wenn du das auf Berufe einschränken willst, die eine normale Beschriftung auf Deutsch haben, wäre es eher das hier:

SELECT DISTINCT ?profession ?professionLabel WHERE {
  VALUES ?class { wd:Q28640 wd:Q12737077 }
  ?profession wdt:P31 ?class;
              rdfs:label ?professionLabel.
  FILTER(LANG(?professionLabel) = "de")
  MINUS {
    ?profession wdt:P2521 ?femaleLabel.
    FILTER(LANG(?femaleLabel) = "de")
  }
}

Try it!

Ich bin mir jetzt nicht sicher, ob das sinnvoll ist… es scheint relativ viele Berufe zu geben, die auf Deutsch keine Beschriftung haben, aber viele davon scheinen nicht länderspezifisch zu sein und sollten vielleicht eher mit anderen Items zusammengeführt werden.

Klingt mir nach einem sinnvollen Plan. Der im Prinzip zu dem anderen Abschnitt führt, den ich aufgemacht habe (Doppelungen und der Umgang damit). Erst mal vielen Dank - ich mache damit weiter und melde mich, falls es noch was gibt. Ich bin ja auch weiter mit @Doc Taxon und mit @MB-one in Kontakt - es wird schon weiter gehen - wann und wie auch immer. :)

Hi Iva!

Du brauchst nicht mit vier Tilden zu unterzeichnen, denn Dein Name steht ja über dem Text.

Warum Du diese Abfrage möchtest, erschließt sich mir zwar auch nicht, aber wenn ich das richtig verstehe, wünschst Du Dir die Modifizierung der obigen Abfrage insofern, als dass nur die Ergebnisse gelistet werden sollen, die ein deutschsprachiges ?itemLabel besitzen, richtig?

Liebe Grüße, Doc Taxon ...

Ja, das mit den vier Tilden habe ich inzwischen auch verstanden. Diese neue Form auf den Disk-Seiten ist mir einfach noch SEHR neu ;). Weshalb ich DIESE Abfrage will? Ich dachte, dass ich damit am einfachsten morgen nach meinem Berlinale-Date mal schauen kann, was davon wie zu automatisieren wäre mit einer entsprechenden Excel-Liste - da GAB es mal was, was mir dunkel in Erinnerung ist, was für die Stolpersteine eingesetzt wurde (und werden kann) und ich würde das gern modifiziert für die Frauen in Rot einsetzen und zwar - nachdem Du darum "gebeten" hast, am einfachsten erst mal für besagte weibliche Bezeichnungen. Im (über-?)nächsten Schritt dann auch für die Beschreibungen, um die Länder dort zuzuordnen. Weil doch bei den Beschreibungen sehr oft dabei steht (oder: stehen sollte - je nach Blickwinkel), in welchem Land die Frau ihren Beruf ausübt bzw. wo sie geboren ist (aka: schwedische Politikerin).

Ich mache jetzt mal gleich einen zweiten Abschnitt auf, um das "Ganze" etwas übersichtlicher zu gestalten - wenn Du meinst, dass es hier unzutreffend wäre, kannst Du mich auch gern woanders hin verweisen. Also: habe jetzt einfach mal wieder "try it" gemacht und bin auf die 4. Seite gesprungen (bei 1000 Datensätzen). Dabei habe ich entdeckt, dass es einen Datensatz Mitarbeiter (Q20204892) gibt. Ich war etwas fassungslos und habe ihn mir näher angeschaut. Als ich dann auch noch sah, dass im (bei mir unteren) Bereich mit den Wikipedien keinen Link zur de-WP gab, bin ich misstrauisch geworden und habe mal das Wort in der de-WP gesucht. Und siehe da - auch dort ein Link zu Wiki-Data - allerdings zu einem anderen Objekt (Q1863288) - mit anderen Festlegungen. Und nun? Was würdest Du in so einem(?) Fall empfehlen? Ich wage noch nicht danach zu schauen, wie es bei Wörtern wie "Kollege" aussieht...

PS: Wie hast Du die Labels(?) im Text verlinkt?So wie ich (via Kettensymbol) oder geht das anders besser?

Generell kannst du im Project chat (oder auf der deutschen Version, dem Forum – das lese ich selbst allerdings nie, weiß also nicht, wie genau es da zu geht) nachfragen, wenn du dir nicht sicher bist. In dem Fall würde ich aufgrund der englischen Beschriftungen sagen, dass es sich um unterschiedliche Konzepte handelt – ersteres (Q20204892) würde ich vielleicht eher als „Mitwirkende(r)“ oder „Beitragende(r)“ statt als „Mitarbeiter“ übersetzen. (Bin mir jetzt aber auch nicht sicher genug, um das tatsächlich zu ändern.)

Um Items zu verlinken, gibt es {{Q}} (und {{P}} für Properties).

Ach so, und wenn du den visuellen Editor verwendest, kannst du zwei geschweifte Klammern eingeben ({{), dann kannst du auch da eine Vorlage wie {{Q}} eingeben. Oder mit dem Button in der unteren rechten Ecke in den Wikitext-Modus wechseln und direkt {{Q|Q42}} schreiben.