User:Beat Estermann/WD-Intro-2020-11-16

Useful Links

• Asaf's Gentle Introduction to Wikidata (Youtube)
• Slide Deck of this Course
• Google Doc mit Anwendungsfällen der beteiligten Institutionen
• Handout: Wikidata in Brief
• Handout: Wikidata Query Service in Brief
• Help:Multilingual
• Wikidata – Project Cultural Heritage
• eCH-0205 – Linked Open Data (Guidelines)
• Wikidata Query Service (SPARQL Endpoint)
• Wikidata Query Service - User Manual
• Vizquery - a tool for making simple queries
• Cradle - a tool to create customized forms to enter data manually
• Histropedia – Wikidata Query Timeline
• Wikidata Ontology Explorer (seems to be partly broken at the moment)
• Werkzeuge für Freiwillige: Von Wikipedia aus verfolgen, was auf Wikidata vor sich geht (Blog Post by Jens Ohlig, 1 June 2018)
• How to Link Your Institution’s Collections to Wikidata? a short manual to a semi-automatic way of using the “archives at” property (P485)

Useful Gadgets

To activate the gadgets, go to the "Gadget" tab in your preferences and tick the corresponding checkbox.

• Gadget "relateditems:" Adds a button to the bottom of item pages to display inverse statements.

Explanatory note: For many items Wikidata has more information than can be seen on the item page. For example on Whitcomb L. Judson Whitcomb L. Judson (Q731876) you see that he is an inventor but you don't see his invention. That's because discoverer or inventor discoverer or inventor (P61) only links from the invention to the inventor and not the other way round. To solve this general problem that statements are only displayed in one way the script adds at the end of all item pages a new button to load inverse statements.

• Gadget "Recoin" ("Relative Completeness Indicator") is a script that extends Wikidata entity pages with information about the relative completeness of the information and provides suggestions for further information to be added to an item.
• There are further Gadgets that facilitate particular tasks when working on Wikidata - check them out!

Tools for (Semi-)Automatic Data Ingests

• OpenRefine / Wikidata Extension
• QuickStatements

Sum of All GLAMs / Referencing Archival Fonds on Wikidata / Graph-based Query Expansion in Library Discovery Systems

• "An International Knowledge Base for All Heritage Institutions" (Giovanna Fontenelle and Beat Estermann, 4-5 July 2019).
• This Month in GLAM, January 2020 edition

Trivia

• Hatnote: Listen to Wikidata!
• Twitter: Wikidatafacts

Examples of Data Use

Examples of data use in the context of Wikipedia

• Centralized inter-wiki links
• Centralized data management for infoboxes
• Centralized data management for lists
• Mbabel Tool - for the creation of draft articles, including infobox and general article structure, populated with data from Wikidata
• Wikimedia CH campaign at the occasion of the International Museums Day 2018

Examples of data use outside Wikipedia/Wikimedia: external applications

• Histropedia
• The Sum of All Knowledge
• Crotos

Let's Practice!

Searching & Editing Wikidata

Complement information about organizations

Search for an organization from the Bern University Library dataset of corporate archives and use "Recoin" (see "Useful Gadgets") to complement the information:

1. Sanitätsgeschäft M. Schaerer A.G.
2. Universität Bern, Theodor-Kocher-Institut; Theodor-Kocher-Institut → Theodor Kocher Institute (Q98635935)
3. Union Schweizerischer Gesellschaften für experimentelle Biolog; Life Sciences Switzerland → Life Sciences Switzerland (Q13416886)
4. Schweizerische Gesellschaft für Medizinische Radiologie
5. Schweiz. Verein für Physiologie, Physiolog. Chemie und Pharmak; Freie Vereinigung schweizerischer Physiologen (1932); Schweiz. Verein der Physiologen und Pharmakologen (1944-55) → Schweizerischer Verein für Physiologie, Physiologie Chemie und Pharmakologie (Q98635715)
6. Ärztlicher Bezirksverein Emmental
7. Ärztlicher Bezirksverein Oberaargau
8. Schweizerische Gesellschaft für Biochemie → Swiss Society for Biochemistry (Q98635570)
9. Institut Für Sozial- und Präventivmedizin der Uni Bern → Institute of Social and Preventive Medicine (Q98635443)
10. Schweizerische Gesellschaft für Oto-Rhino-Laryngologie → Swiss Society for Oto-Rhino-Laryngology (Q98635727)
11. Schweizerische Akademie der Medizinischen Wissenschaften → Swiss Academy of Medical Sciences (Q1287710)
12. Schweizerische Gesellschaft für Chirurgie → Q98635675
13. Bernische Radium-Stiftung
14. Schweizerische Gesellschaft für Allgemeine Medizin → Swiss Society of General Medicine (Q98635549)
15. International Society for Stereology → International Society for Stereology & Image Analysis (Q48796537) (with "archives at" statement)
16. Pharmacie St. Martin Vevey → Pharmacie St. Martin (Q98635459) (with "archives at" statement)

Hint:

• Indicate the website / database where you found the information as the source of your statement (see: Collection database of the Institute of Medical History of the University of Bern (Q98457204)).

Example Queries

Return all books written by J. K. Rowling

• The relevant items and properties are: J. K. Rowling (Q34660), author (P50)

SELECT ?book ?bookLabel
WHERE {
  ?book wdt:P50 wd:Q34660 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}

Try it!

