User:Metamorforme42/MEC

#Papers about both MEC and 5G network slicing

SELECT ?date ?item (CONCAT(?title, COALESCE((CONCAT(': ', (COALESCE(?subtitle_qualifier, ?subtitle)))), '')) AS ?itemLabel) (URI(CONCAT('https://doi.org/', ENCODE_FOR_URI(?doi))) AS ?doilink) WHERE {
  ?item wdt:P921 wd:Q65053087.
  ?item wdt:P921 wd:Q25325231.
  ?item wdt:P356 ?doi.
  OPTIONAL { ?item wdt:P577 ?date. }
  OPTIONAL { ?item wdt:P1476 ?title. }
  OPTIONAL { ?item p:P1476 ?title_statement. ?title_statement pq:P1680 ?subtitle_qualifier. }
  OPTIONAL { ?item wdt:P1680 ?subtitle. }
}
ORDER BY DESC(?date)
LIMIT 100

Try it!

#Citation graph of papers about both MEC and 5G network slicing

#defaultView:Graph
SELECT ?date ?item (CONCAT(?title, COALESCE((CONCAT(': ', (COALESCE(?subtitle_qualifier, ?subtitle)))), '')) AS ?itemLabel) (URI(CONCAT('https://doi.org/', ENCODE_FOR_URI(?doi))) AS ?doilink) ?linkTo WHERE {
  ?item wdt:P921 wd:Q65053087.
  ?item wdt:P921 wd:Q25325231.
  ?item wdt:P356 ?doi.
  OPTIONAL { ?item wdt:P577 ?date. }
  OPTIONAL { ?item wdt:P1476 ?title. }
  OPTIONAL { ?item p:P1476 ?title_statement. ?title_statement pq:P1680 ?subtitle_qualifier. }
  OPTIONAL { ?item wdt:P1680 ?subtitle. }
  OPTIONAL { ?item wdt:P2860 ?linkTo. }
}
ORDER BY DESC(?date)
LIMIT 100

Try it!

# ETSI ISG MEC White papers

SELECT ?work ?edition_number ?item ?date (CONCAT(?title, COALESCE((CONCAT(': ', (COALESCE(?subtitle_qualifier, ?subtitle)))), '')) AS ?itemLabel) ?pdf ?isbn13 WHERE {
  ?work wdt:P31 wd:Q47461344 ; wdt:P50 wd:Q113627075 ; wdt:P136 wd:Q223729.
  ?work wdt:P747 ?item. ?item wdt:P393 ?edition_number.
  OPTIONAL { ?item wdt:P577 ?date. }
  OPTIONAL { ?item wdt:P1476 ?title. }
  OPTIONAL { ?item p:P1476 ?title_statement. ?title_statement pq:P1680 ?subtitle_qualifier. }
  OPTIONAL { ?item wdt:P1680 ?subtitle. }
  OPTIONAL { ?item wdt:P212 ?isbn13. }
  OPTIONAL { ?item p:P953 ?link_statement. ?link_statement ps:P953 ?pdf; pq:P2701 wd:Q42332.  }
}

Try it!