User:PAC2/Portrait d'un prénom
Ce notebook interface (Q28405706) explore un prénom en prenant pour exemple (Ada (Q346047)).
TL;DR edit
En juin 2020 :
- on compte 354 Ada (Q346047) dont 352 human (Q5) et 2 personnages de fiction.
- Ada Lovelace (Q7259) est la Ada (Q346047) la plus célèbre avec 76 articles Wikipédia
- 60 Ada (Q346047) sont writer (Q36180)
- 54 Ada (Q346047) sont américaines
Combien de personnalités s'appellent Ada (Q346047) ? edit
SELECT (COUNT (?item) as ?count) WHERE {
?item wdt:P735 wd:Q346047.
}
Quelles sont les Ada (Q346047) avec le plus grand nombre d'articles sur Wikipédia liens de sites ? edit
SELECT ?item ?itemLabel (COUNT(?sitelink) AS ?count) WHERE {
?item wdt:P735 wd:Q346047.
?sitelink schema:about ?item.
FILTER (SUBSTR(str(?sitelink), 11, 15) = ".wikipedia.org/") .
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?item ?itemLabel
ORDER BY DESC (?count)
Quelle est la instance of (P31) des Ada ? edit
SELECT ?nature ?natureLabel (COUNT(?item) AS ?count) WHERE {
?item wdt:P735 wd:Q346047;
wdt:P31 ?nature.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?nature ?natureLabel
ORDER BY DESC (?count)
Quel est le sex or gender (P21) des Ada (Q346047)? edit
SELECT ?genre ?genreLabel (COUNT(?item) AS ?count) WHERE {
?item wdt:P735 wd:Q346047;
wdt:P21 ?genre.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?genre ?genreLabel
ORDER BY DESC (?count)
Quelles sont les principales occupations des Ada (Q346047) ? edit
SELECT ?occupation ?occupationLabel (COUNT(?item) AS ?count) WHERE {
?item wdt:P735 wd:Q346047;
wdt:P106 ?occupation.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?occupation ?occupationLabel
ORDER BY DESC (?count)
LIMIT 5
Quelles sont les principales nationalités des Ada (Q346047) ? edit
SELECT ?pays ?paysLabel (COUNT(?item) AS ?count) WHERE {
?item wdt:P735 wd:Q346047;
wdt:P27 ?pays.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?pays ?paysLabel
ORDER BY DESC (?count)
A quoi ressemblent les Ada (Q346047) ? edit
SELECT ?item ?itemLabel ?image WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
?item wdt:P735 wd:Q346047.
OPTIONAL { ?item wdt:P18 ?image. }
}