User:Fralambert/Statut municipal

Projet de créer les statuts municipaux au Québec

Liste des municipalités des Laurentides edit

SELECT DISTINCT  ?municipality ?municipalityLabel 
WHERE { ?tree0 (wdt:P150)* ?municipality . ?tree0 (wdt:P131|wdt:P17)* wd:Q2304022 . ?municipality wdt:P31 wd:Q3327873
      SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
      }
ORDER BY ?municipalityLabel

Try it!

Liste des MRC sans population edit

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q204613 .
  FILTER NOT EXISTS { ?item wdt:P1082 [] }
      SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY ?itemLabel

Try it!

Liste des biens désignées de Parry Sound edit

SELECT DISTINCT  ?monument ?monumentLabel 
WHERE { {
    SELECT DISTINCT ?monument WHERE {
      ?monument wdt:P1435/wdt:P279* wd:Q15080599 .
      ?monument p:P1435 ?heritage_statement .
      FILTER NOT EXISTS { ?heritage_statement pq:P582 ?end . }
    } }
  ?monument wdt:P131/wdt:P131* wd:Q1798108 .       
      SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
      }
ORDER BY ?monumentLabel

Try it!

Liste des ressources historiques municipales de l'Alberta edit

SELECT DISTINCT  ?monument ?monumentLabel 
WHERE { {
    SELECT DISTINCT ?monument WHERE {
      ?monument wdt:P1435/wdt:P279* wd:Q14475671 .
      ?monument p:P1435 ?heritage_statement .
      FILTER NOT EXISTS { ?heritage_statement pq:P582 ?end . }
    } }    
      SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
      }
ORDER BY ?monumentLabel

Try it!

Liste des lieux historiques nationaux du Canada sans P2526 edit

SELECT ?item WHERE {
  ?item wdt:P1435 wd:Q1568567 .
  MINUS { ?item wdt:P2526 [] } .
}

Try it!

Édifices fédéraux du patrimoine du Nouveau-Brunswick edit

SELECT DISTINCT  ?monument ?monumentLabel 
WHERE { {
    SELECT DISTINCT ?monument WHERE {
      ?monument wdt:P1435/wdt:P279* wd:Q3579115 .
      ?monument p:P1435 ?heritage_statement .
      FILTER NOT EXISTS { ?heritage_statement pq:P582 ?end . }
    } }    
       ?monument wdt:P131+ wd:Q1965 .
      SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, en". }
      }
ORDER BY ?monumentLabel

Try it!

bien patrimoniaux de l'Ontario sans P1420 edit

SELECT DISTINCT ?item ?itemLabel WHERE {
  ?item wdt:P1435 wd:Q15080599 .
  ?item wdt:P131+ wd:Q1930. # Pour une autre région, changer Q1930 pour la municipalité ou le nomté voulu.
  MINUS { ?item wdt:P4120 [] } . 
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, en". }
}
ORDER BY ?itemLabel

Try it!

Églises du Québec sans P5599 edit

SELECT distinct ?item ?itemLabel with
{ select ?item where { ?item wdt:P131+ wd:Q176 . } } as %i
where {
  include %i
  ?item wdt:P31/wdt:P279* wd:Q44539 .
  FILTER NOT EXISTS { ?item wdt:P5599 ?thing .} 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
} order by ?itemLabel

Try it!

Monuments avec P969 edit

SELECT DISTINCT ?item ?communeLabel ?P969 WHERE {
  {
    SELECT DISTINCT ?item WHERE {
      ?item (wdt:P1435/wdt:P279*) wd:Q14469659.
      ?item p:P1435 ?heritage_statement.
      FILTER(NOT EXISTS { ?heritage_statement pq:P582 ?end. })
    }
  }
  ?item (wdt:P131/wdt:P131*) wd:Q510572.
  ?item wdt:P131 ?commune.
  ?item wdt:P969 ?P969. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
GROUP BY ?item ?itemLabel ?communeLabel ?P969 
ORDER BY ?communeLabel ?itemLabel

Try it!

Bâtiment en Ontario à relocaliser edit

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31/wdt:P279* wd:Q41176 .
  ?item wdt:P131 wd:Q1904 .
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!