Open main menu

letzter editEdit

SELECT * WHERE {
wd:Q19286461 schema:dateModified ?a
}

Try it!

SPARQL-Abfrage SeengruppeEdit

SELECT ?lake ?lakeLabel ?value ?valueLabel ?v ?vLabel WHERE {
    ?lake wdt:P527 ?value ; # beliebiger See besteht aus mehreren Seen
          wdt:P31 wd:Q23397 # ist ein See
    {SELECT ?value ?v 
     WHERE {
        VALUES ?p {wdt:P31 wdt:P361}   
        ?value ?p ?v . # Teile sind ein See und Teil etwas anderem
        }        
    }
     SERVICE wikibase:label {bd:serviceParam wikibase:language "en,de"}   
 }

Try it!

Finde alle Seen, die aus mehreren Teilen bestehen. Nenne den Namen dieser Teile und zeige den Typ an und wovon er ein Teil ist.

SPARQL-Abfrage Seen ohne AbflussEdit

PREFIX schema: <http://schema.org/>

SELECT ?p ?pLabel ?p_article ?z1Label ?z2Label WHERE {
   VALUES ?z1 {wd:Q183 wd:Q40 wd:Q39} # Staat DE, AT, CH
   ?p wdt:P17 ?z1 .
   VALUES ?z2 {wd:Q23397 wd:Q131681} # See, Stausee
   ?p wdt:P31 ?z2 FILTER NOT EXISTS {?p wdt:P201 ?x }  # ohne Abfluss P201
   SERVICE wikibase:label {bd:serviceParam wikibase:language "en,de"}   
   OPTIONAL {  # add a sitelinked article, if it is on de-wiki
     ?p_article schema:about ?p .
     ?p_article schema:inLanguage "de" .
     FILTER (SUBSTR(str(?p_article), 1, 25) = "https://de.wikipedia.org/")
   }      
 } LIMIT 10

Try it! Finde Seen ohne eingetragenem Abfluss

SPARQL-Abfrage 3Edit

SELECT ?lake ?lake_label ?value ?value_label ?v ?v_label WHERE 
  {
    ?lake wdt:P201 ?value ; # beliebiger See hat einen Abfluss
          wdt:P31 wd:Q23397 . # ist ein See
    OPTIONAL {?lake rdfs:label ?lake_label filter (lang(?lake_label) = "en")} 
    OPTIONAL {?value rdfs:label ?value_label filter (lang(?value_label) = "en")} 
    {
    SELECT ?value ?v ?v_label
    WHERE {
      VALUES ?p {wdt:P31 wdt:P885}   
      ?value ?p ?v .# Teile sind ein See und nenne Quelle des Wasserlaufs
    OPTIONAL {?v rdfs:label ?v_label filter (lang(?v_label) = "en")}    
    } 
  }
}

Try it!

Abfluss eines beliebigen Sees angeben und welche Eigenschaft (z.B. Fluss, Strom, ..) und Quelle dieser hat

SPARQL-Abfrage: one or more occurrencesEdit

SELECT ?lake ?lakeLabel ?outflow ?outflowLabel ?mouth ?mouthLabel WHERE {
  ?lake wdt:P17 wd:Q183. # für Deutschland
  ?lake wdt:P31 wd:Q23397.
  ?lake wdt:P201 ?outflow.
  ?outflow wdt:P403+ ?mouth. # mündet in, one or more occurrences 
  #?p wdt:P31 wd:Q131681.
  #?p wdt:P200/wdt:P201 wd:Q672715
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "de" .
  }
} ORDER BY DESC(?lake) LIMIT 100

Try it! Lake outflows to river, der mündet in einen Fluss. Letzteres wiederholt sich so lange, bis entweder ein Meer oder ein See erreicht wurde (Seen münden nirgend wohin)

SPARQL-Abfrage: Inseln im GewässerEdit

PREFIX schema: <http://schema.org/>

SELECT ?p ?pLabel ?p_article ?xLabel ?zLabel WHERE {
   VALUES ?x {wd:Q202199 wd:Q23442 wd:Q1402592 wd:Q28337} # Inselarten
   VALUES ?z {wd:Q183 wd:Q40 wd:Q39}  # Staaten DE, AT, CH     
   ?p wdt:P17 ?z . 
   ?p wdt:P31 ?x FILTER NOT EXISTS {?p wdt:P706 ?xx} # ohne P706
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "de,en" .
   }      
   OPTIONAL {  # add a sitelinked wp:article, if it is on de-wiki
     ?p_article schema:about ?p .
     ?p_article schema:inLanguage "de" .
     FILTER (SUBSTR(str(?p_article), 1, 25) = "https://de.wikipedia.org/")
   }      
 } LIMIT 50

Try it!

Finde Binneninsel (Q202199), Insel (Q23442), Inselgruppe (Q28337) und Sandbank (Q28337) im Staat ?z ohne P706 (liegt geografisch im Gewässer).

SPARQL-Abfrage: Gewässer als BildermotivEdit

SELECT ?p ?pLabel ?xLabel ?oLabel  WHERE {
   ?p wdt:P180 ?x . # Motiv 
   ?p wdt:P31 ?o .
   ?x wdt:P31/wdt:P279* wd:Q15324 .# Gewässer
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "de,en,fr" .
   }      
 } LIMIT 500

Try it!

Finde alle items, die als Motiv (P180) ein item haben, dass als Gewässer (Q15324) oder darunter einsortiert ist.

SPARQL-Abfrage: fiktives GewässerEdit

SELECT ?p ?pLabel WHERE {
   ?p wdt:P31/wdt:P279* wd:Q16500104 # fiktives Gewässer
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "de,en" .
   }      
}

Try it!

Finde alle fiktiven Gewässer.