Alina data

Babel user information
ru-N Русский — родной язык этого участника. nl-4 Deze gebruiker beheerst het Nederlands als ware het zijn moedertaal. en-4 This user has near native speaker knowledge of English.
Users by language

I have a background in archive management and am engaged in projects related to publishing data and images of visual arts and heritage on different Wikimedia platforms. I work at meemoo, Flemish Institute for Archive. One of our tasks is to support and advise heritage institutions in Flanders, Brussels and Belgium on everything that has to do with digitization of heritage. Making their data and images accessible online for broader public is one of the fields of my specialization.

We encourage the heritage institutions to work more with Wikimedia and make their data and images accessible via different Wikimedia platforms. We initiated projects like "Flemish art collections, Wikidata and Linked Open Data" and help the institutions with the publishing of their data and images.

Wikidata queries that I use for GLAM

Check if creators from a specific collection have a CommonsCreatorPage and CommonsCategory

SELECT DISTINCT ?c ?cLabel ?CommonsCreatorPage ?CommonsCategory WHERE {
  ?p wdt:P195 wd:Q2365880.
  ?p wdt:P170 ?c.
  OPTIONAL {?c wdt:P1472 ?CommonsCreatorPage.}
  OPTIONAL {?c wdt:P373 ?CommonsCategory.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
ORDER BY ?cLabel

Try it!

Check if creators from a specific collection have a Wikipedia article

SELECT DISTINCT ?creator ?creatorLabel ?article WHERE {
  ?p wdt:P195 wd:Q2365880.
  ?p wdt:P170 ?creator.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
   ?article schema:about ?creator; schema:inLanguage ?lang .
}

Try it!

Look up the Wikipedia articles for artworks from a specific collection

Version 1

SELECT ?work ?workLabel ?creatorLabel ?lang ?article  WHERE {
  ?work wdt:P195 wd:Q1471477 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en,fr,uk" . }
  OPTIONAL { ?work wdt:P170 ?creator . }
  ?article schema:about ?work; schema:inLanguage ?lang .
  FILTER(!REGEX(str(?article),'commons'))    #remove this filter if you want to see the commons categories as well
}
ORDER BY ?work ?lang

Try it!

Version 2

SELECT (group_concat(?article;separator=' ; ') as ?articles) (count(?article) as ?count) ?work WHERE {
SELECT ?work ?wp ?article WHERE {
 ?work wdt:P195 wd:Q1471477 .
 ?article schema:about ?work;
          schema:isPartOf ?siteurl .
  
 ?wp wdt:P31 wd:Q10876391. # selects every wikipedia
 ?wp wdt:P856 ?url . 
  bind ( uri(?url) as ?siteurl )
}
} group by ?work order by desc(?count)

Try it!

Version 3

SELECT ?article ?wp ?work WHERE {
 ?work wdt:P195 wd:Q1471477 .
 ?article schema:about ?work;
          schema:isPartOf ?siteurl .
  
 ?wp wdt:P31 wd:Q10876391.       # selects every wikipedia linguistic version
 ?wp wdt:P856 ?url .             # finds their base urls (string datatype)
 bind ( uri(?url) as ?siteurl )  # convert the urls strings to sparql url datatype
}

Try it!

The locations of artworks per creator

SELECT ?work ?workLabel ?location ?locationLabel ?coordinate_location ?inception WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". }
  ?work wdt:P170 wd:Q158840.
  ?work wdt:P276 ?location.
  ?location wdt:P625 ?coordinate_location.
  OPTIONAL { ?work wdt:P571 ?inception. }
  }

Try it!

The AAT and Iconclass ID's for 'depicts' concepts for artworks of KMSKA

SELECT ?Royal_Museum_of_Fine_Arts_Antwerp ?Royal_Museum_of_Fine_Arts_AntwerpLabel ?depicts ?depictsLabel ?AAT_ID ?Iconclass_notation ?inventory_number WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?Royal_Museum_of_Fine_Arts_Antwerp wdt:P195 wd:Q1471477.
  ?Royal_Museum_of_Fine_Arts_Antwerp wdt:P180 ?depicts.
  ?depicts wdt:P1014 ?AAT_ID.
  ?depicts wdt:P1256 ?Iconclass_notation.
  OPTIONAL { ?Royal_Museum_of_Fine_Arts_Antwerp wdt:P217 ?inventory_number. }
}
LIMIT 10000

