Wikidata:ScienceSource project/Focus list and journal queries

The project focus list has been built up very largely by automated imports. In 2018 it stood at a bit over 3K items, after its initial launch. In 2019 it has scaled up, using the metadata provided by the NCBI2wikidata tool.

For any bot posting to the focus list, there is the issue of the quality of the articles. A normal way to judge articles is by the reputation of the journal in which they are published. There are a number of difficult points about that approach. This page, in any case, goes into this area, in the Wikidata context

IdentifiersEdit

List of properties typically found as identifiers on pages about journals:

Property Present? Absent?
ISSN (P236) [1] [2]
OCLC control number (P243) [3] [4]
Internet Archive ID (P724) [5] [6]
NLM Unique ID (P1055) [7] [8]
ERA Journal ID (P1058) [9] [10]
Library of Congress Control Number (LCCN) (bibliographic) (P1144) [11] [12]
Scopus source ID (P1156) [13] [14]
CODEN (P1159) [15] [16]
Danish Bibliometric Research Indicator (BFI) SNO/CNO (P1250) [17] [18]
Norwegian Register journal ID (P1270) [19] [20]
Norway Import Service and Registration Authority periodical code (P1272)

[21]||[22]

JUFO ID (P1277) [23] [24]
OpenCitations bibliographic resource ID (P3181) [25] [26]
BHL bibliography ID (P4327) [27] [28]
UniProt journal ID (P4616) [29] [30]
Directory of Open Access Journals ID (P5115) [31] [32]
[33], for the case where the journal is stated to be open access.[1]
Elsevier journal ID (P5963) [34] [35]
Springer journal ID (P5983)[2] [36] [37]
Dimensions Source ID (P6180) [38] [39]
  • #defaultView:BubbleChart
    #Focus list journals without publishers, descending order of number of focus list articles
    SELECT ?journalLabel (COUNT(?article) AS ?count)
      WHERE {?article wdt:P5008 wd:Q55439927;
                   wdt:P1433 ?journal.
             MINUS {?journal wdt:P123 ?publisher}.
           SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
            }
    GROUP BY ?journalLabel
    ORDER BY DESC(?count)
    
    Try it!

Open accessEdit

#Open-access journals represented on the focus list, without [[Property:P5115|Directory of Open Access Journals ID&#32;<small>(P5115)</small>]]
SELECT DISTINCT ?journal ?journalLabel ?publisherLabel

WHERE {?item wdt:P1433 ?journal;
             wdt:P5008 wd:Q55439927.
       ?journal wdt:P31 wd:Q773668.
       OPTIONAL {?journal wdt:P123 ?publisher}
       
       MINUS {?journal wdt:P5115 [ ]}
       
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       }

Try it!

#Journals represented on the focus list, neither having Directory of Open Access Journals ID, 
#nor being hybrid open-access
SELECT DISTINCT ?journal ?journalLabel

WHERE {?item wdt:P1433 ?journal;
             wdt:P5008 wd:Q55439927.
       MINUS {?journal wdt:P5115 [ ]}.
       MINUS {?journal wdt:P31 wd:Q5953270} 
       
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       }

Try it!

#Journals represented on the focus list, neither having Directory of Open Access Journals ID, 
#nor being hybrid open-access; with an article having license, showing publisher
SELECT DISTINCT ?journal ?journalLabel ?publisherLabel ?licenseLabel

WHERE {?item wdt:P1433 ?journal;
             wdt:P275 ?license;
             wdt:P5008 wd:Q55439927.
       OPTIONAL {?journal wdt:P123 ?publisher}
       MINUS {?journal wdt:P5115 [ ]}.
       MINUS {?journal wdt:P31 wd:Q5953270}
       
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       }

Try it!

#Journals represented on the focus list, having no Directory of Open Access Journals ID, 
#nor being open-access or hybrid open-access
SELECT DISTINCT ?journal ?journalLabel ?licenseLabel

WHERE {?item wdt:P1433 ?journal;
             wdt:P5008 wd:Q55439927;
             wdt:P275 ?license.
       MINUS {?journal wdt:P5115 [ ]}.
       MINUS {?journal wdt:P31 wd:Q773668} 
       MINUS {?journal wdt:P31 wd:Q5953270} 
       
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       }

Try it!

#Journals represented on the focus list, having no Directory of Open Access Journals ID, 
#nor being open-access, hybrid open-access or delayed open-access
SELECT DISTINCT ?journal ?journalLabel ?licenseLabel

WHERE {?item wdt:P1433 ?journal;
             wdt:P5008 wd:Q55439927;
             wdt:P275 ?license.
       MINUS {?journal wdt:P5115 [ ]}.
       MINUS {?journal wdt:P31 wd:Q773668} 
       MINUS {?journal wdt:P31 wd:Q5953270} 
       MINUS {?journal wdt:P31 wd:Q5253501}
       
      SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       }

