Wikidata

User:Mfilot/Wikidata Query Service Queries

< User:Mfilot

Queries edit

Schweizer Unternehmen edit 

#Schweizer Unternehmen
#defaultView:Table
SELECT ?item ?itemLabel ?uid ?rechtsformLabel ?hauptverwaltungLabel ?logo  WHERE {
  ?item wdt:P17 wd:Q39.
  ?item wdt:P31 wd:Q4830453.
  OPTIONAL {?item wdt:P1454 ?rechtsform}
  OPTIONAL {?item wdt:P159 ?hauptverwaltung}
  OPTIONAL {?item wdt:P4829 ?uid}
  OPTIONAL {?item wdt:P154 ?logo}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it,en". }
}
ORDER BY ?itemLabel
LIMIT 300

P26 duration more than x years edit 

 #P26 duration more than x years
 SELECT ?person ?personLabel ?duration ?someone ?someoneLabel
 WHERE
 {
   ?person wdt:P31 wd:Q5. 
   ?person p:P26 [
     ps:P26 ?someone;
     pq:P580 ?start;
     pq:P582 ?end].
  BIND(ROUND((?end - ?start)/365.2425) AS ?duration).
  FILTER(?duration > 80). 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
 }
 ORDER BY DESC(?duration)
 Limit 50

Number of articles for items with instance of (P31) Gemeinde der Schweiz (Q70208) per language edit 

 #Number of articles for items with instance of (P31) Gemeinde der Schweiz (Q70208) per language
 SELECT ?lang (COUNT(DISTINCT ?item) AS ?count) WHERE {
   ?item wdt:P31 wd:Q70208 .    
   ?article schema:about ?item .
   FILTER (SUBSTR(str(?article), 11, 15) = ".wikipedia.org/") .
   ?article schema:inLanguage ?lang .
 } GROUP BY ?lang
 ORDER BY DESC (?count)

Number of Wikipedia articels for items with instance of (P31) Gemeinde der Schweiz (Q70208) edit 

#Numbers of Wikipedia sitelinks for items with instance of (P31) Gemeinde der Schweiz (Q70208)
 SELECT ?item ?itemLabel (COUNT(DISTINCT ?lang) AS ?count) WHERE {
   ?item wdt:P31 wd:Q70208 .    
   ?article schema:about ?item .
   FILTER (SUBSTR(str(?article), 11, 15) = ".wikipedia.org/") .
   ?article schema:inLanguage ?lang .
   SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it". }
 } GROUP BY ?item ?itemLabel
 ORDER BY DESC (?count)

Count number of articles for human with citizenship of Switzerland edit 

#Count number of articles for human (Q5) with citizenship of Switzerland (Q39)
SELECT ?item ?itemLabel (COUNT(DISTINCT ?lang) AS ?count) WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P27 wd:Q39.
  ?article schema:about ?item.
  ?article schema:inLanguage ?lang.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it". }
  FILTER((SUBSTR(STR(?article), 11, 15)) = ".wikipedia.org/")
}
GROUP BY ?item ?itemLabel
ORDER BY DESC(?count)

Railway tunnel in Switzerland edit

Railway tunnel in Switzerland (Simple Query) edit 

#Railway tunnel in Switzerland
#defaultView:Table
SELECT ?item ?itemLabel ?laenge ?unitlaengeLabel
WHERE {
  ?item wdt:P31 wd:Q1311958.
  ?item wdt:P17 wd:Q39.
  OPTIONAL { ?item p:P2043/psv:P2043 [ wikibase:quantityAmount ?laenge ;
                                       wikibase:quantityUnit ?unitlaenge ].}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, fr, it". }
}
ORDER BY DESC (?laenge)

Exclude tunnel projects edit 

#Railway tunnel in Switzerland without tunnel projects
#defaultView:Table
SELECT ?item ?itemLabel ?laenge ?unitlaengeLabel
WHERE {
  ?item wdt:P31 wd:Q1311958.
  ?item wdt:P17 wd:Q39.
  OPTIONAL { ?item p:P2043/psv:P2043 [ wikibase:quantityAmount ?laenge ;
                                       wikibase:quantityUnit ?unitlaenge ].}
  MINUS {?item wdt:P31 wd:Q27464969}   # <-- Exclude tunnelprojects
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, fr, it". }
}
ORDER BY DESC (?laenge)

