User:Erfurth/DieDatenlaube

Rechnen und Runden

#Chart of number books on animal magnetism (1766-1880) grouped by decade
SELECT ?decade (COUNT(?item) AS ?noB) WHERE {
  ?item wdt:P2 wd:Q394362;
    wdt:P243 wd:Q172203;
    wdt:P222 ?date.
  BIND(YEAR(?date) AS ?year)
  BIND(STR((ROUND(?year / 10 )) * 10)  AS ?decade)
}
GROUP BY ?decade
ORDER BY (?decade)

Try it!

Illustrationen mit Medialegend

#defaultView:ImageGrid
SELECT DISTINCT ?image ?item ?medialegend
WHERE 
{
  ?item wdt:P1433 wd:Q655617. #in der Gartenlaube veröffentlicht
  ?item wdt:P921 wd:Q1731. #main subject = Dresden
  ?item wdt:P18 ?image. # mit Illustration
  ?item p:P18 ?statement.
  ?statement pq:P2096 ?medialegend. # medialegends - Todo: multivaluehandling
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Version von Chris

SELECT DISTINCT ?image ?item (GROUP_CONCAT(?medialegend; SEPARATOR = " ") AS ?legende) WHERE {
  VALUES ?item {
    wd:Q97610922
  }
  ?item wdt:P1433 wd:Q655617;
    wdt:P921 wd:Q1731;
    p:P18 ?statement.
  ?statement ps:P18 ?image;
    pq:P2096 ?medialegend.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?image ?item

Try it!

Geographische Verteilung (Sachsen)

#defaultView:Map
SELECT ?item ?itemLabel ?city ?cityLabel ?coord
WHERE 
{
 ?item wdt:P31 wd:Q191067.
 ?item wdt:P1433 wd:Q655617.
 ?item wdt:P921 ?city.
 ?city wdt:P7046 ?hov.
 ?city wdt:P625 ?coord.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

• Sachsen: TryIt!, Welt

Wartungsliste: main subject

SELECT ?item ?itemLabel (year(xsd:dateTime(?date)) as ?year)  ?pages WHERE {
   ?item wdt:P1433 wd:Q655617.
   ?item wdt:P577 ?date.
   optional {
     ?item wdt:P304 ?pages
   }   
   FILTER NOT EXISTS { ?item wdt:P921 ?mainSubject }
   FILTER NOT EXISTS { ?item wdt:P136 wd:Q5185279 }
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
} ORDER BY ?date

• TryIt!

Mainsubjects

https://w.wiki/3RBa mit Images

Illustrationen

• Desdemona rechtfertigt ihre Flucht (Q95547440)
• Ein Denkmal für Corona Schröter (Q19188605)
• Auf der Landpraxis (Q62612023)
• Der alte Gelehrte (Q104531307)
• Das Ende der Noth (Q15892100)