Vanished user adhmfdfmykrdyr

Babel user information
en-N This user has a native understanding of English. es-1 Esta persona tiene un conocimiento básico del español.
Users by language

Sample queries

Count by birth year of male versus female Finnish artists starting in 1760

#defaultView:LineChart
SELECT ?year (COUNT(?_gender) AS ?count)  (SAMPLE(?_genderLabel) AS ?_genderLabel)  WHERE {
 ?item wdt:P27 wd:Q33.
   ?item wdt:P106/wdt:P279* wd:Q483501.
 ?item wdt:P569 ?_date.
 ?item wdt:P21 ?_gender.
 ?_gender rdfs:label ?_genderLabel.
 BIND(str(YEAR(?_date)) AS ?year)
 FILTER((LANG(?_genderLabel)) = "en")
 FILTER(?_date >= "1760-00-00T00:00:00Z"^^xsd:dateTime)
}
GROUP BY ?_genderLabel ?year
HAVING (?count > 1)

Try it!

Popular class for Paralympic swimmers

#Paralympic swiming class popularity

#added before 2016-10
#illustrates bubblechart view, count

#defaultView:BubbleChart
SELECT ?swimmingClassLabel (COUNT(?person) AS ?count)
WHERE
{
    ?person wdt:P106 wd:Q10843402.
	?person wdt:P2094 ?swimmingClass.
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?swimmingClassLabel

Try it!

Female Spanish writers with no image on Wikidata and an article on Spanish Wikipedia

#Female Spanish writers with no image on Wikidata and an article on Spanish Wikipedia


SELECT DISTINCT ?spanishfemalewriter ?spanishfemalewriterLabel WHERE {
  ?spanishfemalewriter wdt:P106 wd:Q36180.
  ?spanishfemalewriter wdt:P27 wd:Q29.
  ?spanishfemalewriter wdt:P21 wd:Q6581072.
  ?spanishfemalewriter wdt:P31 wd:Q5.
  OPTIONAL { ?spanishfemalewriter wdt:P18 ?img . }
  
	FILTER EXISTS { ?sitelink schema:about ?item. ?sitelink schema:inLanguage "es" }
   SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
  FILTER(!BOUND(?img))
}

Try it!

Headcoaches of wheelchair basketball teams

#Headcoaches of wheelchair basketball teams


SELECT ?item ?itemLabel ?coachname ?coachnameLabel WHERE {
  ?item wdt:P31 wd:Q1194951.
  ?item wdt:P641 wd:Q1128216.
  OPTIONAL { ?item wdt:P286 ?coachname. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Location of streets in Madrid named after women with articles on Spanish Wikipedia

#Location of streets in Madrid named after women with articles on Spanish Wikipedia
PREFIX schema: <http://schema.org/>
#defaultView:Map
#Streets in Madrid named after a woman with a Spanish Wikipedia article
SELECT ?item ?itemLabel ?sitelink ?coor WHERE {
  ?item wdt:P31 wd:Q79007.
  ?item wdt:P17 wd:Q29.
  ?item wdt:P138 ?named.
  ?named wdt:P21 wd:Q6581072.
  ?sitelink schema:about ?item.
  ?sitelink schema:inLanguage "es".
  ?item wdt:P625 ?coor.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}

Try it!

Streets in Spain named after women with articles on Spanish Wikipedia

#Streets in Spain named after women with articles on Spanish Wikipedia
PREFIX schema: <http://schema.org/>

#Streets in Spain named after a woman with a Spanish Wikipedia article
SELECT ?item ?itemLabel ?sitelink WHERE {
  ?item wdt:P31 wd:Q79007.
  ?item wdt:P17 wd:Q29.
  ?item wdt:P138 ?named.
  ?named wdt:P21 wd:Q6581072.
  ?sitelink schema:about ?item.
  ?sitelink schema:inLanguage "es".
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}

Try it!

Streets in Madrid named after a woman with a Spanish Wikipedia article

#Streets in Madrid named after a woman with a Spanish Wikipedia article


SELECT ?item ?itemLabel ?sitelink
WHERE
{
	# instance of = street
  	?item wdt:P31 wd:Q79007. 

  	# located in = Madrid (Q2807)
  	{ ?item wdt:P131 wd:Q2807 }

        # person = female (Q6581072)
  	{   ?item wdt:P138 ?named.
  ?named wdt:P21 wd:Q6581072. }
 
	# look for articles (sitelinks) in Spanish ("es")
  	{ ?sitelink schema:about ?item . ?sitelink schema:inLanguage "es" }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es" }
}

Try it!

People who have competed at the Winter Paralympic Games

#People who have competed at the Winter Paralympic Games


SELECT DISTINCT ?itemLabel ?gamesLabel ?nationalityLabel ?occupationLabel ?birthLabel
WHERE
{
	?item wdt:P1344 ?games .
    ?games wdt:P31 wd:Q3317976 .
	?item wdt:P27 ?nationality .
	?item wdt:P106 ?occupation .
	?item wdt:P19 ?birth .
   
	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

LIMIT 10000

Try it!