Exclude railway tunnels that aren't used as railway tunnel any more edit 

#Railway tunnel in Switzerland without tunnel projects and tunnels that aren't used as railway tunnel any more
#defaultView:Table
SELECT ?item ?itemLabel ?laenge ?unitlaengeLabel
WHERE {
  ?item p:P31 ?eisenbahntunnel.
  ?eisenbahntunnel ps:P31 wd:Q1311958.
  ?item wdt:P17 wd:Q39.
  OPTIONAL { ?item p:P2043/psv:P2043 [ wikibase:quantityAmount ?laenge ;
                                       wikibase:quantityUnit ?unitlaenge ].}
  MINUS {?item wdt:P31 wd:Q27464969} 
  FILTER NOT EXISTS { ?eisenbahntunnel pq:P582 ?x } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, fr, it". }
}
ORDER BY DESC (?laenge)

Railway tunnels lenght (in m) in Switzerland edit

convert all tunnel length to meter 

#Railway tunnels lenght (in m) in Switzerland without tunnel projects and tunnels that aren't used as railway tunnel any more 
#defaultView:Table
SELECT DISTINCT ?item ?itemLabel ?laenge ?unitlaengeLabel
WHERE {
  ?item p:P31 ?eisenbahntunnel.
  ?eisenbahntunnel ps:P31/wdt:P279* wd:Q1311958.
  ?item wdt:P17 wd:Q39.
  OPTIONAL { ?item p:P2043/psn:P2043 [ wikibase:quantityAmount ?laenge ;
                                       wikibase:quantityUnit ?unitlaenge ].}
  MINUS {?item wdt:P31 wd:Q27464969} 
  FILTER NOT EXISTS { ?eisenbahntunnel pq:P582 ?x }   
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, fr, it". }
}
ORDER BY DESC (?laenge)

See also SPARQL Wikibook Chapter Normalised units

DISTINCT ist notwendig, da einige Objekte sowohl als railway tunnel (Q1311958), als auch Objekt, dass subclass of (P279) von railway tunnel (Q1311958) ist.

Bahnhöfe im Kanton Bern edit 

#defaultView:Map
SELECT ?bahnhof ?bahnhofLabel ?bahnhofnr ?loc WHERE {
  ?bahnhof wdt:P31 wd:Q55488.
  ?bahnhof wdt:P131/wdt:P131* wd:Q11911.
  OPTIONAL { ?bahnhof wdt:P625 ?loc } .
  OPTIONAL { ?bahnhof wdt:P954 ?bahnhofnr } .
    SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de".
  }
}

Gemeindepräsidenten der Stadt Bern edit

a.k.a Stadtpräsidenten 

#Stadtpräsidenten der Stadt Bern
#defaultView:Timeline
SELECT ?Person ?PersonLabel ?start ?end ?bild  WHERE {
  ?Person wdt:P31 wd:Q5.
  ?Person p:P39 ?amt.
  ?amt ps:P39 wd:Q1268257.
  ?amt pq:P642 wd:Q70.
  ?amt pq:P580 ?start.
  ?amt pq:P582 ?end.
  OPTIONAL {?Person wdt:P18 ?bild}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr". }
}
LIMIT 30

Gemeindepräsidenten edit 

#Gemeindepräsidenten
SELECT ?Person ?PersonLabel ?gemeinde ?gemeindeLabel WHERE {
  ?Person wdt:P31 wd:Q5.
  ?Person p:P39 ?amt.
  ?amt ps:P39 wd:Q1268257.
  ?amt pq:P642 ?gemeinde.
  OPTIONAL {?Person wdt:P18 ?bild}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr". }
}
LIMIT 30

Flüsse die in die Aare münden edit 

PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?linkTo {
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q1675 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:maxVisited 4 ;
                gas:linkType wdt:P403 .
  }
  OPTIONAL { ?item wdt:P403 ?linkTo }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,fr" }
}

Flüsse die in die Aare münden edit

Mit Länge, Abflussmenge... 

PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?linkTo ?laenge ?abflussmenge {
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q1675 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:maxVisited 4 ;
                gas:linkType wdt:P403 .
  }
  OPTIONAL { ?item wdt:P403 ?linkTo }
  OPTIONAL { ?item wdt:P2043 ?laenge }
  OPTIONAL { ?item wdt:P2225 ?abflussmenge}
  MINUS { ?linkTo wdt:P31 wd:Q131681 } 
  MINUS { ?linkTo wdt:P31 wd:Q23397 }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "de,fr" }
}

Bevölkerung von Bern V01 edit

  • zu verbessern: nur einen Wert pro Jahr berücksichtigen
#Population of Bern (Q70) after 1900

SELECT (YEAR(?date) AS ?year) ?population (?objectLabel AS ?Location) WHERE {
  ?object p:P1082 ?populationStatement.
  ?populationStatement ps:P1082 ?population.
  ?populationStatement pq:P585 ?date.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,fr". }
  FILTER((YEAR(?date)) >= 1900).
  FILTER( ?object = wd:Q70 )
}
ORDER BY ?year

Bevölkerung von Bern V02 edit 

#Population of Bern (Q70) after 1900

SELECT ?objectLabel ?year (MAX(?pop) AS ?population) WHERE {
  ?object p:P1082 ?populationStatement.
  ?populationStatement ps:P1082 ?pop.
  ?populationStatement pq:P585 ?date.
  BIND(YEAR(?date) as ?year)
  FILTER((YEAR(?date)) >= 1900).
  FILTER(?object = wd:Q70 ).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
Group by ?objectLabel ?year
order by ?year

Länder ISO3166 Code Alpha 2 und 3 edit 

#Countries ISO3166 abbreviation alpha 2 & alpha 3
# defaultView:Table
SELECT ?countryLabel ?iso3166_Alpha2 ?iso3166_Alpha3
{
  ?country wdt:P31 wd:Q6256 ;
           wdt:P297 ?iso3166_Alpha2 ;
           wdt:P298 ?iso3166_Alpha3 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
ORDER by ?countryLabel

Code postals des communes françaises edit 

#code postal des communes en france
# defaultView:Table
SELECT ?gemeindeLabel ?plz
{
  ?gemeinde wdt:P31 wd:Q484170 ;
           wdt:P281 ?plz ;
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" }
}
ORDER by ?plz

PLZ Schweizer Gemeinden mit Kanton edit 

#PLZ Gemeinden der Schweiz
# defaultView:Table
SELECT ?gemeindeLabel ?plz ?vwEinheitLabel
WHERE {
  ?gemeinde wdt:P31 wd:Q70208.
  ?gemeinde wdt:P281 ?plz.
  ?gemeinde wdt:P131 ?vwEinheit.
  ?vwEinheit wdt:P31 wd:Q23058.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
ORDER by ?plz

#PLZ Gemeinden der Schweiz
# defaultView:Table
SELECT ?plz ?dings ?dingsLabel ?isteinLabel
WHERE {
  ?dings wdt:P281 ?plz.
  ?dings wdt:P771 ?bfsnr.
  ?dings wdt:P31 ?istein
  # FILTER( ?dings in (wd:Q70208, wd:Q3257686, wd:Q532 ))
  # FILTER( REGEX( STR( ?plz ), "^(\\d{4})$" ) = false ) # filter for zip codes that don't match pattern.
  FILTER (REGEX(?plz,'^3[0-9]{3}'))
  FILTER (?istein in (wd:Q70208))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}
ORDER by ?plz

Bakterien Gram-Färbung edit 

SELECT ?item ?itemLabel ?NCBITaxonId ?gramLabel WHERE {
 ?item wdt:P685 ?NCBITaxonId.
 ?item wdt:P31 wd:Q16521.
 ?item wdt:P105 wd:Q7432.
 ?item wdt:P171* wd:Q10876.
 ?item wdt:P2597 ?gram. 
 # OPTIONAL {?item wdt:P2597 ?gram}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
LIMIT 200

Nobelpreis- und Ig-Nobelpreisträger edit 

#People who received both Nobel Prize and Ig Nobel Prize
SELECT DISTINCT ?person ?personLabel WHERE {
  ?person wdt:P166/wdt:P31? wd:Q7191 .
  ?person wdt:P166/wdt:P31? wd:Q184253 .
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" .
  }
}

Italienische Wetterstationen unter 10müM edit 

#Italian weather stations lower than 10 m.a.s.l. with a "." 
#defaultView:Map
SELECT ?item ?itemLabel ?coord ?elev 
{
  ?item wdt:P31 wd:Q190107 ;
        p:P2044/psn:P2044/wikibase:quantityAmount ?elev ; 
        wdt:P625 ?coord ;
        wdt:P17 wd:Q38 .
  FILTER(?elev < 9 && REGEX(STR(?elev),"\\."))

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it" }
}

Instance of language edit 

#Instances of actual languages (e.g. "instance of Hindi", often incorrectly set to indicate the language of something or to request a sitelink)
SELECT ?item ?itemLabel
WHERE {
  ?item wdt:P31/wdt:P31* wd:Q34770 .
  FILTER NOT EXISTS {?item wdt:P31 wd:Q34770}
  FILTER NOT EXISTS {?item wdt:P31 wd:Q33215}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Bakteriell verursachte Krankheiten edit 

SELECT DISTINCT ?item ?itemLabel ?effect ?effectLabel WHERE {
 ?item wdt:P31 wd:Q16521.
 ?item wdt:P171* wd:Q10876.
 ?item wdt:P1542 ?effect.
 ?effect wdt:P31/wdt:P279* wd:Q12136.
 MINUS {?effect wdt:P31/wdt:P279* wd:Q9190427} 
 # OPTIONAL {?item wdt:P2597 ?gram}  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}
ORDER BY ?itemLabel
LIMIT 200

Departemente des Bundes edit 

SELECT ?item ?itemLabel ?subitem ?subitemLabel WHERE {
  ?item wdt:P749/wdt:P279* wd:Q30917 .
  ?item wdt:P355 ?subitem
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de,fr,it,en" .
  }
}

Objekte mit SR-Nummer edit

Alle Objekte mit SR-Nummer SR Number (P5743). Eindeutige Nummer der Gesetze in der Systematische Rechtssammlung (SR) der Schweiz 

SELECT ?item ?itemLabel ?objekt ?is_a ?is_aLabel 
WHERE {
  ?item wdt:P5743 ?objekt.
  ?item wdt:P31 ?is_a
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de,fr,it,en" .
  }
}
Order By ?objekt

Wikipediaartikel mit 'Bundesgesetz' im Titel edit

Wikipediaartikel mit 'Bundesgesetz' im Titel 

SELECT DISTINCT ?name ?item ?objekt WHERE {
  ?article schema:inLanguage 'de'; 
           schema:name ?name ;
           schema:about ?item.
#  ?item wdt:P17 wd:Q39.
  OPTIONAL {?item wdt:P5743 ?objekt.}.
  FILTER (CONTAINS(?name, 'Bundesgesetz')) .
}
LIMIT 25

Meldepflichtige Krankheiten edit 

#Meldepflichtige Krankheiten
SELECT ?item ?itemLabel ?loc ?locLabel WHERE {
  ?item wdt:P31 wd:Q314676.
  ?item p:P31 ?notifiable_disease.
  ?notifiable_disease pq:P3005 ?loc.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr". }
}
LIMIT 30


Todesursache nach Ursache und Geschlecht edit 

#Overall causes of death ranking
#defaultView:Tableview

SELECT ?sexLabel ?cidLabel (COUNT(*) AS ?count) WHERE {
  ?pid wdt:P31 wd:Q5;
       wdt:P509 ?cid;
       wdt:P21 ?sex.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".}
}
GROUP BY ?sex ?sexLabel ?cid ?cidLabel
ORDER BY DESC(?count) ?cid ?sex

Todesursache nach Ursache und Sterbeort edit 

#Overall causes of death ranking
#defaultView:TreeMap

SELECT  ?staatLabel ?cidLabel (COUNT(*) AS ?count) WHERE {
  ?pid wdt:P31 wd:Q5;
       wdt:P509 ?cid;
       wdt:P20 ?sterbeort.
  ?sterbeort wdt:P17 ?staat.
FILTER(?staat = wd:Q39).
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".}
}
GROUP BY  ?staat ?staatLabel ?cid ?cidLabel
ORDER BY DESC(?count) ?cid

Vorname & Geschlecht edit 

#Vorname & Geschlecht
SELECT ?genderLabel ?given_nameLabel (COUNT(*) AS ?count) WHERE {
  ?human wdt:P31 wd:Q5;
    wdt:P569 ?dateofbirth;
    wdt:P21 ?gender;
    wdt:P19 ?ort;
    wdt:P735 ?given_name.
  ?ort wdt:P131/wdt:P131* wd:Q39.
  FILTER(YEAR(?dateofbirth) > 1900). 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,fr,it". }
}
GROUP BY  ?gender ?genderLabel ?given_name ?given_nameLabel
ORDER BY DESC(?count)

Männliche Vornamen edit 

#Vorname männlich
#defaultView:Table
SELECT ?item ?itemLabel 
WHERE {
  ?item wdt:P31 wd:Q12308941.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, fr, it". }
}

Mehr als 15 Kinder edit 

#More than 15 children
#defaultView:TableView
SELECT  ?item ?itemLabel  ?_number_of_children WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P1971 ?_number_of_children.
  ?item wdt:P569 ?_date_of_birth.
  BIND( year(?_date_of_birth) as ?year ).
  FILTER( ?_number_of_children > 15).
  ?item rdfs:label ?itemlbl.  // label
  FILTER(LANG(?itemlbl) = "de")  // Deutsches Label muss vorhanden sein.
  FILTER ( ?item not in ( wd:Q7257214, wd:Q151509, wd:Q635520,  wd:Q104419, wd:Q247901,
                          wd:Q295168, wd:Q10332933, wd:Q65581286, wd:Q312011, wd:Q468298,
                          wd:Q20031966, wd:Q6193704 ) )
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de"}.
}
ORDER BY DESC(?_number_of_children)

Anzahl Kinder nach Geburtsjahr Eltern (bestimmtes Jahr) edit 

#defaultView:Tableview
SELECT  ?item ?itemLabel  ?_number_of_children WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P1971 ?_number_of_children.
  ?item wdt:P569 ?_date_of_birth.
  BIND( year(?_date_of_birth) as ?year ).
  FILTER( ?year = 1972)
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de"}.
}
ORDER BY DESC(?_number_of_children)

Anzahl Kinder nach Geburtsjahr Eltern (ab 1900) edit 

#defaultView:LineChart
SELECT  (str(?year) AS ?years) (AVG( ?_number_of_children ) AS ?count) WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P1971 ?_number_of_children.
  ?item wdt:P569 ?_date_of_birth.
  BIND( year(?_date_of_birth) as ?year ).
  FILTER( ?year > 1900)
}
GROUP BY ?year

