User:Jobu0101/Verwaltungsaufbau Deutschlands

Im Februar 2020 habe ich damit begonnen, mich darum zu kümmern, dass der Verwaltungsaufbau Deutschlands lückenlos in Wikidata dargestellt wird.

Die 10795 Gemeinden DeutschlandsEdit

Das erste ZielEdit

Los ging es damit, dafür zu sorgen, dass alle Gemeinden Deutschlands in Wikidata abgebildet werden. Zwar hatte bereits vorher jede Gemeinde ein eigenes Wikidata-Objekt, doch diese waren nicht als Gesamtheit ansprechbar. Hier und da fehlte dies und das und andersherum gab es viele ehemalige Gemeinden, die noch nicht als ehemalig markiert waren.

Glücklicher Weise existiert zu jedem Flächenstaat ein Wikipedia-Artikel, der dessen Gemeinden auflistet. Diese Artikel sind die folgenden:

Also bin ich Bundesland für Bundesland durchgegangen und habe folgendes getan:

  1. Ich habe den entsprechenden Artikel aufgerufen und die dort angegebene Anzahl mit den dort aufgelisteten Gemeinden verglichen.
  2. Ich habe mir mit Wikidata-Abfragen alle Gemeinden ausgeben lassen, die laut Wikidata zu dem entsprechenden Bundesland gehören.
  3. Ich habe die beiden Listen verglichen und hauptsächlich auf Wikidataseite repariert, was zu reparieren war. Am häufigsten mussten ehemaligen Gemeinden der Gemeindestatus entzogen werden. Die Wikipedia-Artikel sind (im Gegensatz zu Wikidata) sehr gut gewartet. Daher habe ich diese als Hauptquelle für meine Arbeit genommen. In den Artikeln fielen nur ein paar Linkfixes an.

Mit anderen Worten: Wikipedia und Wikidata sind nun in sync. Gibt es hier einen Fehler, so lässt der sich höchstwahrscheinlich auf einen Fehler der Wikipedia zurückführen. Ich habe mir vorgenommen, in Zukunft auf die Gemeinden ein Auge zu werfen, damit die Ordnung, für die ich sorgte, bestehen bleibt.

In den folgenden Unterabschnitten präsentiere ich ein paar Abfragen, die das Ergebnis der Arbeit darstellen.

