Wikidata

User:Jobu0101/Tatort

< User:Jobu0101

Zur Zeit (angefangen bereits in der zweiten Jahreshälfte 2021) arbeite ich daran, alle möglichen Tatortdaten in Wikidata einzupflegen. Trotz meiner Arbeit gibt es noch sehr viele Baustellen. Im folgenden ein paar Abfragen, die auf Unvollständigkeiten aufmerksam machen können. Hilfe ist erwünscht. Am besten koordiniert, also schreibt mich an!

Alle Tatortfolgen

edit

Die folgende Abfrage zeigt alle regulären Tatortfolgen. Schön ist, dass diese inzwischen alle ein Wikidata-Item haben. Darüber hinaus müsste inzwischen auch das Erstausstrahlungsdatum und die Folgennummer korrekt eingetragen sein. Große Lücken gibt es in den hinteren Spalten bei den Ermittlern, Regisseuren und Drehbuchautoren, so wie bei der Laufzeit.

Update vom 22. Februar 2022: Im Rahmen der Generalüberholung und Automatisierung von de:Liste der Tatort-Regisseure wurden nun alle Regisseure von mir korrekt eingetragen. 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?ordinal (MIN(?publication) AS ?aired) ?film ?title (GROUP_CONCAT(DISTINCT(?investigatorName);separator=", ") AS ?investigators) (GROUP_CONCAT(DISTINCT(?directorName);separator=", ") AS ?directors)(GROUP_CONCAT(DISTINCT(?screenwriter);separator=", ") AS ?screenwriters) (SAMPLE(?runtime) AS ?runtime) (SAMPLE(?imdb) AS ?imdb) WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal . FILTER(xsd:integer(?ordinal)<10000)
  OPTIONAL{?film wdt:P1476 ?title}
  OPTIONAL{?film wdt:P57 ?dir . ?dir rdfs:label ?directorName . FILTER(lang(?directorName) = "de")}
  OPTIONAL{?film wdt:P58 ?screen . ?screen rdfs:label ?screenwriter .  FILTER(lang(?screenwriter) = "de")}
  OPTIONAL{?film wdt:P345 ?imdb}
  OPTIONAL{?film wdt:P577 ?publication}
  OPTIONAL{?film wdt:P2047 ?runtime}
  OPTIONAL{?film p:P161 ?cast . ?cast pq:P453 ?investigator . ?investigator wdt:P31 wd:Q110857263 . ?investigator rdfs:label ?investigatorName . FILTER(lang(?investigatorName) = "de")}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
GROUP BY ?film ?title ?ordinal
ORDER BY DESC(xsd:integer(?ordinal))
Try it!

Neue Folgen finden sich unter anderem in der IMDb

aber auch in der Wikipedia

Tatortfolgen, denen noch keine Folgennummer zugewiesen wurde

edit 
PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?publication ?filmLabel ?title ?investigatorSeriesLabel ?iso ?directorLabel ?imdb ?article WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . FILTER NOT EXISTS {?series pq:P1545 ?ordinal}
  OPTIONAL{?film wdt:P1476 ?title}
  OPTIONAL{?film wdt:P577 ?publication}
  OPTIONAL{?film wdt:P345 ?imdb}
  OPTIONAL{?film wdt:P57 ?director}
  OPTIONAL{?film p:P179 ?investSeries . ?investSeries v:P179 ?investigatorSeries OPTIONAL{?investSeries pq:P1545 ?iso} FILTER(?investigatorSeries != wd:Q689438)}
  OPTIONAL{?article schema:about ?film . ?article schema:inLanguage "de"}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
ORDER BY DESC(?publication) ?filmLabel
Try it!

Mögliche Tatortfolgen, die noch nicht entsprechend markiert wurden

edit

Arbeite ich immer wieder ab (in der Regel schaue ich jede Woche mindestens einmal nach). Bergfalke2 erstellt in der Regel die neuen Tatortfolgen, zeichnet sie aber nie als solche aus. Über diese Abfrage finde ich sie und kann den misslichen Umstand beheben. 

SELECT ?film ?label WHERE {
  {{?film wdt:P31 wd:Q506240} UNION {?film wdt:P6359 ?crew}} FILTER(?film NOT IN (wd:Q3307571, wd:Q116925796))
  ?film rdfs:label ?label . FILTER(lang(?label) = "de")
  FILTER (SUBSTR(STR(?label),1,6)='Tatort')
  FILTER NOT EXISTS {?film wdt:P179 wd:Q689438}
}
Try it!

