Wikidata:WikiProject France/Monuments historiques

Bienvenue sur le projet monuments historiques
Welcome to the monuments historiques WikiProject

Un monument historique est un bien mobilier ou immobilier juridiquement protégé pour son intérêt et sa valeur historique.

Un seul et unique élément doit contenir les informations sur la protection au titre des monuments historiques. Ces informations sont stockées à l'aide de heritage designation (P1435) et de Mérimée ID (P380) (pour les bien immobiliers) ou Palissy ID (P481) (pour les bien mobiliers). Dans les cas où la protection s'étend sur plusieurs biens, il faut donc créer un élément chapeau représentant l'ensemble de ces bâtiments (voir l'exemple de Pierre courcoulée and cordon des Druides (Q17984083), regroupant cordon des Druides (Q1132337) et Pierre courcoulée (Q2093334)).

Statistiques edit

Répartition des monuments historiques par type :

Graphs are temporarily unavailable due to technical issues.

See it in Wikidata Query Service

Graphs are temporarily unavailable due to technical issues.

See it in Wikidata Query Service

Participants edit

[+] Add yourself to the list

The participants listed below can be notified using the following template in discussions:
{{Ping project|France}}

Requêtes edit

Requêtes qui devraient être vides en toutes circonstances :

#MH sans identifiant
SELECT DISTINCT ?item ?itemLabel WHERE {
	{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #MH
	OPTIONAL { ?item p:P1435 [ ps:P1435 [] ; pq:P580 ?dateDebut ] . }
	FILTER(year(?dateDebut) < year(now())-2 ) #protégé il y a plus de deux ans
	MINUS { ?item wdt:P380 [] } #sans d'identifiant Mérimée
	MINUS { ?item wdt:P481 [] } #sans d'identifiant Palissy
	MINUS { ?item wdt:P131+ wd:Q33788 } #hors Nouvelle-Calédonie
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

#erreurs de valeurs
SELECT DISTINCT ?item ?itemLabel WHERE {
	{ ?item wdt:P1435 wd:Q916475 . }
	UNION
	{ ?item wdt:P1435 wd:Q916475 . }
	UNION
	{ ?item wdt:P31 wd:Q10387575 . }
	UNION
	{ ?item wdt:P31 wd:Q10387684 . }
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

#Protection MH sans date de début
SELECT DISTINCT ?item ?itemLabel WHERE {
	{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #Protection MH
	MINUS { ?item p:P1435 [ ps:P1435 [] ; pq:P580 ?dateDebut ] . } #Sans date de début
	MINUS { ?item wdt:P131+ wd:Q33788 } #hors Nouvelle-Calédonie
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

#Date de début de protection erronée (inscription avant 1913 ou classement avant 1840)
SELECT DISTINCT ?item ?itemLabel ?dateDebut WHERE {
	{ ?item p:P1435 [ ps:P1435 wd:Q10387575 ; pq:P580 ?dateDebut ] .
	FILTER(year(?dateDebut) < 1913 ) }
	UNION
	{ ?item p:P1435 [ ps:P1435 wd:Q10387684 ; pq:P580 ?dateDebut ] .
	FILTER(year(?dateDebut) < 1840 ) }
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

#MH avec catégorie Commons mais sans image
SELECT DISTINCT ?item ?itemLabel WHERE {
	{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #MH
	?item wdt:P373 [] . #avec catégorie Commons
	MINUS { ?item wdt:P18 [] } #mais sans image
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

#MH dont les coordonnées sont à plus de 10 kilomètres des coordonnées de la localisation en P131
SELECT ?MH ?MHLabel ?coordMH ?coordLoc ?dist WHERE {
 ?MH wdt:P380 [] ; wdt:P625 ?coordMH ; wdt:P131/wdt:P625 ?coordLoc .
 BIND( geof:distance( ?coordLoc , ?coordMH) as ?dist ) .
 FILTER (?dist > 10) .
 SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
} ORDER BY DESC(?dist)

Try it!

#MH construit plus de 25 ans après la mort de l'architecte
SELECT DISTINCT ?item ?itemLabel ?dateConstruction ?dateDeces WHERE {
	{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #MH
	?item wdt:P571 ?dateConstruction ; wdt:P84/wdt:P570 ?dateDeces .
	FILTER(year(?dateConstruction) - year(?dateDeces) > 25)
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

#MH sans coordonnées géographiques
SELECT DISTINCT ?item ?itemLabel WHERE {
	{ ?item wdt:P1435 wd:Q10387575 . } UNION { ?item wdt:P1435 wd:Q10387684 . } #MH
	?item p:P380 [] #immeubles
	MINUS { ?item wdt:P625 [] } #sans coordonnées géographique
	SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" } .
}

Try it!

voir ou modifier cette liste

Outils edit

Compte-rendus de violations :

« identifiant Mérimée » (P380)

« identifiant Palissy » (P481)

Outils externes :

Monumental

Liste de monuments français avec image mais sans catégorie Commons

Voir aussi edit

Wikidata:WikiProject Built heritage • Wikidata:WikiProject Museums

Projet sur Wikipédia • Portail sur Wikipédia • Projet sur Wikisource • Projet sur Wikimedia Commons