Anzahl Items mit der Eigenschaft "Bevölkerungsgruppe" P172 gruppiert nach "ist ein(e)" P31 edit 

#Number of item with property Bevöklerungsgruppe P172 grouped by P31  
SELECT ?is_aLabel (COUNT(?id) as ?count)  WHERE {
  ?item wdt:P172 ?id.
  ?item wdt:P31 ?is_a
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?is_aLabel
Order BY DESC (?count)

Item mit merkwürdiger P31 Aussage edit 

SELECT ?item ?is_aLabel ?idLabel  WHERE {
  ?item wdt:P172 ?id.
  ?item wdt:P31 ?is_a.
   FILTER ( ?is_a  in ( wd:Q104526) )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Flugzeugabstürze edit

Query 

SELECT ?item ?itemLabel ?zeitpunkt ?typLabel ?beteiligte ?überlebende ?verletzte ?tote
WHERE {
  ?item wdt:P31 wd:Q3002150.
  OPTIONAL {?item wdt:P585 ?zeitpunkt}.
  OPTIONAL {?item wdt:P121 ?typ}.
  OPTIONAL {?item wdt:P1132 ?beteiligte}.
  OPTIONAL {?item wdt:P1561 ?überlebende}.
  OPTIONAL {?item wdt:P1339 ?verletzte}.
  OPTIONAL {?item wdt:P1120 ?tote}.
	SERVICE wikibase:label {
		bd:serviceParam wikibase:language "de,fr" . 
	 }
 }
 ORDER BY DESC (?zeitpunkt)

Sportler edit 

SELECT ?personLabel ?person ?vornameLabel ?familiennameLabel ?geschlechtLabel ?gebortLabel ?dayofbirth ?monthofbirth ?yearofbirth
WHERE {
  ?person wdt:P106 wd:Q2066131.
  ?person wdt:P27 wd:Q39.
  ?person wdt:P735 ?vorname.
  ?person wdt:P734 ?familienname.
  ?person wdt:P19 ?gebort.
  ?person wdt:P21 ?geschlecht.
  ?person wdt:P569 ?dateofbirth.
  BIND( YEAR(?dateofbirth) as ?yearofbirth).
  BIND( MONTH(?dateofbirth) as ?monthofbirth).
  BIND( DAY(?dateofbirth) as ?dayofbirth).
   SERVICE wikibase:label {
		bd:serviceParam wikibase:language "de,fr,it" . 
	 }
    FILTER((YEAR(?dateofbirth)) >= 1910).
 }
 ORDER BY DESC(?dateofbirth)
Limit 100

Menschen mit Geburtsort in der Schweiz edit 

#(Anzahl) Menschen mit Geburtsort in der Schweiz in Wikidata
#SELECT ?ortLabel (COUNT(?item) AS ?count)
SELECT ?ortLabel ?itemLabel ?item
WHERE {
	?item wdt:P31 wd:Q5 .
    ?item wdt:P19 ?ort .
    ?ort wdt:P131 wd:Q39 .
  #    ?ort wdt:P131/wdt:P131* wd:Q39 .  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,fr". }
}
#Group BY ?ortLabel

Federated Query edit

Similar Example: [2] Note: SPARQL Endpoint data.admin.ch is not part of the allowed federated queries. [3] 

SELECT ?item ?itemLabel 
WHERE {
  ?item wdt:P31 wd:Q70208 . 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de,fr,it,en" .
  }
}

SELECT ?gemeinde ?gemeindenr ?gemeindeLabel WHERE {
  ?gemeinde wdt:P31 wd:Q70208.
  ?gemeinde wdt:P131 wd:Q666217.
  ?gemeinde wdt:P771 ?gemeindenr
  
#  SERVICE <http://data.admin.ch/sparql> {
#    }
  
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de".
  }
}