Tatortfolgen in Ermittlerserien ohne lokale Folgennummer

edit 
PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?subSeriesLabel ?filmLabel WHERE {
  ?film p:P179 ?subSeriesStatement . ?subSeriesStatement v:P179 ?subSeries . ?subSeries wdt:P361 wd:Q689438
  FILTER NOT EXISTS {?subSeriesStatement pq:P1545 ?ord}
  OPTIONAL{?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal}
  OPTIONAL{?film wdt:P577 ?publication}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY DESC(?publication)
Try it!

Rollen in Tatortfolgen, die keine Ermittler sind

edit

Die folgende Abfrage hat mir geholfen, Ermittler aufzuspüren, die bereits ein Wikidata-Item hatten, aber nicht als Ermittler über Tatort investigator (Q110857263) gekennzeichnet waren. 

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?film ?ordinal ?filmLabel ?actorLabel ?roleLabel ?instanceLabel ?role WHERE {
	?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal . FILTER(xsd:integer(?ordinal)<10000)
    ?film p:P161 ?cast . ?cast v:P161 ?actor . ?cast pq:P453 ?role FILTER NOT EXISTS {?role wdt:P31 wd:Q110857263}
    OPTIONAL{?role wdt:P31 ?instance}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
ORDER BY ?instanceLabel ?roleLabel ASC(xsd:integer(?ordinal))
Try it!

Filmreihen mit Tatortfolgen

edit

Die folgende Abfrage liefert alle Filmreihen mit Tatortfolgen (außer der Filmreile aller Tatortfolgen). Dies sind hauptsächlich von mir angelegte Ermittlerreihen. 

PREFIX v: <http://www.wikidata.org/prop/statement/>

SELECT ?otherSeries ?otherSeriesLabel (COUNT(DISTINCT(?film)) AS ?count) ?partOfLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P179 ?otherSeries FILTER(?otherSeries != wd:Q689438)
  OPTIONAL{?otherSeries wdt:P361 ?partOf}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?otherSeries ?otherSeriesLabel ?partOf ?partOfLabel
ORDER BY DESC(?count) ?otherSeriesLabel
Try it!

Ermittler

edit

Fehlende Ermittler können unter anderem hier gefunden werden:

Die folgende Abfrage gibt die Tatort-Ermittler, die bereits ein Wikidata-Item haben und auch als Ermittler markiert sind, zurück. Freie Spalten dürften gerne ausgefüllt so wie fehlende Ermittler nachgetragen werden. Vor dem Anlegen eines neuen Ermittlers ist erst zu prüfen, ob er bereits ein Wikidata-Item hat, welches nur noch nicht richtig als Tatort-Ermittler gekennzeichnet ist. 

SELECT ?actorLabel ?investigator ?investigatorLabel ?sexLabel ?givenNameLabel ?familyNameLabel ?teamLabel ?seriesLabel ?firstApprearanceLabel WHERE {
  ?investigator wdt:P31 wd:Q110857263
  OPTIONAL {?investigator wdt:P21 ?sex}
  OPTIONAL {?investigator wdt:P735 ?givenName}
  OPTIONAL {?investigator wdt:P734 ?familyName}
  OPTIONAL {?investigator wdt:P175 ?actor}
  OPTIONAL {?investigator wdt:P361 ?team}
  OPTIONAL {?investigator wdt:P1441 ?series}
  OPTIONAL {?investigator wdt:P4584 ?firstApprearance}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?familyNameLabel
Try it!

Ermittler-Teams

edit

Bei den Teams sollten die Schauspieler nicht über cast member (P161) hinzugefügt werden. Stattdessen über has part(s) (P527) die Ermittler und denen werden dann über performer (P175) die passenden Schauspieler zugeordent. Von der folgenden Abfrage werden auch nur die Teams gefunden, die über has part(s) (P527) mindestens einen Tatort-Ermittler verknüpft haben. Daher einfach mal in

nachschauen, welche Teams noch nicht gefunden werden und passend ergänzen. 

SELECT ?team (COUNT(?investigator) AS ?members) ?teamLabel (GROUP_CONCAT(DISTINCT(?name);separator=", ") AS ?investigators) ?seriesLabel ?instanceLabel WHERE {
  ?investigator wdt:P31 wd:Q110857263 .
  ?team wdt:P527 ?investigator . ?investigator rdfs:label ?name . FILTER(lang(?name) = "de")      
  ?team wdt:P31 ?instance
  OPTIONAL {?team wdt:P1441 ?series}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?team ?teamLabel ?instance ?instanceLabel ?series ?seriesLabel
ORDER BY ?team
Try it!

Ermittler-Serien

edit 
SELECT ?series ?seriesLabel ?placeLabel (GROUP_CONCAT(DISTINCT(?investigatorName);separator=", ") AS ?investigators) (COUNT(DISTINCT(?film)) AS ?count) (GROUP_CONCAT(DISTINCT(?investigatorOldName);separator=", ") AS ?investigatorsOld) WHERE {
  ?series wdt:P361 wd:Q689438
  OPTIONAL{?film wdt:P179 ?series}
  OPTIONAL{?series wdt:P840 ?place}
  OPTIONAL{?series wdt:P144 ?investigatorOld . ?investigatorOld rdfs:label ?investigatorOldName . FILTER(lang(?investigatorOldName) = "de")}
  OPTIONAL{?series wdt:P674 ?investigator . ?investigator rdfs:label ?investigatorName . FILTER(lang(?investigatorName) = "de")}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?series ?seriesLabel ?place ?placeLabel
ORDER BY DESC(?count) ?seriesLabel
Try it!

Ermittler-Serien mit Auflistung aller ausgestrahlter Folgen

edit 
SELECT ?series ?seriesLabel (COUNT(DISTINCT(?film)) AS ?count) (GROUP_CONCAT(DISTINCT(?film);separator=" ") AS ?films) WHERE {
  ?series wdt:P361 wd:Q689438 .
  ?film wdt:P179 ?series .
  ?film wdt:P577 ?publication FILTER(?publication<NOW())
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?series ?seriesLabel
ORDER BY DESC(?count) ?seriesLabel
Try it!

Tatortfolgen, die noch in keiner Ermittler-Serie sind

edit

Am 2. März 2022 habe ich die Arbeiten insoweit abgeschlossen, dass hier keine bereits ausgestrahlte Folge mehr erscheint. Das heißt, jede Folge ist in mindestens einer Ermittler-Serie. Das heißt aber nicht, dass alles fertig einsortiert ist. Manche Folge gehören nämlich auch in mehrere Serien.

Im Laufe des Jahres 2022 haben sich hier wieder viele Folgen angestaut. Da neben mir keiner diese Arbeit zu tun scheint, blieb alles an mir hängen und ich arbeitete bis zum 17.11.2022 wieder die komplette Liste ab. Dabei waren auch die zukünftigen Folgen für das Ende des Jahres 2022, das vollständige Jahr 2022 ist nun also einsortiert. 

PREFIX v: <http://www.wikidata.org/prop/statement/>

SELECT ?film ?ordinal ?publication ?filmLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication
  FILTER NOT EXISTS {?film wdt:P179 ?otherSeries . ?otherSeries wdt:P361 wd:Q689438 FILTER(?otherSeries != wd:Q110880410)}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(?publication)
Try it!

Tatortfolgen, die in einer Ermittlerserie sind, aber sind, aber noch keine globale Folgennummer tragen

edit 
SELECT ?film ?publication ?filmLabel ?subSeriesLabel ?subSeries WHERE {
  ?film wdt:P179 ?subSeries . ?subSeries wdt:P361 wd:Q689438
  FILTER NOT EXISTS {?film p:P179 ?series . ?series ps:P179 wd:Q689438 . ?series pq:P1545 ?ordinal}
  OPTIONAL{?film wdt:P577 ?publication}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(?publication)
Try it!

Tatort-Regisseure

edit

Die folgende Abfrage kann mit der Liste der Tatort-Regisseure verglichen werden (zum besseren Vergleich sind unten nur die Folgen vor 2022 berücksichtigt). Bei einigen Regisseuren ist in Wikidata auch noch der Nachname einzutragen, wie man der ausgeführten Abfrage schön ansehen kann. Folgen, die noch vollkommen fehlen, findet man über die nächste Abfrage.

Derzeit listet die Abfrage Norbert ter Hall (Q2110132) noch doppelt, wegen der zwei Nachnamen. 

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?dir ?familyName ?director (COUNT(?ordinal) as ?count) (GROUP_CONCAT(?ordinal;separator=", ") AS ?episodes) WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication . FILTER(year(?publication)<2022)
  ?film wdt:P57 ?dir . ?dir rdfs:label ?director . FILTER(lang(?director) = "de")
  OPTIONAL{?dir wdt:P734 ?family . ?family rdfs:label ?familyName .  FILTER(lang(?familyName) = "de")}
}
GROUP BY ?dir ?director ?familyName
ORDER BY ASC(STR(?familyName)) ?director
Try it!

Tatortfolgen mit mehreren Regisseuren

edit

Die folgende Abfrage zeigt alle Folgen, in denen mehre Personen Regie führten. 

PREFIX v: <http://www.wikidata.org/prop/statement/>

SELECT ?film ?ordinal ?publication ?filmLabel (GROUP_CONCAT(DISTINCT(?directorName);separator=", ") AS ?directors) (COUNT(?directorName) AS ?count) WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication .
  ?film wdt:P57 ?dir . ?dir rdfs:label ?directorName . FILTER(lang(?directorName) = "de")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
GROUP BY ?film ?filmLabel ?ordinal ?publication
HAVING (?count > 1)
ORDER BY ?publication
Try it!

Tatortfolgen ohne Regisseur

edit

Die folgende Abfrage zeigt alle Folgen mit Folgennummer, für die noch kein Regisseur eingetragen ist. Am 21. Februar 2022 vollständig von mir abgearbeitet. Liste müsste also leer sein, sofern nichts neues dazu gekommen ist. Auch im Laufe des Jahres 2022 habe ich sie immer wieder abgearbeitet. 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?filmLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication
  FILTER NOT EXISTS {?film wdt:P57 ?director}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(xsd:integer(?ordinal))
Try it!

Tatortfolgen ohne Drehbuchautor

edit

Die folgende Abfrage zeigt alle Folgen, für die noch kein Drehbuchautor eingetragen ist. Von denen gibt es noch relativ viele (225 am 16.11.2022, 232 am 19.04.2023). Hilfe erwünscht! Durch den tollen Einsatz von Baekemm konnte die Anzahl bereits zum 23.04.2023 auf 124 Folgen reduziert werden. Am 24.04.2023 waren es noch 94 Folgen. Am 20.05.2023 waren es erstmals 0 Folgen. Seitdem arbeiten wir de:Benutzer:Jobu0101/Tatort-Autoren ab. Wir könnten damit im Juli oder August 2023 fertig werden. 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?filmLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication
  FILTER NOT EXISTS {?film wdt:P58 ?writer}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(xsd:integer(?ordinal))
Try it!

Tatortfolgen und Drehbuchautoren

edit 
PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?title ?writerLabel ?writer ?imdb WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal . FILTER(xsd:integer(?ordinal)<10000) .
  ?film wdt:P1476 ?title .
  ?film wdt:P577 ?publication .
  OPTIONAL{?film wdt:P58 ?writer OPTIONAL{?writer wdt:P345 ?imdb} }                                                                                        
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(xsd:integer(?ordinal)) ?writerLabel
Try it!

Tatortfolgen mit Drehbuchautoren, die nicht als Autoren tätig sind

edit

Aktuell (20.04.2023) haben wir hier 46 Einträge und alle davon sind in irgendeiner Weise falsch. Entweder ist die falsche Person als Drehbuchautor eingetragen, oder es ist die richtige, ohne dass ihr die Tätigkeit screenwriter (Q28389) (oder zumindest writer (Q36180)) zugeordnet wurde. Hier muss jeder Fall einzeln für sich überprüft und korrigiert werden. 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?title ?writerLabel ?writer ?imdb WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal . FILTER(xsd:integer(?ordinal)<10000) .
  ?film wdt:P1476 ?title .
  ?film wdt:P577 ?publication .
  ?film wdt:P58 ?writer OPTIONAL{?writer wdt:P345 ?imdb} .
  FILTER NOT EXISTS {?writer wdt:P106 ?occ . ?occ wdt:P279* wd:Q36180}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(xsd:integer(?ordinal)) ?writerLabel
Try it!

Tatortfolgen ohne Filmeditor

edit

Die folgende Abfrage zeigt alle Folgen, für die noch kein Filmeditor eingetragen ist. Von denen gibt es noch relativ viele (394 am 19. April bei Erstellung der Abfrage). Hilfe erwünscht! 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?filmLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication
  FILTER NOT EXISTS {?film wdt:P1040 ?editor}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(xsd:integer(?ordinal))
Try it!

Tatortfolgen ohne Instanz

edit 
PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?publication ?filmLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication
  FILTER NOT EXISTS {?film wdt:P31 ?instance}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ASC(xsd:integer(?ordinal))
Try it!

Tatort-Sünden

edit

Ich habe inzwischen schon einige entdeckt und bin leider erst jetzt (21.02.2022) auf die Idee gekommen, sie festzuhalten:

Vollständigkeit von der Liste der Tatort-Ermittler

edit

Zur Prüfung der Vollständigkeit der Liste der Tatort-Ermittler verwende ich unter anderem die folgende Abfrage. 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?ordinal ?film ?publication WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication FILTER(?publication<NOW())
  FILTER NOT EXISTS {?film wdt:P179 ?subseries . VALUES ?subseries {wd:Q110839889 wd:Q110737643 wd:Q110835471 wd:Q110864497 wd:Q110862588 wd:Q110861914 wd:Q110856934 wd:Q110863111 wd:Q110858551 wd:Q110994246 wd:Q110894625 wd:Q110883559 wd:Q110884381 wd:Q110894531 wd:Q110900805 wd:Q110900686 wd:Q110894547 wd:Q110894613 wd:Q110894533 wd:Q110894708 wd:Q115247621 wd:Q110857629 wd:Q110892512 wd:Q110897668 wd:Q110888856 wd:Q110880147 wd:Q110898182 wd:Q110892363 wd:Q110900933 wd:Q110887846 wd:Q110887868 wd:Q110904257 wd:Q110904360 wd:Q110866363 wd:Q110894699 wd:Q110864620 wd:Q110896340 wd:Q110883509 wd:Q110899154 wd:Q110862815 wd:Q110864856 wd:Q110898276 wd:Q111046522 wd:Q111046592 wd:Q110897017 wd:Q110897620 wd:Q110899236 wd:Q111046630 wd:Q110892151 wd:Q110897611 wd:Q110899190 wd:Q111046658 wd:Q111046648 wd:Q111046675 wd:Q111046686 wd:Q110894690 wd:Q111046914 wd:Q110897648 wd:Q110899828 wd:Q111049984 wd:Q110896447 wd:Q111049935 wd:Q110899932 wd:Q110883782 wd:Q110899881 wd:Q110896434 wd:Q110974815 wd:Q110866422 wd:Q111050003 wd:Q111046691 wd:Q111046848 wd:Q111047718 wd:Q111047800 wd:Q111050095 wd:Q110896860 wd:Q111050102 wd:Q110899671} }
}
ORDER BY DESC(xsd:integer(?ordinal))
Try it!

Tatortfolgen mit Ermittler-Serie

edit 
PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?subseries ?publication WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?publication
  OPTIONAL{?film wdt:P179 ?subseries FILTER(?subseries != wd:Q689438)}
}
ORDER BY ?subseries ?publication
Try it!

Offizielle Webseite der Tatortfolgen

edit

Seit dem 19.04.2023 hat nun jede Tatortfolge die passende ARD-Webseite zugeordnet bekommen (mit Ausnahme der 13 ORF-Folgen natürlich). Das sind also 1235 Folgen. Drei Tage zuvor waren es 3-5 Folgen. 

PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?ordinal ?aired ?film ?title ?website ?language WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal .
  ?film wdt:P577 ?aired .
  OPTIONAL {?film p:P856 ?websiteBlock . ?websiteBlock v:P856 ?website OPTIONAL{ ?websiteBlock pq:P407 ?language  } }
  OPTIONAL{?film wdt:P1476 ?title}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
ORDER BY DESC(?aired) DESC(xsd:integer(?ordinal))
Try it!


Tatortfolgen mit anderem deutschen als englischem Label

edit 
PREFIX v: <http://www.wikidata.org/prop/statement/>
SELECT ?film ?ordinal ?deLabel ?enLabel WHERE {
  ?film p:P179 ?series . ?series v:P179 wd:Q689438 . ?series pq:P1545 ?ordinal
  OPTIONAL{?film rdfs:label ?deLabel . FILTER(lang(?deLabel) = "de")}
  OPTIONAL{?film rdfs:label ?enLabel . FILTER(lang(?enLabel) = "en")}
  BIND (COALESCE(STR(?deLabel)=STR(?enLabel),FALSE) AS ?comp)
  FILTER(?comp=FALSE)
}
ORDER BY DESC(xsd:integer(?ordinal))
Try it!
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Jobu0101/Tatort&oldid=1952572892"