User:DerFussi/Cottbus

Thanks a lot to User sk for providing the queries.

Wikidata-Cottbus-Stadtplan

Straßenverbindungen als Graph

#defaultView:Graph;Table
#------------------------------------------------------------------------------------
# Straßenverbindungen als Graph (über die Eigenschaft "physisch verbunden mit")
#------------------------------------------------------------------------------------
SELECT distinct
?item ?itemLabel ?image  ?other ?otherLabel ?image2
WHERE
{
    ?item wdt:P131+ wd:Q3214. # Objekt liegt in Verwaltungseinheit Cottbus (oder Subklasse)

    #?instance_of wdt:P279+ wd:Q376799 .   # Verkehrsinfrastuktur
    VALUES ?instance_of { 
      wd:Q79007      # Innerortstraße
      wd:Q21000333   # Einkaufsstraße 
      wd:Q174782     # Platz
      wd:Q537127     # Straßenbrücke
      wd:Q3397519    # Spannbetonbrücke 
      wd:Q1055465    # Balkenbrücke  
    } # Innerortstraße oder Platz oder Brücke
    ?item wdt:P31 ?instance_of.
	
    ?item  wdt:P2789    ?other  .   # verbundenes objekt
    	
    OPTIONAL {
      ?item  wdt:P18     ?image  .   # grab image1
      ?other wdt:P18     ?image2 .   # grab image2
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]" }
}

Try it!

Straßen und Gebäude als Graph

#----------------------------------------------------------------
# Straßen und Gebäude als Graph (über die Eigenschaft "Straße")
#----------------------------------------------------------------
#defaultView:Graph;Table
SELECT distinct ?item ?itemLabel ?image  ?other ?otherLabel ?image2 
WHERE
{
    ?item wdt:P131+ wd:Q3214. # Adresseobjekt liegt Verwaltungseinheit Cottbus (oder Subklasse)
    ?other  wdt:P669  ?item  .  # Objekt hat "Straße" = Adresseobjekt
    OPTIONAL {
      ?item  wdt:P18 ?image  . # grab image1
      ?other wdt:P18 ?image2 . # grab image2
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]" }
}

Try it!