User:PAC2/Départements

Liste des personnes nées dans le Vaucluse

La requête suivante retourne des résultats situés hors du département, notamment les personnes nées à Aix en Provence.

The following query uses these:

• Properties: located in the administrative territorial entity (P131)   , place of birth (P19)   , date of birth (P569)   , INSEE department code (P2586)   

  SELECT ?item ?itemLabel ?sitelink ?birthplace ?birthplaceLabel ?year WHERE {
    ?departement ((^wdt:P131*)/^wdt:P19) ?item.
    ?item wdt:P19 ?birthplace;
      wdt:P569 ?birthdate;
      rdfs:label ?itemLabel.
    FILTER((LANG(?itemLabel)) = "fr")
    BIND(YEAR(?birthdate) AS ?year)
    FILTER(?year >= 1975 )
    ?departement wdt:P2586 "84";
      rdfs:label ?departementLabel.
    FILTER((LANG(?departementLabel)) = "fr")
    ?birthplace rdfs:label ?birthplaceLabel.
    FILTER((LANG(?birthplaceLabel)) = "fr")
    ?sitelink schema:about ?item;
      schema:isPartOf <https://fr.wikipedia.org/>.
  }
  ORDER BY (?year)
  

Try it!

Même problème ici :

The following query uses these:

• Properties: located in the administrative territorial entity (P131)   , place of birth (P19)   , date of birth (P569)   , INSEE department code (P2586)   

  SELECT ?birthplace ?birthplaceLabel ?departement ?departementLabel (COUNT(*) as ?count) WHERE {
    ?departement ((^wdt:P131*)/^wdt:P19) ?item.
    ?item wdt:P19 ?birthplace;
      wdt:P569 ?birthdate;
      rdfs:label ?itemLabel.
    FILTER((LANG(?itemLabel)) = "fr")
    ?departement wdt:P2586 "84";
      rdfs:label ?departementLabel.
    FILTER((LANG(?departementLabel)) = "fr")
    ?birthplace rdfs:label ?birthplaceLabel.
    FILTER((LANG(?birthplaceLabel)) = "fr")
    ?sitelink schema:about ?item;
      schema:isPartOf <https://fr.wikipedia.org/>.
  }
  GROUP BY ?birthplace ?birthplaceLabel ?departement ?departementLabel
  ORDER BY DESC(?count)
  

Try it!

Requête en utilisant P150

The following query uses these:

• Properties: INSEE department code (P2586)   , place of birth (P19)   , date of birth (P569)   , contains the administrative territorial entity (P150)   

  SELECT ?birthplace ?birthplaceLabel ?departement ?departementLabel (COUNT(*) as ?count) WHERE {
    ?departement wdt:P2586 "84";
      rdfs:label ?departementLabel.
    FILTER((LANG(?departementLabel)) = "fr")
    ?item wdt:P19 ?birthplace;
      wdt:P569 ?birthdate;
      rdfs:label ?itemLabel.
    FILTER((LANG(?itemLabel)) = "fr")
    ?departement wdt:P150* ?birthplace.
    ?birthplace rdfs:label ?birthplaceLabel.
    FILTER((LANG(?birthplaceLabel)) = "fr")
    ?sitelink schema:about ?item;
      schema:isPartOf <https://fr.wikipedia.org/>.
  }
  GROUP BY ?birthplace ?birthplaceLabel ?departement ?departementLabel
  ORDER BY DESC(?count)
  

Try it!

Liste des personnes nées dans le Vaucluse depuis 1975

The following query uses these:

• Properties: INSEE department code (P2586)   , place of birth (P19)   , date of birth (P569)   , contains the administrative territorial entity (P150)   

  SELECT ?item ?itemLabel ?sitelink ?birthplace ?birthplaceLabel ?departement ?departementLabel ?year WHERE {
    ?departement wdt:P2586 "84";
      rdfs:label ?departementLabel.
    FILTER((LANG(?departementLabel)) = "fr")
    ?item wdt:P19 ?birthplace;
      wdt:P569 ?birthdate;
      rdfs:label ?itemLabel.
    FILTER((LANG(?itemLabel)) = "fr")
    BIND(YEAR(?birthdate) AS ?year)
    FILTER(?year >= 1975 )
    ?departement wdt:P150* ?birthplace.
    ?birthplace rdfs:label ?birthplaceLabel.
    FILTER((LANG(?birthplaceLabel)) = "fr")
    ?sitelink schema:about ?item;
      schema:isPartOf <https://fr.wikipedia.org/>.
  }
  ORDER BY ?year
  

Try it!