User:Iwan.Aucamp/Queries

Misc

SELECT DISTINCT ?item ?itemLabel ?itemDescription {
  # Q2352616 = catalogue
  { ?item wdt:P31? / wdt:P279* wd:Q2352616. }
  UNION
  # Q36524 = authority control
  { ?item wdt:P31? / wdt:P279* wd:Q36524. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

SELECT ?item {
  ?item schema:about wd:Q5084390 .  
}

Try it!

Query + guid

PREFIX ps: <http://www.wikidata.org/prop/statement/>
PREFIX p: <http://www.wikidata.org/prop/>
SELECT ?value ?guid WHERE { wd:Q1999199 p:P31 ?value . ?value ps:P31 ?guid . }

Try it!

SELECT ?value ?guid WHERE { wd:Q1999199 p:P31 ?value . ?value ps:P31 ?guid . }

Try it!

Find exemplars

SELECT ?item (COUNT(?value) as ?count) WHERE {
  ?item ( wdt:P279| ( wdt:P279 / wdt:P279 ) ) wd:Q7868.
  ?item ?prop ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,en"  }  
} GROUP BY ?item

Try it!

SELECT ?item (COUNT(?value) as ?count) WHERE {
  ?item wdt:P31 wd:Q13442814.
  ?item ?prop ?value.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,en"  }  
} GROUP BY ?item LIMIT 100

Try it!

lexemes

select ?lexemeId (COUNT(?value) as ?count) WHERE {
  ?lexemeId <http://purl.org/dc/terms/language> wd:Q25167.
  ?lexemeId wikibase:lemma ?lemma.
  ?lexemeId ?prop ?value.
  FILTER (regex(?lemma, '^.*'))
} GROUP BY ?lexemeId

Try it!

select ?lexemeId ?lemma WHERE {
  ?lexemeId <http://purl.org/dc/terms/language> wd:Q25167.
  ?lexemeId wikibase:lemma ?lemma.
}

Try it!

url lookup

#defaultView:Table
SELECT DISTINCT ?iri ?prop ?propLabel ?id ?item ?itemLabel WHERE {
  hint:Query hint:optimizer "None".
  VALUES ( ?test_url ) { 
            ( "https://quickstats.censusdata.abs.gov.au/census_services/getproduct/census/2016/quickstat/SSC11428" )
            ( "http://plantnet.rbgsyd.nsw.gov.au/cgi-bin/NSWfl.pl?page=nswfl&lvl=sp&name=Hibbertia~spanantha" )
            ( "https://www.lions.com.au/players/7" )
            ( "https://reiseauskunft.bahn.de/bin/bhftafel.exe/en?input=8400285&boardType=dep&time=actual&productsDefault=1111101&start=yes" )
  }
  BIND( IRI(?test_url) AS ?iri ).
     
  {?prop wdt:P1630 ?formatter_url .}
  UNION
  {?prop wdt:P3303 ?formatter_url .}
  
  FILTER (CONTAINS( ?formatter_url, "$1" ) ) 
  BIND (STRBEFORE( ?formatter_url, "$1" ) AS ?f_url_start )
  BIND (STRAFTER( ?formatter_url, "$1" ) AS ?f_url_end )
  
  FILTER(STRSTARTS( ?test_url, ?f_url_start ))
  FILTER(STRENDS( ?test_url, ?f_url_end ))
  
  BIND ( SUBSTR( ?test_url, 1+STRLEN(?f_url_start), STRLEN(?test_url)-STRLEN(?f_url_start)-STRLEN(?f_url_end) ) AS ?id )
  
  ?prop wikibase:directClaim ?propRel .
  ?item ?propRel ?id .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" } .
}

Try it!

w3.org properties

SELECT ?item ?itemLabel ?value WHERE 
{
  ?item wdt:P1628 ?value.
  FILTER(STRSTARTS(STR(?value), "http://www.w3.org/")).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

model items

researchers

SELECT ?item ?itemLabel ?statement_count
WHERE {
  # VALUES ?profession { wd:Q1650915 wd:Q3400985 wd:Q2248623 }
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P106 / wdt:P279* wd:Q1650915 .
  ?item wikibase:statements ?statement_count .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?statement_count)
LIMIT 10

Try it!

SELECT ?item ?itemLabel ?statement_count
WHERE {
  # VALUES ?profession { wd:Q1650915 wd:Q3400985 wd:Q2248623 }
  ?item wdt:P31 wd:Q5  .
  ?item wikibase:statements ?statement_count .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?statement_count)
LIMIT 10

Try it!

proceedings

SELECT ?item ?itemLabel ?statement_count
WHERE {
  # VALUES ?profession { wd:Q1650915 wd:Q3400985 wd:Q2248623 }
  ?item wdt:P31/(wdt:P279)* wd:Q1143604 .
  ?item wikibase:statements ?statement_count .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC (?statement_count)
LIMIT 100

Try it!