HereinTheHague

Babel user information
en-N This user has a native understanding of English. nl-3 Deze gebruiker heeft gevorderde kennis van het Nederlands. es-1 Esta usuaria tiene un conocimiento básico del español. fr-1 Cette utilisatrice dispose de connaissances de base en français.
Users by language

About me

Hi! Welcome to my page. I am originally from the United States, but moved to The Hague in 2012 to marry a Dutchie. In my former life I worked as a librarian in both the public and academic sector. These days I work with educational metadata at a non-profit organization.

I started at Wikidata back in February 2019. At the moment I work on two mini projects:

• public transportation in The Hague
• professional wrestlers

Weird combination, huh? My dream job would be to work for local public transportation company HTM Personenvervoer (Q132168) in the field of metadata. Someday...

public transportation project

This is my main project on Wikidata. At the moment this project entails:

• adding stops for each of the tram lines HTM operates. Example: HMC Westeinde (Q3466818)
• (then) adding HTM bus lines and respective stops (including weekend night buses)
• (then) adding extras like fare zones and customer help centers; then linking the tram/bus stop pages to them as required

Viewing RandstadRail 4 stops, in order

The following query uses these:

• Items: fast tram stop (Q3201814)   , RandstadRail 4 (Q2735863)   , Lansingerland-Zoetermeer railway station (Q2740322)   

• Properties: instance of (P31)   , connecting line (P81)   , series ordinal (P1545)   , towards (P5051)   

  SELECT ?item ?itemLabel ?towardsLabel ?order
  WHERE {
    ?item wdt:P31 wd:Q3201814 .    # instance of fast tram stop
    ?item wdt:P81 wd:Q2735863 .    # connecting line RandstadRail 4
    ?item p:P81 ?station_query .   # build query to look at qualifiers (note use of lower case p: )
    ?station_query ps:P81 wd:Q2735863 . # connecting line - item must be same as the item for p:P81 above
    ?station_query pq:P1545 ?order .    # qualifier: series ordinal value, later used in ORDER BY
    ?station_query pq:P5051 ?towards .  # qualifier: towards, to later limit to one direction
    FILTER ( ?towards != wd:Q2740322 )  # to only show one direction  
   
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
  }
  ORDER BY xsd:integer(?order)
  

Try it!

professional wrestlers project

I started this project first, to get a sense of how to add metadata to pages. My husband watches a lot of professional wrestling, so I figured it would be a good way to know more about the wrestlers I was seeing on TV. At the moment this project entails:

• adding occupation start time (and end time, optionally) to professional wrestler pages
• adding CageMatch IDs to professional wrestler pages, if missing

The current query I use limits results to those without an occupation start time and with an English Wikipedia page. The latter restriction is due to the high number of Japanese wrestlers without an English Wikipedia page. The optional code is to transform the CageMatch ID into a live URL and the SAMPLE code in the select statement is to pick the first CageMatch link which appears (the site has both EN and DE links).

Professional wrestlers without an occupation start time

The following query uses these:

• Items: human (Q5)   , professional wrestler (Q13474373)   

• Properties: instance of (P31)   , occupation (P106)   , formatter URL (P1630)   , CageMatch worker ID (P2728)   , start time (P580)   

  SELECT ?wrestler ?article (SAMPLE(?link) AS ?link) ?wrestlerLabel
  WHERE {
     ?wrestler wdt:P31 wd:Q5 .
     ?wrestler wdt:P106 wd:Q13474373 .
     ?article schema:about ?wrestler .
     ?article schema:inLanguage "en" .
     ?article schema:isPartOf <https://en.wikipedia.org/> .
  OPTIONAL { wd:P2728 wdt:P1630 ?url .
             ?wrestler wdt:P2728 ?cgid .
             BIND(IRI(REPLACE(?cgid, '^(.+)$', ?url)) AS ?link).
           }
  MINUS {
     ?wrestler p:P106 ?occupation_statement .
     ?occupation_statement ps:P106 wd:Q13474373 .
     ?occupation_statement pq:P580 ?start .
        }
     SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" .
     }
   } 
  GROUP BY ?wrestler ?article ?wrestlerLabel
  ORDER BY ?wrestlerLabel
  

Try it!

CageMatch ID sanity check

The following query uses these:

• Items: human (Q5)   , professional wrestler (Q13474373)   

• Properties: instance of (P31)   , occupation (P106)   , CageMatch worker ID (P2728)   

  SELECT  ?wrestler ?wrestlerLabel ?refLabel (SAMPLE(?link) AS ?link) 
  WHERE {
  # Wikidata entries with CageMatch worker ID in occupation as reference
  # where the CageMatch worker ID was forgotten in the identifiers section
  # (this query should return 0 results)
  
     ?wrestler wdt:P31 wd:Q5 .          # human
     ?wrestler wdt:P106 wd:Q13474373 .  # occupation professional wrestler
  
     ?article schema:about ?wrestler .  # limit to wrestlers with EN Wikipedia article
     ?article schema:inLanguage "en" .  # to quicken search - for now
     ?article schema:isPartOf <https://en.wikipedia.org/> .
  
     ?wrestler p:P106 ?cgid_query . # build statement with p:
     ?cgid_query ps:P106 ?occ .     # retrieve obj within statement with ps:
     ?cgid_query prov:wasDerivedFrom ?refnode . # build ref node 
     ?refnode pr:P2728 ?ref .       # ref node should be Cagematch worker ID
  
  # only look for entries without the CageMatch ID in the identifiers section
  # bind to format as clickable URL 
    MINUS {
     ?wrestler wdt:P2728 ?cgid .
     BIND(IRI(REPLACE(?cgid, '^(.+)$', ?url)) AS ?link).
        }
     SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" .
        }
     }
  GROUP BY ?wrestler ?wrestlerLabel ?refLabel
  ORDER BY ?wrestlerLabel
  

Try it!