Wikidata

User:Nortix08/Straßen in Hannover

< User:Nortix08

siehe auch Plätze in Hannover

Fortschritt edit

Top groupings (Minimum 5 items) Top Properties (used at least 0 times per grouping)
Name Count native label (P1705) length (P2043) geoshape (P3896) terminus (P559)
List (Q9004530) 191 5.24% (10) 🔍 2.09% (4) 🔍 2.09% (4) 🔍 2.09% (4) 🔍
Bothfeld (Q69730084) 189 4.23% (8) 🔍 1.06% (2) 🔍 1.59% (3) 🔍 1.59% (3) 🔍
Groß-Buchholz (Q97920888) 180 6.67% (12) 🔍 1.11% (2) 🔍 1.11% (2) 🔍 1.11% (2) 🔍
Misburg-Nord (Q97843183) 173 5.2% (9) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Bemerode (Q63139227) 169 7.1% (12) 🔍 0.59% (1) 🔍 0% (0) 🔍 0% (0) 🔍
Südstadt (Q18609543) 139 17.99% (25) 🔍 6.47% (9) 🔍 7.19% (10) 🔍 7.19% (10) 🔍
Wettbergen (Q97940796) 136 6.62% (9) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Mitte (Q97612386) 123 4.88% (6) 🔍 13.82% (17) 🔍 14.63% (18) 🔍 14.63% (18) 🔍
Kirchrode (Q15727660) 116 6.9% (8) 🔍 0.86% (1) 🔍 0.86% (1) 🔍 0.86% (1) 🔍
Mittelfeld (Q77826110) 111 3.6% (4) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Vahrenwald (Q97354172) 107 13.08% (14) 🔍 1.87% (2) 🔍 0.93% (1) 🔍 0.93% (1) 🔍
Sahlkamp (Q76356866) 90 7.78% (7) 🔍 0% (0) 🔍 1.11% (1) 🔍 1.11% (1) 🔍
Kleefeld (Q97921414) 88 7.95% (7) 🔍 1.14% (1) 🔍 1.14% (1) 🔍 1.14% (1) 🔍
Döhren (Q8936588) 86 15.12% (13) 🔍 1.16% (1) 🔍 1.16% (1) 🔍 1.16% (1) 🔍
Anderten (Q97842946) 82 2.44% (2) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Davenstedt (Q28125155) 82 100.0% (82) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Nordstadt (Q97762617) 80 15.0% (12) 🔍 7.5% (6) 🔍 7.5% (6) 🔍 7.5% (6) 🔍
Ahlem (Q28125149) 80 100.0% (80) 🔍 1.25% (1) 🔍 1.25% (1) 🔍 1.25% (1) 🔍
Badenstedt (Q28125151) 80 100.0% (80) 🔍 2.5% (2) 🔍 3.75% (3) 🔍 3.75% (3) 🔍
Oberricklingen (Q97940644) 75 6.67% (5) 🔍 1.33% (1) 🔍 1.33% (1) 🔍 1.33% (1) 🔍
Calenberger Neustadt (Q90886771) 71 4.23% (3) 🔍 2.82% (2) 🔍 2.82% (2) 🔍 2.82% (2) 🔍
Ricklingen (Q97940634) 71 4.23% (3) 🔍 2.82% (2) 🔍 2.82% (2) 🔍 2.82% (2) 🔍
Linden-Mitte (Q18615961) 62 14.52% (9) 🔍 1.61% (1) 🔍 1.61% (1) 🔍 1.61% (1) 🔍
Stöcken (Q63387819) 61 100.0% (61) 🔍 1.64% (1) 🔍 1.64% (1) 🔍 1.64% (1) 🔍
Linden-Süd (Q18615959) 60 11.67% (7) 🔍 8.33% (5) 🔍 8.33% (5) 🔍 8.33% (5) 🔍
Vinnhorst (Q97763124) 60 8.33% (5) 🔍 1.67% (1) 🔍 1.67% (1) 🔍 1.67% (1) 🔍
Ledeburg (Q97940511) 58 100.0% (58) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Linden-Nord (Q18615966) 56 12.5% (7) 🔍 7.14% (4) 🔍 7.14% (4) 🔍 7.14% (4) 🔍
Herrenhausen (Q63387763) 52 100.0% (52) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Limmer (Q18615968) 52 92.31% (48) 🔍 5.77% (3) 🔍 5.77% (3) 🔍 5.77% (3) 🔍
Oststadt (Q9061486) 47 10.64% (5) 🔍 14.89% (7) 🔍 14.89% (7) 🔍 14.89% (7) 🔍
Vahrenheide (Q76356842) 47 8.51% (4) 🔍 2.13% (1) 🔍 2.13% (1) 🔍 2.13% (1) 🔍
Isernhagen-Süd (Q97919597) 46 100.0% (46) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Zoo (Q5649223) 43 100.0% (43) 🔍 4.65% (2) 🔍 4.65% (2) 🔍 2.33% (1) 🔍
Seelhorst (Q97313071) 39 100.0% (39) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Heideviertel (Q97921842) 37 100.0% (37) 🔍 2.7% (1) 🔍 2.7% (1) 🔍 2.7% (1) 🔍
Hainholz (Q76451696) 35 100.0% (35) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Mühlenberg (Q75135712) 31 100.0% (31) 🔍 6.45% (2) 🔍 6.45% (2) 🔍 6.45% (2) 🔍
Wülfel (Q9202379) 28 100.0% (28) 🔍 7.14% (2) 🔍 7.14% (2) 🔍 7.14% (2) 🔍
Misburg-Süd (Q97843389) 27 100.0% (27) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Lahe (Q97920246) 27 100.0% (27) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Leinhausen (Q97924530) 26 100.0% (26) 🔍 3.85% (1) 🔍 3.85% (1) 🔍 3.85% (1) 🔍
Bult (Q18615934) 26 100.0% (26) 🔍 3.85% (1) 🔍 3.85% (1) 🔍 3.85% (1) 🔍
Burg (Q63387623) 23 100.0% (23) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Marienwerder (Q1667345) 23 100.0% (23) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Waldhausen (Q97059009) 22 100.0% (22) 🔍 4.55% (1) 🔍 4.55% (1) 🔍 4.55% (1) 🔍
Waldheim (Q7961512) 22 100.0% (22) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Wülferode (Q63139304) 20 100.0% (20) 🔍 0% (0) 🔍 0% (0) 🔍 0% (0) 🔍
Bornum (Q47457067) 15 100.0% (15) 🔍 100.0% (15) 🔍 100.0% (15) 🔍 100.0% (15) 🔍
Brink-Hafen (Q97763565) 12 100.0% (12) 🔍 8.33% (1) 🔍 0% (0) 🔍 0% (0) 🔍
Totals (all items) 3375 30.52% (1030) 🔍 2.16% (73) 🔍 2.22% (75) 🔍 2.19% (74) 🔍


