User:PAC2/Elisabeth

Ensemble des prénoms d'une personne avec leur rang edit

SELECT ?firstname ?firstnameLabel ?rank WHERE {
  wd:Q34389 p:P735 ?statement.
  ?statement ps:P735 ?firstname;
    pq:P1545 ?rank.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}

Try it!

Liste des éléments avec comme prénom de rang 1 Elisabeth edit

SELECT ?item ?itemLabel ?rank ?rank2 WHERE {
  ?item p:P735 ?statement.
  ?statement ps:P735 wd:Q385468.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
LIMIT 100

Try it!

Ensemble des personnes avec comme prénom Élisabeth, Elisabeth ou Elizabeth de rang 1 edit

SELECT ?item ?itemLabel  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}

Try it!

Nombre d'Élisabeth edit

SELECT ?target ?targetLabel (COUNT(*) AS ?count)  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item wdt:P31 wd:Q5;
    p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY  ?target ?targetLabel
ORDER BY DESC (?count)

Try it!

Elisabeth les plus connues edit

SELECT ?item ?itemLabel ?itemDescription (COUNT(*) AS ?count)  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item wdt:P31 wd:Q5;
     p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  ?sitelink schema:about ?item.
  FILTER (SUBSTR(str(?sitelink), 11, 15) = ".wikipedia.org/") .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY DESC (?count)
LIMIT 100

Try it!

Elisabeth par genre edit

SELECT ?gender ?genderLabel (COUNT(*) AS ?count)  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item wdt:P31 wd:Q5;
    wdt:P21 ?gender;
    p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY  ?gender ?genderLabel
ORDER BY DESC (?count)

Try it!

Elisabeth par pays de citoyenneté edit

SELECT ?country ?countryLabel (COUNT(*) AS ?count)  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item wdt:P31 wd:Q5;
    wdt:P27 ?country;
    p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY  ?country ?countryLabel
ORDER BY DESC (?count)
LIMIT 20

Try it!

Elisabeth par occupation edit

SELECT ?occupation   ?occupationLabel (COUNT(*) AS ?count)  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item wdt:P31 wd:Q5;
    wdt:P106 ?occupation;   
     p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY  ?occupation   ?occupationLabel
ORDER BY DESC (?count)
LIMIT 20

Try it!

Elisabeth de fiction edit

SELECT ?item ?itemLabel ?itemDescription (COUNT(*) AS ?count)  WHERE {
  VALUES ?target {
    wd:Q385468
    wd:Q17524931
    wd:Q18093037
  }
  ?item wdt:P31/wdt:P279* wd:Q15632617;
     p:P735 ?statement.
  ?statement ps:P735  ?target.
  OPTIONAL { ?statement pq:P1545 ?rank. }
  BIND(IF(BOUND(?rank),?rank, 0) AS ?rank2)
  FILTER(xsd:integer(?rank2) < xsd:integer(2))
  ?sitelink schema:about ?item.
  FILTER (SUBSTR(str(?sitelink), 11, 15) = ".wikipedia.org/") .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en". }
}
GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY DESC (?count)
LIMIT 10

Try it!