What other information is available about J. K. Rowling books?

• Relevant properties are: publisher(P123), publication Date(P577), award received (P166)

SELECT ?book ?bookLabel ?publisherLabel ?publicationDate ?awardsLabel
WHERE {
  ?book wdt:P50 wd:Q34660 .
  ?book wdt:P123 ?publisher;
        wdt:P577 ?publicationDate;
        wdt:P166 ?awards .

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }              
}

Try it!

What happened to the other books?

• The Optional function is needed so that all entries are kept.

SELECT ?book ?bookLabel ?publisherLabel ?publicationDate ?awardsLabel
WHERE {
  ?book wdt:P50 wd:Q34660 .
  OPTIONAL {?book wdt:P123 ?publisher .}
  OPTIONAL {?book wdt:P577 ?publicationDate .}
  OPTIONAL {?book wdt:P166 ?awards .}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }              
}

Try it!

Things named after French Presidents

#defaultView:Map
SELECT ?truc ?presLabel ?trucLabel ?coord ?layer WHERE {
 {
 SELECT DISTINCT ?truc (SAMPLE(?coord) AS ?coord) (SAMPLE(?layer) AS ?layer) WHERE {
 ?pres wdt:P39 wd:Q191954 ;
 rdfs:label ?layer.
 FILTER((LANG(?layer)) = "fr")
 
 ?truc wdt:P138 ?pres ;
 wdt:P625 ?coord.
 }
 GROUP BY ?truc ?trucLabel
 }
 SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!

Things named after Swiss Federal Councilors

#defaultView:Map
SELECT ?truc ?fcLabel ?trucLabel ?coord ?layer WHERE {
 {
 SELECT DISTINCT ?truc (SAMPLE(?coord) AS ?coord) (SAMPLE(?layer) AS ?layer) WHERE {
 ?fc wdt:P39 wd:Q11811941 ;
 rdfs:label ?layer.
 FILTER((LANG(?layer)) = "fr")
 
 ?truc wdt:P138 ?fc ;
 wdt:P625 ?coord.
 }
 GROUP BY ?truc ?trucLabel
 }
 SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!

Plays by Swiss Playwrights

SELECT DISTINCT ?play ?playLabel ?author ?authorLabel
WHERE {
  ?play wdt:P31/wdt:P279* wd:Q25379 ; 
        wdt:P50 ?author .
  ?author wdt:P27 wd:Q39 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}

Try it!

Plays that Were Performed in Switzerland

SELECT DISTINCT ?play ?playLabel ?author ?premiere ?venueLabel

WHERE {
  ?play wdt:P31/wdt:P279* wd:Q25379 ; 
        wdt:P50 ?author .
  ?production wdt:P31/wdt:P279* wd:Q43099500 ;
              wdt:P144 ?play ;
              wdt:P276 ?venue .
  ?venue wdt:P361*/wdt:P131/wdt:P17 wd:Q39 .
             
  OPTIONAL { ?production wdt:P1191 ?premiere . }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }

}

ORDER BY ?premiere

Try it!

Let's Practice!

Querying & Editing Wikidata

Teilbibliotheken der Universitätsbibliothek Bern

Schreiben Sie eine Abfrage, die alle Teilbibliotheken der Universitätsbibliothek Bern zurückgibt.

SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P361 wd:Q15852122.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!

Hinweis:

• Beziehen Sie folgende Elemente in Ihre Abfrage mit ein: Bild (P18), Gründung (P571), Strassenadresse (P6375), Ort (P276), Koordinaten (P625), die Telefonnummer (P1329), E-Mail-Adresse (P968), die offizielle Website (P856), Schutzkategorie (P1435), ist Teil von (P361) und besteht aus (P527) usw.
• Zeigen Sie die Ergebnisse auf einer Karte an.
• Ändern Sie die Sprache auf Französisch oder Englisch um zu sehen, welche Bezeichnungen in diesen Sprachen fehlen.

Mit Wikidata Lücken in Wikipedia finden

Die folgende Abfrage kann in einem kommenden Wikipedia-Editathon, der von der ETH-Bibliothek organisiert wird, verwendet werden. Sie gibt Einträge für Personen aus, die im Universitätsarchiv der ETH Zürich archiviert sind, aber keinen Wikipedia-Artikel auf Deutsch haben:

SELECT DISTINCT ?person ?personLabel ?personDescription ?occupation
  WHERE {
  ?person wdt:P485 wd:Q39934978 .  
  MINUS { ?sitelink schema:isPartOf <https://de.wikipedia.org/> ;
     schema:about ?person . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de" }
}

Try it!

Aufgabe:

• Ändern Sie die Abfrage für Personen ohne Artikel in der Englischen Wikipedia.
• Ändern Sie die Abfrage für Personen, welche in Ihrer eigenen Institution archiviert sind (archives at P485).

Hinweis:

• Testen Sie die Suche nach Personen mit Archiven in der ETH Zürich (oder in anderen Archiven) in der Testumgebung der ETH Zürich Bibliothek.

Exploring Ontologies & Editing Wikidata

Typology of heritage institutions

Use the Wikidata Ontology Explorer to inspect the typology of collections on Wikidata. Find out which are the most used properties in connection with collections. Click through the main classes and properties and make sure that they have appropriate labels and descriptions in your language.

(Semi-)Automatic Reconciliation

See dataset of person archives after reconciliation with OpenRefine.