User:Kleeblatt187/Streets

Kurzlinks

• nur für Chemnitz: https://w.wiki/4wfz
• nur für Dresden: https://w.wiki/4wfx
• nur für Leipzig: https://w.wiki/4wg2
• für Sachsen komplett: https://w.wiki/4wg3
• Legende:
  • 7FFF00 (hellgrün): mit Koordinaten, Bild und Commons-Kategorie bei Wikidata hinterlegt
  • 00008b (blau): nur mit Koordinaten und Bild bei Wikidata, aber ohne Commons-Kategorie
  • 009500 (dunkelgrün): nur mit Koordinaten und Commons-Kategorie bei Wikidata, ohne Bild
  • ff0000 (rot): nur mit Koordinaten bei Wikidata, aber ohne Bild und ohne Commons-Kategorie

Straßen als Karte: Chemnitz und Dresden

In Anlehnung an diese Abfrage für Dresden, aber ergänzt um Chemnitz-spezifische Anpassung:

• Abfrage aller Innerortsstraßen, die in Dresden (alle; keine bei Stadtteilen o.ä.) oder in Chemnitz (keine) oder in einem der Chemnitzer Stadtteile (alle) liegen
• Voraussetzung für die Darstellung auf der Karte: Koordinate an Straße bei Wikidata hinterlegt (für Dresden und Chemnitz vollständig erledigt)
• ergänzende Farben, um mehr Konstellationen darzustellen

PREFIX schema: <http://schema.org/>
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?image 
   ?commons2 ?coordinate ?status ?rgb
WHERE {
{
   ?item wdt:P31 wd:Q79007 .                                # Innerortsstraße 
   {?item wdt:P131 wd:Q1731.}                               # ... liegt in der Verwaltungseinheit Dresden ...
          UNION                                                       # ... oder     (eigentlich ein "und")
  {?item wdt:P131 wd:Q2795.}                               # ... liegt in der Verwaltungseinheit Chemnitz ...
          UNION                                                       # ... oder     (eigentlich ein "und")
   {?item wdt:P131 ?Stadtteil . ?Stadtteil wdt:P131 wd:Q2795. }     # ... in einer Unter-Verwaltungseinheit von Chemnitz
}
  OPTIONAL { ?item wdt:P373 ?commons. } 
  OPTIONAL { ?item wdt:P18 ?image. }                                 
  OPTIONAL { ?item wdt:P625 ?coordinate. }                          
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
   
  BIND(BOUND(?commons) && strlen(?commons)>0 as ?check_cat)          
  BIND(BOUND(?image) as ?check_img)                                  
   
  BIND(  IF( ?check_img , "image",
         IF( ?check_cat , "category",   
            "no cat")) AS ?status).

  BIND(  IF( ?check_img && ?check_cat, "7FFF00",     # 7FFF00 hellgrün:    mit Koordinaten, Bild und Commons-Kategorie bei Wikidata hinterlegt
         IF( ?check_img , "00008B",                  # 00008b blau:        nur mit Koordinaten und Bild bei Wikidata, aber ohne Commons-Kategorie
         IF( ?check_cat , "009500",                  # 009500 dunkelgrün:  nur mit Koordinaten bei Wikidata und Commons-Kategorie, ohne Bild bei Wikidata
            "#ff0000"))) AS ?rgb).                   # ff0000 rot:         andernfalls, also nur Koordinaten bei Wikidata, aber ohne Bild und ohne Commons-Kategorie  
  OPTIONAL {?commons2 	schema:about ?item ;
           schema:isPartOf <https://commons.wikimedia.org/> .
  } 
}

Try it!

Straßen als Karte: Sachsen

In Anlehnung an diese Abfrage für Dresden und obige Darstellung, aber erweitert auf ganz Sachsen:

• Abfrage aller Innerortsstraßen, die in Sachsen bzw. einer Unterverwaltungseinheit davon liegen
• Voraussetzung für die Darstellung auf der Karte: Koordinate an Straße bei Wikidata hinterlegt
• vier Farben, um verschiedene Konstellationen darzustellen

PREFIX schema: <http://schema.org/>
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?image 
   ?commons2 ?coordinate ?status ?rgb

WHERE 
 { ?item (wdt:P131|wdt:1001) ?sub0 . ?tree0 (wdt:P150)* ?sub0 . ?tree0 (wdt:P131)* wd:Q1202 .   # Unterverwaltungseinheit von Sachsen
    ?item wdt:P31 wd:Q79007 .     # Innerortsstraße 
  OPTIONAL { ?item wdt:P373 ?commons. } 
  OPTIONAL { ?item wdt:P18 ?image. }                                 
  OPTIONAL { ?item wdt:P625 ?coordinate. }                          
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
   
  BIND(BOUND(?commons) && strlen(?commons)>0 as ?check_cat)          
  BIND(BOUND(?image) as ?check_img)                                  
   
  BIND(  IF( ?check_img , "image",
         IF( ?check_cat , "category",   
            "no cat")) AS ?status).

  BIND(  IF( ?check_img && ?check_cat, "7FFF00",     # 7FFF00 hellgrün:    mit Koordinaten, Bild und Commons-Kategorie bei Wikidata hinterlegt
         IF( ?check_img , "00008B",                  # 00008b blau:        nur mit Koordinaten und Bild bei Wikidata, aber ohne Commons-Kategorie
         IF( ?check_cat , "009500",                  # 009500 dunkelgrün:  nur mit Koordinaten bei Wikidata und Commons-Kategorie, ohne Bild bei Wikidata
            "#ff0000"))) AS ?rgb).                   # ff0000 rot:         andernfalls, also nur Koordinaten bei Wikidata, aber ohne Bild und ohne Commons-Kategorie
  OPTIONAL {?commons2 	schema:about ?item ;
           schema:isPartOf <https://commons.wikimedia.org/> .
  }
}

Try it!