User:Iwan.Aucamp/WIP/Norway

Example Items

• helsenorge.no (Q19374100)
• Act relating to the admission of foreign nationals into the realm and their stay here (Q12008659)
• Regulations on patient records of Norway (Q91262441)
• Regulations on the Entry of Foreign Nationals Into the Kingdom of Norway and Their Stay in the Realm (Q91264460)
• Dagens Medisin (Q11964506)
• The Norwegian Patient Registry (Q11992500)
• The Norwegian Primary Care Registry (Q91496632)
• Norwegian Surveillance System for Communicable Diseases (Q19381316)

Types

• act of the Parliament of Norway (Q91267389)

SELECT ?item ?itemLabel {
  # instance of (P31) subclass of (P279) Act of the Parliament of Norway (Q91267389)
  ?item wdt:P31 / wdt:P279* wd:Q91267389.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

• regulation of the government of Norway (Q4590880)

SELECT ?item ?itemLabel {
  # instance of (P31) subclass of (P279) Regulation of the Government of Norway (Q4590880)
  ?item wdt:P31 / wdt:P279* wd:Q4590880.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

• Norwegian health registry (Q91500776)

SELECT ?item ?itemLabel {
  # instance of (P31) subclass of (P279) Norwegian Health Register (Q91500776)
  ?item wdt:P31 / wdt:P279* wd:Q91500776.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Queries

subclass of legislative act (itemsubclass of (P279)statute (Q820655)) that applies to jurisdiction Norway (itemapplies to jurisdiction (P1001)Norway (Q20))

SELECT ?item ?itemLabel ?linkTo {
  ?item wdt:P279* wd:Q820655.
  ?item ( wdt:P1001| wdt:P17 ) wd:Q20.
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

instance of company (iteminstance of (P31)company (Q783794)) in country Norway (itemcountry (P17)Norway (Q20))

SELECT ?item ?itemLabel ?linkTo {
  ?item (wdt:P31 / wdt:P279*) wd:Q783794.
  ?item wdt:P17 wd:Q20.
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

subclass of something (?itemsubclass of (P279)type) with country Norway (?itemcountry (P17)Norway (Q20))

SELECT ?item ?itemLabel ?type ?typeLabel {
  ?item wdt:P279 ?type.
  ?item wdt:P17 wd:Q20. 
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

subclass of something (?itemsubclass of (P279)type) linked to Norway (?item?propertyNorway (Q20))

SELECT ?item ?itemLabel ?property ?propertyLabel ?type ?typeLabel {
  ?item wdt:P279 ?type.
  ?item ?prop wd:Q20.
  ?property wikibase:directClaim ?prop.
  MINUS { ?item wdt:P31 / wdt:P279* wd:Q34770 }.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

all laws and regulations applying to Norway

laws

SELECT DISTINCT ?item ?itemLabel ?linkTo {
  VALUES ?lawClasses { wd:Q820655 }.
  ?item wdt:P31 / wdt:P279* ?lawClasses.
  { ?item wdt:P31? / ( wdt:P1001| wdt:P17 ) wd:Q20 }
  UNION
  { ?item (wdt:P31? / wdt:P467) wd:Q109016 }
  # excluding treaties ...
  MINUS { ?item wdt:P31 wd:Q29883540 }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

General

Dictionaries

Dictionaries with language Norwegian

SELECT DISTINCT ?item ?itemNativeLabel ?itemDescription ?accessStatusLabel ?website WHERE {
  ?item wdt:P31 / wdt:P279* wd:Q23622.
  ?item wdt:P407 / wdt:P279* wd:Q9043.
  OPTIONAL { ?item ( wdt:P1705| wdt:P1476 | wdt:P1448 ) ?itemNativeLabel }.
  OPTIONAL { ?item ( wdt:P856 | wdt:P953 ) ?website }.
  ## OPTIONAL { ?item wdt:P407 ?language }.
  OPTIONAL { ?item (wdt:P31 / wdt:P279*)? / wdt:P6954 ?accessStatus }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Online

SELECT DISTINCT ?item ?itemNativeLabel ?itemDescription ?accessStatusLabel ?website WHERE {
  ?item wdt:P31 / wdt:P279* wd:Q23622.
  ?item wdt:P407 / wdt:P279* wd:Q9043.
  ?item wdt:P31 / wdt:P279* wd:Q3327521.
  OPTIONAL { ?item ( wdt:P1705| wdt:P1476 | wdt:P1448 ) ?itemNativeLabel }.
  OPTIONAL { ?item ( wdt:P856 | wdt:P953 ) ?website }.
  ## OPTIONAL { ?item wdt:P407 ?language }.
  OPTIONAL { ?item wdt:P6954 ?accessStatus }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Norwegian language dictionaries

SELECT DISTINCT ?item ?itemNativeLabel ?itemDescription ?accessStatusLabel ?website WHERE {
  ?item wdt:P31 / wdt:P279* wd:Q55623087.
  OPTIONAL { ?item ( wdt:P1705| wdt:P1476 | wdt:P1448 ) ?itemNativeLabel }.
  OPTIONAL { ?item ( wdt:P856 | wdt:P953 ) ?website }.
  OPTIONAL { ?item wdt:P6954 ?accessStatus }.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Business Models

All business models

SELECT DISTINCT ?item ?itemLabel WHERE {
  ?item ( wdt:P31 / wdt:P279* )| ( wdt:P279+ ) wd:Q815823.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!