Die 10795 Gemeinden Deutschlands mit GemeindeschlüsselEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT DISTINCT ?muni ?key ?muniLabel WHERE {
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  {?instance wdt:P279+ wd:Q262166} UNION {BIND (wd:Q262166 AS ?instance)}
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P439 ?key
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Die 16 Bundesländer mit Anzahl ihrer GemeindenEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT (?prefix AS ?key) ?stateLabel (COUNT(?key) AS ?count) WHERE{
SELECT DISTINCT ?stateLabel ?muni ?prefix ?key WHERE {
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  {?instance wdt:P279+ wd:Q262166} UNION {BIND (wd:Q262166 AS ?instance)}
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P439 ?key .
  BIND (SUBSTR(?key,1,2) AS ?prefix) .
  ?state wdt:P1388 ?prefix
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
}
GROUP BY ?prefix ?stateLabel
ORDER BY ?stateLabel
Run it!

Gemeinden mit und ohne StadtrechtEdit

Jede Gemeinde Deutschlands sollte über instance of (P31) als municipality of Germany (Q262166) markiert werden. Das geht entweder direkt oder über eine subclass of (P279) municipality of Germany (Q262166). Es hat sich beim Durchforsten der Daten gezeigt, dass man früher mehr dazu tendierte, jeder Gemeinde municipality of Germany (Q262166) direkt zu geben, während man heutzutage Gemeinden mit Stadtrecht stattdessen (und nicht zusätzlich) urban municipality of Germany (Q42744322) gibt. Nun gibt es in den verschiedenen Bundesländern ganz verschiedene Spezialformen von Gemeinden, hier ein paar Beispiele:

Weil dies alles Unterklassen von municipality of Germany (Q262166) (und viele sogar Unterklasse von urban municipality of Germany (Q42744322)) sind, ist es eigentlich nicht mehr notwendig, solchen Gemeinden municipality of Germany (Q262166) bzw. urban municipality of Germany (Q42744322) zusätzlich zu vergeben. In der Regel vertrete ich (und wie ich mitbekommen habe, die meisten hier) in diesen Situationen den Standpunkt, über instance of (P31) die Punkte, die schon als Oberklassen impliziert werden, nicht extra anzugeben. An dieser Stelle möchte ich jedoch eine Ausnahme machen und die folgende harte Regel formulieren:

Jeder Gemeinde Deutschlands sollte über instance of (P31) genau eines der beiden Objekte
zugeordnet werden.

Warum an dieser Stelle diese harte Regel? Die Regel vereinfacht es, Abfragen zu schreiben, die sich auf alle Gemeinden mit und ohne Stadtrecht beziehen. Abfragen, die nach Ober- und Unterklassen suchen, brauchen derzeit viel zu lange. Eine Abfrage, die beispielsweise alle Objekte zählt, die Instanz einer Unterklasse von municipality of Germany (Q262166) sind, produziert einen Timeout:

SELECT (COUNT(?muni) AS ?numberOfGermanMunicipalities) WHERE{
SELECT DISTINCT ?muni WHERE {
  ?muni wdt:P31 ?instance . 
  {?instance wdt:P279+ wd:Q262166} UNION {BIND (wd:Q262166 AS ?instance)}
}
}
Run it!

Lässt man in der vorangegangenen Abfrage den Teil {?instance wdt:P279+ wd:Q262166} UNION weg und sucht damit nicht mehr nach Instanzen von echten Unterklassen, sondern nur noch nach direkten Instanzen, liefert einem die Software in unter einer Sekunde das Ergebnis.

Es ist von großem Interesse, schnell auf alle Gemeinden Deutschlands zugreifen zu können. Daher also diese harte Regel. Die Arbeiten, diese harte Regel durchzusetzen, wurden am 24. Februar 2020 erfolgreich abgeschlossen. Im Folgenden die passenden Abfragen.

Die 10795 Gemeinden Deutschlands (dank harter Regel)Edit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?muniLabel ?instanceLabel WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?muniLabel
Run it!

Die 8741 Gemeinden Deutschlands ohne Stadtrecht (dank harter Regel)Edit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?muniLabel WHERE {
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 wd:Q262166 .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?muniLabel
Run it!

Die 2054 Gemeinden Deutschlands mit Stadtrecht (dank harter Regel)Edit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?muniLabel WHERE {
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 wd:Q42744322.
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?muniLabel
Run it!

AufräumarbeitenEdit

Immer wieder muss hier einmal nachgebessert werden. Zur Zeit werden drei Gemeinden zuviel gefunden (Stand 24.08.2020), diese sind Q32165546, Q95993845, Q95976355. Mithilfe is erwünscht.

EinwohnerEdit

Von Ende Februar 2020 bis Mitte März 2020 ging ich alle Gemeinden durch und trug die aktuellsten verfügbaren Einwohnerzahlen aus dem Statistikportal ein. Das sind die Daten vom 30. September 2019. Schöner wäre natürlich der 31. Dezember 2019, aber darauf müssen wir noch etwas warten. Ziel der Aktion ist nicht nur, aktuelle Daten in Wikidata zu haben, sondern auch endlich einmal die Gemeinden untereinander vergleichen zu können. Bislang verglich man Zahlen, die zu verschiedenen Zeitpunkten und vielleicht mit verschiedenen Methoden erhoben wurden. Dem bereitete ich ein Ende. Die Arbeiten wurden am 15. März 2020 erfolgreich abgeschlossen.

AusnahmenEdit

Vier Gemeinden sind bislang noch nicht im Statistikportal hinterlegt. Grund dafür ist, dass sie erst nach dem 30.09.2019 entstanden sind. Es handelt sich um die folgenden Gemeinden:

Gemeinden mit Gründung nach dem 30. September 2019Edit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?instanceLabel ?inception WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P571 ?inception FILTER(?inception > "2019-09-30"^^xsd:dateTime)
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Gemeinden ohne Einwohner-Aktualisierung vom 30. September 2019Edit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?instanceLabel WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  FILTER NOT EXISTS {
    ?muni p:P1082 ?populationBlock .
    ?populationBlock wikibase:rank wikibase:PreferredRank .
    ?populationBlock pq:P585 "2019-09-30"^^xsd:dateTime
  }
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Gemeinden mit Einwohner-Aktualisierung vom 30. September 2019Edit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?instanceLabel ?population WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni p:P1082 ?populationBlock .
  ?populationBlock v:P1082 ?population .
  ?populationBlock wikibase:rank wikibase:PreferredRank .
  ?populationBlock pq:P585 "2019-09-30"^^xsd:dateTime
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Gemeinden mit vom 30. September 2019 verschiedenen EinwohnerzahlenEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?instanceLabel ?population WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni p:P1082 ?populationBlock .
  ?populationBlock v:P1082 ?population .
  ?populationBlock wikibase:rank wikibase:PreferredRank .
  ?populationBlock pq:P585 ?popDate FILTER(?popDate!="2019-09-30"^^xsd:dateTime)
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Die 10795 deutschen Gemeinden mit EinwohnerzahlenEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?population ?instanceLabel WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P1082 ?population
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Einwohner pro Bundesland und Durchschnitt pro GemeideEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?state ?stateLabel (COUNT(?muni) AS ?munis) (SUM(?pop) AS ?population) (ROUND(AVG(?pop)) AS ?average) WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P1082 ?pop .
  BIND (SUBSTR(?key,1,2) AS ?prefix) . ?state wdt:P1388 ?prefix
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?state ?stateLabel
ORDER BY ?average
Run it!

Einwohner gruppiert nach GemeindenanfangsbuchstabeEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?firstLetter (COUNT(?muni) AS ?munis) (ROUND(MIN(?pop)) AS ?min) (ROUND(AVG(?pop)) AS ?average) (ROUND(MAX(?pop)) AS ?max) (SUM(?pop) AS ?population) WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P1082 ?pop .
  ?muni rdfs:label ?muniName . FILTER(lang(?muniName) = "de") .
  BIND (SUBSTR(?muniName,1,1) AS ?firstLetter)
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?firstLetter
ORDER BY ?firstLetter
Run it!

Die größten Gemeinden mit gegebenem GemeindenanfangsbuchstabenEdit

SELECT ?firstLetter ?muni ?key ?muniName ?population WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni wdt:P439 ?key .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock ps:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P1082 ?population .
  ?muni rdfs:label ?muniName . FILTER(lang(?muniName) = "de") .
  BIND(STR(SUBSTR(?muniName,1,1)) AS ?firstLetter) . FILTER(?firstLetter="B")
}
ORDER BY DESC(?population)
LIMIT 5
Run it!

Die 294 Landkreise DeutschlandsEdit

Die 13 Flächenländer Deutschlands sind in Landkreise unterteilt, die sich dann wiederrum in die ihnen zugehörigen Gemeinden untergliedern. Ich habe dafür gesorgt, dass es zu jedem Flächenland eine Klasse gibt, die dessen Landkreise vereint. Für einige Flächenländer war diese Klasse bereits vorhanden, für andere musste ich sie neuanlegen. Über located in the administrative territorial entity (P131) ordnete ich jeder Klasse ihr Bundesland zu (das war in kaum einer Klasse (vielleicht sogar keiner) bereits getan). Die größere Arbeit war jedoch, jeden Kreis in die passende Klasse einzuordnen. Das war selbst bei bereits vorhandenen Klassen nur sehr vereinzelt getan. Die folgenden Abfragen präsentieren das Ergebnis.

Abfragen: Die Kreisklassen und LandkreiseEdit

Die 13 deutschen Kreisklassen mit Anzahl ihrer KreiseEdit

SELECT  ?class ?classLabel ?stateLabel (COUNT(?rural) AS ?count) WHERE {
  ?class wdt:P279 wd:Q106658 .
  ?class wdt:P131 ?state .
  ?rural wdt:P31 ?class .
  FILTER NOT EXISTS {?rural wdt:P576 ?dissolved}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?class ?classLabel ?stateLabel
ORDER BY ?stateLabel
Run it!

Die 294 Landkreise Deutschlands mit Kreisschlüssel und KreisklasseEdit

SELECT ?rural ?key ?ruralLabel ?classLabel WHERE {
  ?rural wdt:P31 ?class .
  ?rural wdt:P440 ?key .
  ?class wdt:P279 wd:Q106658 .
  FILTER NOT EXISTS {?rural wdt:P576 ?dissolved}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

KreisstädteEdit

Ich habe dafür gesorgt, dass jedem Landkreis Deutschlands über capital (P36) sein Verwaltungssitz zugeordnet ist. Diesen nennt man, sofern der Verwaltungssitz Stadtrechte hat, auch Kreisstadt. Anderenfalls sagt man Kreishauptort. Es gibt nur einen Landkreis, dessen Verwaltungssitz keine Stadtrechte besitzt, das ist der bayerische Landkreis Garmisch-Partenkirchen (Q10518) mit Kreishauptort Garmisch-Partenkirchen (Q127043). Der Einfachheit halber werde ich für den Rest des Dokuments den Begriff Kreisstadt auf für diesen Landkreis benutzen.

Andersherum habe ich dafür gesorgt, dass jeder Kreisstadt über capital of (P1376) ihr Landkreis zugeordnet wird. Darüber hinaus hat jede Kreisstadt instance of (P31) district capital (Q134626) bekommen. Bei all diesen Arbeiten ist auch immer gegenzuprüfen, dass nicht etwa andere Wikidata-Objekte, die gar keine Kreisstädte (mehr) sind, noch als entsprechende eingetragen sind. All dies ist geschehen, wie die folgenden Abfragen bezeugen.

Abfragen TODO.

107 kreisfreie StädteEdit

In Deutschland gibt es 107 kreisfreie Städte. Ich habe dafür gesorgt, dass wir für jedes Bundesland eine eigene Klasse haben, in die die kreisfreien Städte dieses Bundeslandes einsortiert werden (Ausnahme ist das Saarland, welches keine einzige kreisfreie Stadt besitzt). Diese Einsortierung habe ich im Februar 2020 durchgeführt und abgeschlossen. Eine andere Möglichkeit, auf die kreisfreien Städte zuzugreifen, ermöglicht der amtliche Gemeindeschlüssel. Der amtliche Gemeindeschlüssel einer Gemeinde endet nämlich genau dann auf "000", wenn sie kreisfrei ist.

Die 15 Klassen für kreisefreie Städte des jeweiligen Bundeslandes mit Anzahl der kreisfreien StädteEdit

SELECT ?class ?classLabel ?stateLabel (COUNT(?city) AS ?urbanDistricts)  WHERE{
  ?class wdt:P279 wd:Q22865 .
  ?class wdt:P131 ?state .
  ?city wdt:P31 ?class .
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?class ?classLabel ?stateLabel
ORDER BY ?stateLabel
Run it!

Die 107 kreisfreien Städte Deutschlands sortiert nach Bundesland und dann EinwohnernEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?city ?key ?cityLabel ?population ?classLabel ?stateLabel  WHERE{
  ?class wdt:P279 wd:Q22865 .
  ?city wdt:P31 ?class .
  ?class wdt:P131 ?state .
  ?city wdt:P439 ?key .
  ?city wdt:P1082 ?population
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?stateLabel DESC(?population)
Run it!

Die 107 kreisfreien Städte Deutschlands über den amtlichen GemeindeschlüsselEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P439 ?key .
  BIND (SUBSTR(?key,6,3) AS ?keyEnd) . FILTER(?keyEnd="000")
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Gemeinden der LandkreiseEdit

Die 10795 Gemeinden Deutschlands gliedern sich in 107 kreisfreie Städte und 10688 kreisangehörige Gemeinden. Um letztere und deren Landkreis-Zuordnung geht es in diesem Abschnitt.

Die 294 Landkreise mit Anzahl der angehörigen GemeindenEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?rural ?key ?ruralLabel ?classLabel (COUNT(?muni) AS ?munis) WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni p:P31 ?instanceBlock . ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end}
  ?muni wdt:P131 ?rural .
  ?rural wdt:P31 ?class .
  ?rural wdt:P440 ?key .
  ?class wdt:P279 wd:Q106658
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?rural ?key ?ruralLabel ?classLabel
ORDER BY ?key
Run it!

Die 10688 kreisangehörigen Gemeinden Deutschlands mit Landkreis nach amtlichem GemeindeschlüsselEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?instanceLabel ?ruralKey ?ruralLabel ?rural WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P439 ?key .
  BIND (SUBSTR(?key,6,3) AS ?keyEnd) . FILTER(?keyEnd!="000") .
  BIND (SUBSTR(?key,1,5) AS ?ruralKey) .
  ?rural wdt:P440 ?ruralKey
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Gemeinden, denen die Zuordnung eines Landkreis fehltEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?muni ?key ?muniLabel ?instanceLabel ?ruralKey ?ruralLabel ?rural WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?muni wdt:P439 ?key .
  BIND (SUBSTR(?key,6,3) AS ?keyEnd) . FILTER(?keyEnd!="000") .
  BIND (SUBSTR(?key,1,5) AS ?ruralKey) .
  ?rural wdt:P440 ?ruralKey
  FILTER NOT EXISTS {?muni wdt:P131 ?rural}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

Am 9. März 2020 fehlten noch 584 Gemeinden. Dies blieb so bis zum 20. März, an dem ich die Arbeit aufnahm.

Gemeinden, die noch einem aufgelösten Landkreis angehörenEdit

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?rural ?key ?ruralLabel ?classLabel ?muniLabel ?muni WHERE {
  VALUES ?instance {wd:Q262166 wd:Q42744322} .
  ?muni p:P31 ?instanceBlock . ?instanceBlock v:P31 ?instance .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end}
  ?muni wdt:P131 ?rural .
  ?rural wdt:P31 ?class .
  ?rural wdt:P440 ?key .
  ?rural wdt:P576 ?dissolved .
  ?class wdt:P279 wd:Q106658
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
ORDER BY ?key
Run it!

NachbarkreiseEdit

Balû nimmt sich gerade (Anfang bis Mitte März 2020) der Arbeit an, jedem Landkreis über shares border with (P47) seine Nachbarkreise zuzuordnen. Der Stand der Arbeit kann über die folgende Abfrage eingesehen werden.

PREFIX p: <http://www.wikidata.org/prop/>
PREFIX v: <http://www.wikidata.org/prop/statement/>
PREFIX pq: <http://www.wikidata.org/prop/qualifier/>

SELECT ?rural ?key ?ruralLabel (COUNT(?neighbor) AS ?count) (GROUP_CONCAT(?neighborName;separator=", ") AS ?neighbors)  WHERE {
  ?rural p:P31 ?instanceBlock . 
  ?instanceBlock v:P31 ?class .
  FILTER NOT EXISTS {?instanceBlock pq:P582 ?end} .
  ?class wdt:P279 wd:Q106658 .
  ?rural wdt:P440 ?key .
  OPTIONAL{?rural wdt:P47 ?neighbor . ?neighbor wdt:P31 ?nClass . ?nClass wdt:P279 wd:Q106658 . ?neighbor rdfs:label ?neighborName . FILTER(lang(?neighborName) = "de")}
  SERVICE wikibase:label{bd:serviceParam wikibase:language "de"}
}
GROUP BY ?rural ?key ?ruralLabel
ORDER BY ?key
Run it!