Try it!


QuackwatchEdit

#Quackwatch filter: finds focus list items that are published in journals in the "Journals (Fundamentally Flawed)"
#section of https://www.quackwatch.org/04ConsumerEducation/nonrecperiodicals.html.
#Matching to Wikidata carried out on 2019-04-09
SELECT DISTINCT ?item ?itemLabel ?journal ?journalLabel

  WHERE {
  
    ?item wdt:P5008 wd:Q55439927;
          wdt:P1433 ?journal.
    
          {
           VALUES ?journal 
          {wd:Q15754497 wd:Q15279374 wd:Q27720778 wd:Q15756796 wd:Q6294757
           wd:Q15752906 wd:Q27711374 wd:Q10310914 wd:Q15760198 wd:Q10310916
           } 
        }     
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }

Try it!

PublishersEdit

Missing publisher fieldEdit

There are items on the focus list, with journal carrying NLM Unique ID (P1055), but missing a publisher (P123) statement.

#Focus list journals with NLM ID, but without publisher
SELECT DISTINCT ?journal ?journalLabel

  WHERE {
  
    ?item wdt:P5008 wd:Q55439927;
          wdt:P1433 ?journal.
         ?journal wdt:P1055 [ ].
       MINUS {?journal wdt:P123 [ ]}
    
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }

Try it!

Beall's listEdit

See Wikidata:ScienceSource project/Beall's list for the content that was here.

QueriesEdit

#Finds focus list items that are published in journals with publisher identified on Beall's list.
SELECT DISTINCT ?item ?itemLabel ?journal ?journalLabel ?publisherLabel

  WHERE {
  
    ?item wdt:P5008 wd:Q55439927;
          wdt:P1433 ?journal.
          ?journal wdt:P123 ?publisher.
    
          {
           VALUES ?publisher
 
          {wd:Q52636754 wd:Q52635805 wd:Q4689899 wd:Q52620137 wd:Q4732612 
           wd:Q43080819 wd:Q30270870 wd:Q30297686 wd:Q52661346 wd:Q52636079 
           wd:Q52557383 wd:Q54958933 wd:Q2896740 wd:Q18712923 wd:Q52609680 
           wd:Q52609536 wd:Q52636154 wd:Q52609215 wd:Q80796 wd:Q52636535 
           wd:Q52633727 wd:Q52636944 wd:Q63254434 wd:Q52637577 wd:Q52665969 wd:Q52660711
           wd:Q52659576 wd:Q56979398 wd:Q52670242 wd:Q29891111 wd:Q63254475 wd:Q52619294 
           wd:Q52662151 wd:Q7072722 wd:Q52609375 wd:Q7259709 wd:Q52636843 
           wd:Q45251004 wd:Q52637573 wd:Q52662489 wd:Q52635330 wd:Q47116994 
           wd:Q30267116 wd:Q24706265 wd:Q52620720 wd:Q52633876 wd:Q56416796 
           wd:Q52660351 wd:Q52635690 wd:Q7433770 wd:Q27991304 wd:Q55566796 
           wd:Q52619286 wd:Q30265175 wd:Q8035326 
           } 
        }     
 
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }

Try it!

#Focus list items in journals published by Bentham Scientific Publishers
SELECT DISTINCT ?item ?itemLabel ?journalLabel ?specLabel

  WHERE {
  
    ?item wdt:P5008 wd:Q55439927;
          wdt:P1433 ?journal;
          wdt:P921 ?subject.
    ?subject wdt:P1995 ?spec.
    ?journal wdt:P123 wd:Q2896740.
    
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }

Try it!

StrakhovEdit

From User:Strakhov/FJ.

Periodicals under some kind of free license
SELECT ?item ?itemLabel

WHERE {
  { ?item wdt:P275/wdt:P31 wd:Q196294 } UNION  { ?item wdt:P275/wdt:P279 wd:Q196294 } .
  ?item wdt:P31/wdt:P279* wd:Q1002697 .
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }

Try it!

  1. {{sparql|query=#Listing DOAJ and/or publisher for open-access journals so tagged. SELECT DISTINCT ?journal ?doaj ?publisherLabel WHERE {?journal wdt:P31 wd:Q773668. ?item wdt:P5008 wd:Q55439927; wdt:P1433 ?journal. OPTIONAL {?journal wdt:P5115 ?doaj} OPTIONAL {?journal wdt:P123 ?publisher} SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } }
  2. #Publishers with Springer as parent organization
    SELECT DISTINCT ?publisher ?publisherLabel
      WHERE {?item wdt:P123 ?publisher.
             ?publisher wdt:P749* wd:Q176916.
        SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
       }
    
    Try it!