Alle Straßen, Plätze, Brücken etc. in Hannover edit 

SELECT DISTINCT ?Objekt ?ObjektLabel
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS{ ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke
    wd:Q57577442   # Feldweg
    wd:Q207934     # Allee
    wd:Q628179     # Weg
    wd:Q5004679    # Weg
    wd:Q221722     # Radweg
    wd:Q787113     # Promenade
    wd:Q1320830    # Ladenpassage
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P8138 wd:Q5649223 .
  OPTIONAL { ?Objekt wdt:P138 ?Namensgeber . }
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Straßen, die nach Flüssen benannt sind edit 

SELECT ?Objekt ?ObjektLabel ?Namensgeber ?NamensgeberLabel ?Stadtteil ?StadtteilLabel ?Typ ?TypLabel
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke     
    wd:Q57577442   # Feldweg
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;
          wdt:P131 ?Stadtteil ;
          wdt:P31 ?Typ ;
          wdt:P138 ?Namensgeber . 
  ?Namensgeber wdt:P31 wd:Q4022 .
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Brücken in Hannover edit 

SELECT ?Objekt ?ObjektLabel ?Namensgeber ?NamensgeberLabel ?Stadtteil ?StadtteilLabel ?Typ ?TypLabel
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  ?Objekt wdt:P31/wdt:P279 wd:Q12280 ;
          wdt:P131* wd:Q1715 ;
          wdt:P131 ?Stadtteil ;
          wdt:P31 ?Typ .
  OPTIONAL { ?Objekt wdt:P138 ?Namensgeber . }
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Straßen, die nach Personen benannt sind, die Mitglied in der NSDAP waren edit 

SELECT DISTINCT ?Objekt ?ObjektLabel ?Namensgeber ?NamensgeberLabel ?Stadtteil ?StadtteilLabel ?Jahr
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS{ ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke
    wd:Q1068842    # Fußgängerbrücke   
    wd:Q57577442   # Feldweg
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;
          wdt:P131 ?Stadtteil ;
          wdt:P138 ?Namensgeber ;
          p:P138 ?Zeitpunkt ;
          rdfs:label ?ObjektLabel.
  ?Namensgeber wdt:P31 wd:Q5 ;
               wdt:P102 wd:Q7320 .
}
ORDER BY ASC( ?Jahr ) ?ObjektLabel
Try it!

Straßen in Hannover, die nach Frauen benannt sind edit 

SELECT DISTINCT ?Objekt ?ObjektLabel ?NameLabel ?StadtbezirkLabel ?commonscat_link ?geo
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS{ ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke   
    wd:Q57577442   # Feldweg  
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;
          wdt:P131 ?Stadtbezirk ;
          wdt:P625 ?geo ;
          wdt:P138 ?Name . 
  ?Name wdt:P31 wd:Q5 ;
        wdt:P21 wd:Q6581072 .
  OPTIONAL {
      ?Objekt wdt:P373 ?commonscat .
      BIND(IRI(CONCAT("https://commons.wikimedia.org/wiki/Category:", ?commonscat)) AS ?commonscat_link) .
  }
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Straßen ohne Baujahr (P571) edit 

SELECT ?Objekt ?ObjektLabel ?StadtbezirkLabel
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS{ ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke   
    wd:Q57577442   # Feldweg
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;
          wdt:P131 ?Stadtbezirk .
  FILTER NOT EXISTS{ ?Objekt wdt:P571 ?Baujahr. }
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Straßen mit/ohne physische Verbindung (P2789) edit 

#-------------------------------------------------------------------------------
# Straßen mit/ohne physische Verbindung
# Quelle: https://www.wikidata.org/wiki/User:Stefan_Kühn/Dresden
#-------------------------------------------------------------------------------
#defaultView:Map
SELECT  ?item ?itemLabel ?coord (count (?connect) as ?anzahl) ?rgb
WHERE {
  ?item wdt:P8138 wd:Q97612386.
  FILTER NOT EXISTS{ ?item wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of
         {
           wd:Q34442      # Straße
           wd:Q79007      # Innerortstraße
           wd:Q21000333   # Einkaufsstraße 
           wd:Q174782     # Platz
           wd:Q537127     # Straßenbrücke
           wd:Q3397519    # Spannbetonbrücke 
           wd:Q1055465    # Balkenbrücke
           wd:Q57577442   # Feldweg
           wd:Q207934     # Allee
           wd:Q628179     # Weg
           wd:Q5004679    # Weg
           wd:Q221722     # Radweg
           wd:Q787113     # Promenade
           wd:Q1320830    # Ladenpassage
         }
  ?item wdt:P31 ?instance_of.
  OPTIONAL { ?item wdt:P2789 ?connect. }
  OPTIONAL { ?item wdt:P625 ?coord. }
  BIND( IF( BOUND(?connect) , "008800", "ff2d00") AS ?rgb).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
}
GROUP BY ?item ?itemLabel ?coord ?rgb
Try it!

Straßen ohne Bild aber mit Commons-Kategorie edit 

SELECT DISTINCT ?item ?itemLabel ?image ?commonscat_link ?coordinates
WHERE {
  ?item wdt:P8138 wd:Q9004530.                                           
  VALUES ?instance_of {
           wd:Q34442      # Straße
           wd:Q79007      # Innerortstraße
           wd:Q21000333   # Einkaufsstraße 
           wd:Q174782     # Platz
           wd:Q537127     # Straßenbrücke
           wd:Q3397519    # Spannbetonbrücke 
           wd:Q1055465    # Balkenbrücke
           wd:Q57577442   # Feldweg
           wd:Q207934     # Allee
           wd:Q628179     # Weg
           wd:Q5004679    # Weg
           wd:Q221722     # Radweg
           wd:Q787113     # Promenade 
         }             
  ?item wdt:P31 ?instance_of;
        wdt:P373 ?commonscat;
        wdt:P625 ?coordinates.
  OPTIONAL {?item wdt:P18 ?image}
  FILTER(!BOUND(?image)) 
  BIND(IRI(CONCAT("https://commons.wikimedia.org/wiki/Category:", ?commonscat)) AS ?commonscat_link) .                        
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en". }
}
ORDER BY ?itemLabel
Try it!

Verbindungen von Straßen als Bubble-Graph edit 

#defaultView:Graph;Table
SELECT DISTINCT
?item ?itemLabel ?image ?other ?otherLabel
WHERE
{
  ?item wdt:P8138 wd:Q90886771.
  VALUES ?instance_of 
         {
           wd:Q34442      # Straße
           wd:Q79007      # Innerortstraße
           wd:Q21000333   # Einkaufsstraße 
           wd:Q174782     # Platz
           wd:Q537127     # Straßenbrücke
           wd:Q3397519    # Spannbetonbrücke 
           wd:Q1055465    # Balkenbrücke
           wd:Q57577442   # Feldweg
           wd:Q207934     # Allee
           wd:Q628179     # Weg
           wd:Q5004679    # Weg
           wd:Q221722     # Radweg
           wd:Q787113     # Promenade 
         }
  ?item wdt:P31 ?instance_of.
  ?item  wdt:P2789 ?other . 
  OPTIONAL { ?item  wdt:P18 ?image . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en,[AUTO_LANGUAGE]" }
}
Try it!

Fehlende Straßennamen edit 

SELECT DISTINCT ?entity ?entityLabel 
WHERE { 
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke
    wd:Q57577442   # Feldweg
    wd:Q207934     # Allee
    wd:Q628179     # Weg
    wd:Q5004679    # Weg
    wd:Q221722     # Radweg
    wd:Q787113     # Promenade
    wd:Q1320830    # Ladenpassage
    } 
  ?entity wdt:P31 ?instance_of ;
          FILTER NOT EXISTS{ ?entity wdt:P5816 wd:Q63065035 } .  
  ?entity wdt:P8138 wd:Q76356866 .  
  MINUS { { ?entity a wdno:P138 . } UNION { ?entity wdt:P138 ?prop . } }  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Geschlecht der namensgebenden Personen für Strassen in Hannover edit 

#defaultView:BubbleChart
SELECT DISTINCT ?GeschlechtLabel (COUNT(?Objekt) AS ?count) 
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS { ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke   
    wd:Q57577442   # Feldweg  
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;
          wdt:P131 ?Stadtbezirk ;
          wdt:P138 ?Name . 
  ?Name wdt:P31 wd:Q5 ;
        wdt:P21 ?Geschlecht .
  }
GROUP BY ?GeschlechtLabel
Try it!

Anzahl Strassen in Stadtbezirken Hannovers benannt nach Frauen edit 

#defaultView:BubbleChart
SELECT DISTINCT ?StadtbezirkLabel (COUNT(?Objekt) AS ?count) 
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS { ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke   
    wd:Q57577442   # Feldweg  
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;          
          wdt:P131 ?Stadtbezirk ;
          wdt:P138 ?Name .
  ?Name wdt:P31 wd:Q5 ;
        wdt:P21 wd:Q6581072 .
  }
GROUP BY ?StadtbezirkLabel
Try it!


Strassen in Hannover benannt nach Frauen mit Wikipedia-Artikel in DE edit 

SELECT DISTINCT ?Objekt ?benanntnach ?Artikel ?ObjektLabel ?NameLabel 
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS{ ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke   
    wd:Q57577442   # Feldweg  
    wd:Q207934     # Allee
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P131* wd:Q1715 ;
          wdt:P138 ?Name ;
          wdt:P138 ?benanntnach .
  OPTIONAL{
    ?Artikel schema:about ?Objekt .
    ?Artikel schema:isPartOf <https://de.wikipedia.org/>.
  }
  ?Name wdt:P31 wd:Q5 ;
        wdt:P21 wd:Q6581072 .
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Equalstreetnames edit

siehe auch EqualStreetNames 

type:way AND -bus=* AND highway=* AND "Straßenname"

https://mapcomplete.osm.be/

named after (P138)concept of unknown value in Wikibase (Q19798648) 

SELECT DISTINCT ?ObjektLabel ?Objekt ?Namensgeber
WHERE
{
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
  FILTER NOT EXISTS{ ?Objekt wdt:P5816 wd:Q63065035. }
  VALUES ?instance_of {
    wd:Q34442      # Straße
    wd:Q79007      # Innerortstraße
    wd:Q21000333   # Einkaufsstraße 
    wd:Q174782     # Platz
    wd:Q537127     # Straßenbrücke
    wd:Q3397519    # Spannbetonbrücke 
    wd:Q1055465    # Balkenbrücke
    wd:Q57577442   # Feldweg
    wd:Q207934     # Allee
    wd:Q628179     # Weg
    wd:Q5004679    # Weg
    wd:Q221722     # Radweg
    wd:Q787113     # Promenade
    wd:Q1320830    # Ladenpassage
    wd:Q1525       # Kreisverkehr
    wd:Q54114      # Boulevard
    } 
  ?Objekt wdt:P31 ?instance_of;
          wdt:P8138 wd:Q5649223 .
  OPTIONAL { ?Objekt wdt:P138 ?Namensgeber . }
}
ORDER BY ASC ( ?ObjektLabel )
Try it!

Offen edit

Muster (?): Brücke Bischofshol (Q98038725)

  1. Benno-Ohnesorg-Brücke (Q17310493)
  2. Leinertbrücke (Q27067860)
  3. Brücke Bischofshol (Q98038725)
  4. Kleefelder Sonnnenweg (Q110200468)
  5. Rut-und-Klaus-Bahlsen-Weg (Q97966279)
  6. Noltemeyerbrücke (Q21036864)
  7. Kaiserbrücke (Q56249415)
  8. Am Schlehenbusch (Q109568938)
  9. Eulenkampbrücke (Q111752921)
  10. Noltemeyerbrücke (Q21036864)
  11. Bridge Alt-Vinnhorst (Q111575090)
  12. Brücke Beneckeallee (Q111586243)
  13. Schulenburger Landstraße (Q111684187)
  14. Hänischbrücke (Q55455034)
  15. Schwanenburgbrücke (Q54892070)
  16. Klappenburgbrücke (Q54918917)
  17. Am Pferdeturm (Q98040946)
  18. Schulenburger Landstraße (Q111684187)
  19. Kaiserbrücke (Q56249415)
  20. Benno-Ohnesorg-Brücke (Q17310493)
  21. Clevertorbrücke (Q1100845)
  22. Königsworther Brücke (Hannover) (Q1796528)
  23. Goethebrücke (Q1147842)
  24. Hänischbrücke (Q55455034)
  25. Leinertbrücke (Q27067860)
  26. Goethebrücke (Q1147842)
  27. Schwienbrücke (Q28109517)
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Nortix08/Straßen_in_Hannover&oldid=2074713368"