Try it!

Qualifier reference URL (P854) for inventory number (P217) of artworks of a specific collection

SELECT ?Royal_Museum_of_Fine_Arts_Antwerp ?Royal_Museum_of_Fine_Arts_AntwerpLabel ?inventory_number ?reference_url WHERE {
  ?Royal_Museum_of_Fine_Arts_Antwerp wdt:P195 wd:Q1471477 . 
  ?Royal_Museum_of_Fine_Arts_Antwerp  p:P217 ?statement .
  ?statement ps:P217 ?inventory_number.
  ?statement prov:wasDerivedFrom ?something.
  ?something pr:P854 ?reference_url.  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". }  
}

Try it!

All people that died in a specific year and their occupation

#Selects all people who died in 1948 and shows their occupation
SELECT ?h ?date ?occupation ?occupationLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,nl". }
  ?h wdt:P31 wd:Q5.
  ?h wdt:P570 ?date.
  OPTIONAL { ?h wdt:P106 ?occupation. }
  FILTER(?date < "1949-01-01T00:00:00Z"^^xsd:dateTime)
  FILTER(?date > "1947-12-31T00:00:00Z"^^xsd:dateTime)
}
ORDER BY ?date

Try it!

All artworks from a specific museum with their creator and date of death

#shows al artworks from a specific museum with their creator and his/hers date of death
SELECT DISTINCT ?p ?pLabel ?c ?cLabel ?dod WHERE {
  ?p wdt:P195 wd:Q1471477.
  ?p wdt:P170 ?c.
  ?c wdt:P570 ?dod.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
ORDER BY ?cLabel

Try it!

Collections that have artworks by a specific creator

#shows all collections which have a work by a specific artist
SELECT ?work ?workLabel ?collection ?collectionLabel WHERE {
  ?work wdt:P170 wd:Q2519247.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl". }
  OPTIONAL { ?work wdt:P195 ?collection. }
}

Try it!

An overview of all works in specific collections all over the world by creators that died in a specific year

! beware: this query doesn't show works by creators that have no collection mentioned.
! beware: this query only shows people that are a creator (P170)and doesn't show author (P50) of books or plays.

#Selects all human who died in 1948 and shows 
#their paintings that are part of a collection (with possible coordinates) as well as the possible placement with country and possible image 
SELECT ?deathdate ?person ?personLabel ?work ?workLabel ?objectname ?objectnameLabel ?image ?coll ?collLabel ?collcoord ?collcountryLabel ?placeLabel ?placecountryLabel WHERE {
  VALUES ?year { 1948 }  # add more years like VALUES ?year { 1948 1949 }
  ?person wdt:P31 wd:Q5.
  ?person p:P570/psv:P570 [wikibase:timeValue ?tv; wikibase:timePrecision ?tp] .
  FILTER(year(?tv)=?year)
#truncate the display of dates given with year och month precision
  BIND(IF(?tp=9,substr(?tv,1,4),IF(?tp=10,substr(str(?tv),1,7),substr(str(?tv),1,10))) AS ?deathdate)
  ?work wdt:P170 ?person .
  ?work wdt:P195 ?coll .
  OPTIONAL { ?work wdt:P18 ?image }
  OPTIONAL { ?work wdt:P31 ?objectname }
#  FILTER(!BOUND(?image))  # uncommment this if only paintings without image are wanted
  OPTIONAL { ?coll wdt:P625 ?collcoord }
  OPTIONAL { ?coll wdt:P17 ?collcountry }
  OPTIONAL { ?coll wdt:P276 ?place . OPTIONAL { ?place wdt:P17 ?placecountry } }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,nl,pl,ca". }
}
ORDER BY ?tv ?personLabel ?workLabel

Try it!

Looking up labels for artworks from a collection in a specific language

SELECT ?item ?_inventory_number ?label ?label_it WHERE {
  ?item wdt:P195 wd:Q1471477.
  OPTIONAL { ?item wdt:P217 ?_inventory_number. }
    ?item rdfs:label ?label_it filter (lang(?label_it) = "it").
}

Try it!