User:Bjs/Queries

Geografie edit

Nebenflüsse des Karnaphuli edit

SELECT DISTINCT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P31 wd:Q4022; # ist ein = Fluss
    wdt:P403 wd:Q766956.  # mündet in = Karnaphuli
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}

Try it!

Nebenflüsse des Karnaphuli oder Feni edit

SELECT DISTINCT ?item ?itemLabel ?itemDescription  WHERE {
  ?item wdt:P31 wd:Q4022.         # ist ein = Fluss
  { ?item wdt:P403 wd:Q766956. }  # mündet in = Karnaphuli
  UNION                           # oder (Vereinigungsmenge)
  { ?item wdt:P403 wd:Q2982759. } # mündet in = Feni 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}

Try it!

Berge in Bangladesh (als Karte) edit

#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?position WHERE {
  ?item wdt:P31 wd:Q8502; # ist ein = Berg
    wdt:P17 wd:Q902;      # Staat = Bangladesch
    wdt:P625 ?position.   # Hole Position aus Koordinaten
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]". }
}

Try it!

Seen oder eine Unterklasse davon in der Region Sizilien edit

SELECT ?See ?SeeLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,it,en,[AUTO_LANGUAGE]". }
  ?See (wdt:P31/wdt:P279*) wd:Q23397;
    wdt:P131 wd:Q1460.
}

Try it!

Seen in der Region Sizilien oder einer untergeordneten Verwaltungseinheit edit

SELECT ?See ?SeeLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,it,en,[AUTO_LANGUAGE]". }
  ?See wdt:P31 wd:Q23397;
    wdt:P131+ wd:Q1460.
}

Try it!

Seen auf der Insel Sizilien oder in einem geographischen Teilgebiet edit

SELECT ?See ?SeeLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,it,en,[AUTO_LANGUAGE]". }
  ?See wdt:P31 wd:Q23397;
    wdt:P706+ wd:Q4951156.
}

Try it!

Diverse Seenarten im Radius von 300 km um die Koordinate von Sizilien edit

