User:Mfilot/Wikidata Query Service Queries QA-CH

Postleitzahl von Objekt in der Schweiz edit

Ausnahmen

In Campione d'Italia liegen gewisse Objekte sowohl in Italien und in der Schweiz. Bis 31. Dezember 2019 hatte Campione d'Italia auch eine Schweizer PLZ.

#Objekt in der Schweiz mit nicht vierstelliger Postleitzahl
#Ausnahmen: ? 
# defaultView:Table
SELECT ?item ?itemLabel ?plz
WHERE {
  ?item wdt:P281 ?plz.
  ?item wdt:P17 wd:Q39.
  #FILTER(STRLEN(?plz)!=4).
  FILTER( REGEX( STR( ?plz ), "^(\\d{4})$" ) = false ). # CH, AT 
  FILTER(?item NOT IN (wd:Q3902234)). #Ausnahmen
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it,en" }
}
ORDER by ?plz
LIMIT 100

Abfrage starten

Adresse von Objekt in der Stadt Bern edit

Ausnahmen :{{Q|Q3902234}}

#Objekt mit Adresse in der Stadt Bern, die nicht "Bern" enthalten
#Ausnahmen: ? 
# defaultView:Table
SELECT ?item ?itemLabel ?adr
WHERE {
  ?item wdt:P6375 ?adr.
  ?item wdt:P131 wd:Q70.
  FILTER (REGEX(?adr,'^((?!Bern).)*$'))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it,en" }
}
ORDER by ?adr
LIMIT 100

Abfrage Starten

Strasse in der Stadt Bern edit

#Strasse in der Stadt Bern
SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q79007;
    (wdt:P131/(wdt:P131*)) wd:Q70.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it,en". }
}
ORDER BY (?itemLabel)
LIMIT 100

Abfrage starten

Höhe über Meer edit

Höchster und Tiefster Punkt pro Land

Höchster Punkt ist die Dufourspitze (Q3403) 4634m ü.M.

Tiefster Punkt Lake Maggiore (Q14379) 193m ü.M.

Ausnahmen

Ein bisschen fragwürdig wie die Objekte erfasst sind.

International Space Station (Q25271)

Alpide belt (Q847514)

Western Alps (Q74259)

Pennine Alps (Q1270)

SELECT ?place ?placeLabel ?elevation ?coord
    WHERE
    {
      ?place p:P2044 [ psn:P2044 [ wikibase:quantityAmount ?elevation  ] ] ;
             wdt:P625 ?coord ;
             wdt:P17 wd:Q39.
      # FILTER (?country IN (wd:Q39))
      FILTER (?place not in (wd:Q25271, wd:Q847514, wd:Q74259, wd:Q1270))
      FILTER (?elevation > 4634 || ?elevation < 193 )
      SERVICE wikibase:label { bd:serviceParam wikibase:language "de,fr,it". }
    }