Aluxosm

About me This user is a member of WikiProject Space. This user is penguin powered.

Works authored by Merlin Sheldrake

#defaultView:Table

SELECT ?item ?itemLabel ?subjectLabel ?publisherLabel ?date ?doi ?pubmed ?pmcid
WHERE 
{
  ?item wdt:P50 wd:Q89428526.
  OPTIONAL {?item wdt:P921 ?subject.}
  OPTIONAL {?item wdt:P1433 ?publisher.}
  OPTIONAL {?item wdt:P577 ?date.}
  OPTIONAL {?item wdt:P356 ?doi.}
  OPTIONAL {?item wdt:P698 ?pubmed.}
  OPTIONAL {?item wdt:P932 ?pmcid.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?date

Try it!

Breweries that are abbreviated to ABC

#defaultView:Table

SELECT ?item ?itemLabel ?countryLabel ?localityLabel
WHERE
{
  {?item wdt:P31 wd:Q131734}           # Is a brewery
  UNION
  {?item wdt:P31 wd:Q5487333}          # or a microbrewery
  
  ?item skos:altLabel ?alias.          # Get the alias (also known as)
  OPTIONAL {?item wdt:P17 ?country}.   # Get the country
  OPTIONAL {?item wdt:P131 ?locality}. # Get the locality

  FILTER(CONTAINS(?alias, "ABC"@en))   # Check that the alias is 'ABC'
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "[AUTO_LANGUAGE]"
    }
}

ORDER BY ?countryLabel

Try it!

People who have held a position in the Air Training Corps

#defaultView:Table

SELECT ?person ?personLabel ?positionLabel ?start_time ?end_time
WHERE
{
  ?person wdt:P31 wd:Q5 .                                           # human
  ?person p:P39 [ ps:P39 ?position; pq:P642 wd:Q4698217] .          # position held - ? - of - Air Training Corps
  OPTIONAL{?person p:P39 [ ps:P39 ?position; pq:P580 ?start_time]}  # start time
  OPTIONAL{?person p:P39 [ ps:P39 ?position; pq:P582 ?end_time]}    # end time
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}

ORDER BY (?start_time)

Try it!

Frequency of articles published about Younger Dryas

#defaultView:LineChart

SELECT ?year (COUNT (DISTINCT ?a) AS ?count) WHERE {
   ?a wdt:P31 wd:Q13442814 .        # Is a scientific article
   ?a wdt:P921 wd:Q944279 .         # Is mainly about "Younger Dryas"
   ?a wdt:P577 ?date .              # Was published on this date
   BIND(str(year(?date)) AS ?year)  # Only care about the year published
}
GROUP BY ?year 
ORDER BY ?year

Try it!

Classification of sound recording devices

Classification of the class sound recording device (Q66087652)   

For help about classification, see Wikidata:Classification.

Parent classes (classes of items which contain this one item)

• sound recording device
  • audio equipment
    • device
      • artificial entity
        • object
          • entity ⊸

Subclasses (classes which contain special kinds of items of this class)

⟨sound recording device⟩ on wikidata tree visualisation (external tool)(depth=1)

List of subclasses

List of direct subclasses

Miga external tool (does not work in Firefox) — listing of subclasses, number of super and subclasses, properties of the instances

⟨sound recording device⟩ on Miga