#defaultView:Map
SELECT ?item ?itemLabel ?coordinate WHERE {
  wd:Q1460 wdt:P625 ?Center.    # Koordinaten von Sizilien
  { ?item wdt:P31 wd:Q23397; }  # ist ein See
  UNION                           # oder
  { ?item wdt:P31 wd:Q131681; }  # ein Stausee
  UNION                           # oder
  { ?item wdt:P31 wd:Q187223; }  # eine Lagune
  UNION                           # oder
  { ?item wdt:P31 wd:Q188025; }  # ein Salzsee
  SERVICE wikibase:around {
    ?item wdt:P625 ?coordinate. # hole Koordinaten 
    bd:serviceParam wikibase:center ?Center. # Abstand von den Koordinaten von Sizilien
    bd:serviceParam wikibase:radius "300". # innerhalb 300 Kilometer 
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,it,en,[AUTO_LANGUAGE]". }
}

Try it!

Alle Seenarten im Rechteck der Koordinaten von Sizilien edit

für die Region Sicily (Q1460) oder die Insel Sicily (Q4951156)
auch für die Unterklassen reservoir (Q131681), lagoon (Q187223), salt lake (Q188025), salt evaporation pond (Q244326)
analog für river (Q4022), mountain (Q8502), mountain range (Q46831), cape (Q185113), bay (Q39594), island (Q23442), island group (Q1402592), city (Q515), municipality (Q15284)

#defaultView:Map
SELECT ?item ?itemLabel ?coordinate WITH {
  SELECT ?item WHERE {
  wd:Q1460 wdt:P625 ?Center.    # Koordinatenpunkt von Region Sizilien
  SERVICE wikibase:around {
    ?item wdt:P625 ?coordinate.
    bd:serviceParam wikibase:center ?Center.
    bd:serviceParam wikibase:radius "300". # 300 Kilometer vom Koordinatenpunkt
  }
    } } as %i
WITH {
  SELECT ?item WHERE {
      ?item wdt:P31/wdt:P279* wd:Q23397. hint:Prior hint:gearing "reverse".      # See mit Unterklassen
} } as %j
WHERE
{
  include %i 
  include %j
  ?item p:P625 ?stat .
  ?stat a wikibase:BestRank .  
  ?stat psv:P625/wikibase:geoLongitude ?long. # Längengrad
  ?stat psv:P625/wikibase:geoLatitude ?lat.   # Breitengrad
  wd:Q1460 p:P1332/psv:P1332/wikibase:geoLatitude ?north . filter(?lat <= ?north ) # innerhalb des Rechtecks der Region Sizilien
  wd:Q1460 p:P1333/psv:P1333/wikibase:geoLatitude ?south . filter(?lat >= ?south )
  wd:Q1460 p:P1334/psv:P1334/wikibase:geoLongitude ?east . filter(?long <= ?east )
  wd:Q1460 p:P1335/psv:P1335/wikibase:geoLongitude ?west . filter(?long >= ?west )
  filter((?long <= 13.5) || (?lat >= 36.5) ) # Malta ausklammern
    ?item wdt:P625 ?coordinate.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,it,en,[AUTO_LANGUAGE]". }
}

Try it!

Seen in der Region Sizilien ohne administrative Lage edit

#defaultView:Map
SELECT ?item ?itemLabel ?coord WHERE {
  ?item wdt:P17 wd:Q1460. # Autonome Region Sizilien
  ?item wdt:P625 ?coord.
  ?item wdt:P31/wdt:P279* wd:Q23397. # See oder Unterklasse
  MINUS { ?item wdt:P131 [] } # ohne administrative Lage
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,it,en,[AUTO_LANGUAGE]" . }
}

Try it!

Lokalisierbares edit

Bauwerke in Buchara

SELECT ?item ?itemLabel ?itemDescription ?typeLabel WHERE {
  ?item (wdt:P31/wdt:P279*) wd:Q811979; # ist ein = Bauwerk oder ein Untertyp davon
    wdt:P131 wd:Q5764;                  # liegt in = Buchara 
    wdt:P31 ?type.                      # Hole Bauwerkstyp aus "ist ein"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Objekt in Bethlehem mit Koordinate, falls vorhanden

SELECT ?item ?itemLabel ?itemDescription ?typeLabel ?position WHERE {
  ?item wdt:P131 wd:Q5776.               # liegt in Bethlehem
  OPTIONAL { ?item wdt:P31 ?type. }      # Hole Objekttyp aus "ist ein"
  OPTIONAL { ?item wdt:P625 ?position. } # Hole Position aus "Koordinaten", falls vorhanden 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Objekt in Bethlehem (als Karte)

#defaultView:Map
SELECT ?item ?itemLabel ?itemDescription ?position WHERE {
  ?item wdt:P131 wd:Q5776; # liegt in Bethlehem
    wdt:P625 ?position.    # Hole Position aus "Koordinaten"
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Museum in München

SELECT DISTINCT ?item ?itemLabel ?itemDescription ?typeLabel WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q33506;     # ist ein Museum oder ein Untertyp davon
    wdt:P31 ?type.                           # Hole Museumstyp aus "ist ein"
  { ?item (wdt:P131/(wdt:P279*)) wd:Q1726. } # liegt in München
  UNION
  { ?item (wdt:P131/(wdt:P31*)) wd:Q253270. } # liegt in einem Stadtbezirk von München
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Teile des Baudenkmals St. Nikolaus in Eschenlohe

#defaultView:Map
SELECT ?item ?itemLabel ?itemDescription ?position WHERE {
  ?item wdt:P361 wd:Q41228059;
    wdt:P625 ?position.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Kunstwerke edit

Gemälde von Franz Marc im Lenbachhaus (als Galerie)

#defaultView:ImageGrid
SELECT * WHERE {
  ?item (wdt:P31/wdt:P279) wd:Q3305213; # ist ein Gemälde oder ein besonderer Typ davon
    wdt:P170 wd:Q44054;                 # Urheber = Franz Marc
    wdt:P195 wd:Q262234;                # Sammlung = Lenbachhaus
    wdt:P18 ?pic;                       # Hole Datei(en) aus Bild 
    wdt:P31 ?type                       # Hole Gemäldetyp aus "ist ein"
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Werk von Franz Marc mit deutschem Wikipediaartikel

SELECT ?item ?itemLabel ?itemDescription ?article WHERE {
  ?item wdt:P170 wd:Q44054; #Urheber = Franz Marc
    wdt:P18 ?pic. #wähle Bild aus P18 
  ?article schema:about ?item; #wähle Artikel/Kategorie
    schema:isPartOf <https://de.wikipedia.org/>. #aus de-wiki
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Werk von Franz Marc mit Commons-Kategorie

SELECT ?item ?itemLabel ?itemDescription ?article WHERE {
  ?item wdt:P170 wd:Q44054; #Urheber = Franz Marc
    wdt:P18 ?pic. #wähle Bild aus P18 
  ?article schema:about ?item; #wähle Artikel/Kategorie
    schema:isPartOf <https://commons.wikimedia.org/>. #aus commons
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Werk von Franz Marc aus dem Jahr 1911

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P170 wd:Q44054; #Urheber = Franz Marc
    wdt:P571 ?date. #wähle Datum aus P571 
  FILTER((YEAR(?date)) = 1911 ) # Extrahiere Jahr aus Datum und selektiere nach 1911
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}

Werk von Franz Marc aus den Jahren 1911 bis 1913, sortiert nach Jahr

SELECT ?item ?itemLabel ?itemDescription (YEAR(?date) AS ?year) ?image WHERE {
  ?item wdt:P170 wd:Q44054; #Urheber = Franz Marc
    wdt:P571 ?date. #wähle Datum aus P571
  OPTIONAL { ?item wdt:P18 ?image. } 
  FILTER((YEAR(?date) >= 1911 ) && (YEAR(?date)) <= 1913 ) # Extrahiere Jahr aus Datum und selektiere nach 1911-1913
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
ORDER BY ?year

Werk von Franz Marc ohne Bild oder Datum

SELECT ?item ?itemLabel ?itemDescription (YEAR(?date) AS ?year) ?image WHERE {
  ?item wdt:P170 wd:Q44054.
  OPTIONAL { ?item wdt:P571 ?date. }
  OPTIONAL { ?item wdt:P18 ?image. }
  FILTER(NOT EXISTS { ?item wdt:P571 ?date. } || NOT EXISTS { ?item wdt:P18 ?image. } )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}