Alle Gemeinde im Umkreis von x km von Bern edit

Version 1 edit 

#Gemeinden im Umkreises von 50 Kilometer um die Stadt Bern
SELECT ?place ?placeLabel ?location ?instanceLabel WHERE {
  wd:Q70 wdt:P625 ?loc.
  SERVICE wikibase:around {
    ?place wdt:P625 ?location.
    bd:serviceParam wikibase:center ?loc;
      wikibase:radius "50".
  }
  ?place wdt:P31 wd:Q70208 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  BIND(geof:distance(?loc, ?location) AS ?dist)
}
ORDER BY (?dist)

Version 2 edit 

#Distanz zu Gemeinden von Bern
SELECT ?locLabel ?dist WHERE {
  wd:Q70 wdt:P625 ?bernLoc .
  ?loc wdt:P625 ?loccoord .
  ?loc wdt:P31 wd:Q70208 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
  BIND(geof:distance(?bernLoc, ?loccoord) as ?dist)
}

Version 3 edit 

#Distanz zu Gemeinden von Bern
#defaultView:Map
SELECT DISTINCT ?city ?cityLabel (SAMPLE(?loc) AS ?location) (SAMPLE(?layer) AS ?layer)
WHERE
{
  wd:Q70 wdt:P625 ?bernLoc .
  ?city wdt:P31/wdt:P279* wd:Q70208;
        wdt:P625 ?loc.
  BIND(round(geof:distance(?bernLoc, ?loc)) as ?dist).
  FILTER(?dist <= 90).
  BIND(
    IF(?dist < 10, "<10",
    IF(?dist < 20, "10-20",
    IF(?dist < 30, "20-30",
    IF(?dist < 40, "30-40",
    IF(?dist < 50, "40-50",
    ">50")))))
    AS ?layer).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?city ?cityLabel

Gemeinde in der Nähe von einem Punkt, aber max 10km entfernt edit 

# Gemeinde im am nächsten von diesem Punkt ist, aber max 10km entfernt
SELECT ?place ?placeLabel ?location ?instanceLabel ?dist
WHERE
{
  BIND('Point(7.292711 46.959336)'^^geo:wktLiteral AS ?myLoc) .
  SERVICE wikibase:around {
      ?place wdt:P625 ?location .
      bd:serviceParam wikibase:center ?myLoc .
      bd:serviceParam wikibase:radius "10" .
  }
  ?place wdt:P31/wdt:P279* wd:Q70208;
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  BIND(geof:distance(?myLoc, ?location) as ?dist)
} ORDER BY ?dist
LIMIT 1

Höchster Punkt pro europäisches Land edit

TODO edit

Liste höchster Erhebungen der Staaten Europas

Schritt 1: Punkt über 8800 M auf der Erde edit 

SELECT ?elevation ?unit ?unitLabel ?item ?itemLabel ?itemDescription ?coord 
WHERE
{
  ?item wdt:P2044 ?elevation . 
  # this could be dropped, but is included to speed it up
  filter(?elevation > 8800) 

  ?item p:P2044 [ psn:P2044 [ wikibase:quantityAmount ?elevation ; wikibase:quantityUnit ?unit ] ] .

  ?item p:P625 [psv:P625 [ wikibase:geoGlobe ?globe];  ps:P625 ?coord ]
  FILTER (?globe = wd:Q2 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?elevation)

Schritt 2: Längster Fluss pro Kontinent edit 

SELECT ?continent ?river ?continentLabel ?riverLabel
WHERE
{
  {
    SELECT ?continent (MAX(?length) AS ?maxlength)
    WHERE
    {
      ?river wdt:P31/wdt:P279* wd:Q355304;
             wdt:P2043 ?length;
             wdt:P30 ?continent.
    }
    GROUP BY ?continent
  }
  ?river wdt:P31/wdt:P279* wd:Q355304;
         wdt:P2043 ?maxlength;
         wdt:P30 ?continent.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?continentLabel

Schritt 3: Höchster Punkt pro Land edit

Ausgeschlossen sind Raumstationen, Satelliten,.. 

SELECT ?country ?countryLabel ?place ?placeLabel
WHERE
{
  {
    SELECT ?country (MAX(?elevation) AS ?maxelevation)
    WHERE
    {
      ?place p:P2044 [ psn:P2044 [ wikibase:quantityAmount ?elevation ] ] ;
             wdt:P17 ?country.
      FILTER (?place not in (wd:Q25271, wd:Q847514, wd:Q74259, wd:Q1270))
    }
    GROUP BY ?country
    LIMIT 20
  }
  ?place p:P2044 [ psn:P2044 [ wikibase:quantityAmount ?maxelevation ] ] ;
         wdt:P17 ?country.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, en". }
}
ORDER BY ?countryLabel

Radwanderwege in der Schweiz edit 

#Radwanderwege in der Schweiz
#defaultView:Table
SELECT ?item ?itemLabel ?laenge ?unitlaengeLabel ?osmr ?altLabel WHERE {
  ?item wdt:P31 wd:Q353027;
    wdt:P17 wd:Q39.
  OPTIONAL { ?item skos:altLabel ?altLabel .}
  OPTIONAL {
    ?item (p:P2043/psv:P2043) _:b0.
    _:b0 wikibase:quantityAmount ?laenge;
      wikibase:quantityUnit ?unitlaenge.
  }
 Optional { ?item wdt:P402 ?osmr}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de, fr, it". }
}
ORDER BY DESC (?laenge)

Demonyme von Schweizer Ortschaften edit 

#Demonyme: Französische Volks- und Einwohnerbezeichnungen in der Schweiz
#Vervollständigen männlich oder weiblich
SELECT ?item ?itemLabel ?demonym WHERE {
  ?item wdt:P1549 ?demonym;
    (wdt:P131/(wdt:P131*)) wd:Q39.
  FILTER((LANG(?demonym)) = "fr")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it,en". }
}
ORDER BY (?itemlabel)
LIMIT 10

User:Mfilot

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Mfilot/Wikidata_Query_Service_Queries&oldid=2006601206"