User:PAC2/Gender neutral labels

Home

SPARQL

Gender diversity

Gendered labels

Documented queries

Media cartography

This page looks at gender neutrality of labels in Wikidata.

It focus on properties whose values are instances of human (Q5) (such as author (P50)) and items which are instances of occupation (Q12737077).

You can find relative discussions on project chat Wikidata:Project_chat/Archive/2021/11#Why_are_labels_of_occupation_always_male_labels? and Topic:Wgl2sg728eg71a8s, Wikidata:Requests for comment/How to avoid to use male form as a generic form in property labels in French ?, Wikidata:Requests for comment/Gender neutral labels for occupations and positions in French.

Property labels whose values are instances of human (Q5)

#title: List of properties which have instances or subclass of humans as possible value with male and female form in French
SELECT ?property ?propertyLabel ?maleform ?femaleform (GROUP_CONCAT(?alias; SEPARATOR = ", ") AS ?aliases) WHERE {
  ?property p:P2302 ?statement.
  ?statement ps:P2302 wd:Q21510865;
    pq:P2308 wd:Q5;
    pq:P2309 ?relation.
  ?property rdfs:label ?propertyLabel FILTER((LANG(?propertyLabel)) = "fr").
  OPTIONAL {
    ?property skos:altLabel ?alias
    FILTER((LANG(?alias)) = "fr"). 
  }
  OPTIONAL {
    ?property wdt:P2521 ?femaleform
    FILTER((LANG(?femaleform)) = "fr"). 
  }
  OPTIONAL {
    ?property wdt:P3321 ?maleform
    FILTER((LANG(?maleform)) = "fr"). 
  }
}
GROUP BY ?property ?propertyLabel ?maleform ?femaleform

List of properties which have instances or subclass of humans as possible value with male and female form in French

Instances of occupation (Q12737077)

449,925 instances of occupation (Q12737077)

SELECT (COUNT(*) AS ?count) WHERE {
  wd:Q12737077 ^wdt:P279*/^wdt:P31 ?item.}

Try it!

English labels

List of items with female and male name in English

SELECT ?item ?itemLabel ?femaleform ?maleform ?lang WHERE {
  wd:Q12737077 ^wdt:P279*/^wdt:P31 ?item. 
 ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang) 
  FILTER((LANG(?itemLabel)) = "en")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
}
LIMIT 100

Try it!

Items with male form as a generic form in English

# See https://m.wikidata.org/wiki/User:PAC2/Gender_neutral_labels
#title: Items with male form as a generic form in English 
SELECT ?item ?itemLabel ?femaleform ?maleform ?lang WHERE {
  wd:Q12737077 ^wdt:P279*/^wdt:P31 ?item. 
 ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang) 
  FILTER((LANG(?itemLabel)) = "en")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
  FILTER(?itemLabel = ?maleform) 
  FILTER(?itemLabel != ?femaleform) 
}
LIMIT 100

Items with male form as a generic form in English

French labels

List of items with male form as a generic form in French

# See https://m.wikidata.org/wiki/User:PAC2/Gender_neutral_labels
#title: Items with male form as a generic form in French
SELECT DISTINCT ?item ?itemLabel ?femaleform ?maleform ?lang WHERE {
  wd:Q12737077 (^(wdt:P279*)/^wdt:P31) ?item.
  ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang)
  FILTER((LANG(?itemLabel)) = "fr")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
  FILTER(?itemLabel = ?maleform)
  FILTER(?itemLabel != ?femaleform)
}
ORDER BY ?item
LIMIT 100

Items with male form as a generic form in French

Statistics in French

96 items with male form as a generic form in French

# See https://m.wikidata.org/wiki/User:PAC2/Gender_neutral_labels
#title: Count of items with male form as a generic form in French 
SELECT (COUNT(*) AS ?count ) WHERE {
  wd:Q12737077 ^wdt:P279*/^wdt:P31 ?item. 
 ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang) 
  FILTER((LANG(?itemLabel)) = "fr")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
  FILTER(?itemLabel = ?maleform) 
  FILTER(?itemLabel != ?femaleform) 
}

Count of items with male form as a generic form in French

4 items with female form as a generic form in French

# See https://m.wikidata.org/wiki/User:PAC2/Gender_neutral_labels
#title: Count of items with female form as a generic form in French 
SELECT (COUNT(*) AS ?count ) WHERE {
  wd:Q12737077 ^wdt:P279*/^wdt:P31 ?item. 
 ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang) 
  FILTER((LANG(?itemLabel)) = "fr")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
  FILTER(?itemLabel != ?maleform) 
  FILTER(?itemLabel = ?femaleform) 
}

Count of items with female form as a generic form in French

19 items with labels same as male and female form

# See https://m.wikidata.org/wiki/User:PAC2/Gender_neutral_labels
#title: Count of items with labels which are both male and female form 
SELECT (COUNT(*) AS ?count ) WHERE {
  wd:Q12737077 ^wdt:P279*/^wdt:P31 ?item. 
 ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang) 
  FILTER((LANG(?itemLabel)) = "fr")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
  FILTER(?itemLabel = ?maleform) 
  FILTER(?itemLabel = ?femaleform) 
}

Count of items with labels which are both male and female form

13 items with labels which is different from male and female form

# See https://m.wikidata.org/wiki/User:PAC2/Gender_neutral_labels
#title: Count of items with labels different from male and female form
SELECT (COUNT(*) AS ?count) WHERE {
  wd:Q12737077 (^(wdt:P279*)/^wdt:P31) ?item.
  ?item wdt:P2521 ?femaleform;
    wdt:P3321 ?maleform;
    rdfs:label ?itemLabel.
  BIND(LANG(?itemLabel) AS ?lang)
  FILTER((LANG(?itemLabel)) = "fr")
  FILTER((LANG(?femaleform)) = ?lang)
  FILTER((LANG(?maleform)) = ?lang)
  FILTER(?itemLabel != ?maleform)
  FILTER(?itemLabel != ?femaleform)
}

Count of items with labels different from male and female form

Queries with Lexemes

List of lexemes associated with occupations

#title: List of lexemes in French about occupation items with gender
SELECT DISTINCT ?item ?itemLabel ?sense ?lexeme ?lemma ?genre ?genreLabel WHERE {
  ?lexeme rdf:type ontolex:LexicalEntry;
    dct:language wd:Q150;
    wikibase:lemma ?lemma;
    ontolex:sense ?sense;
    wdt:P5185 ?genre.
  ?sense wdt:P5137 ?item.
  ?item (wdt:P31/(wdt:P279*)) wd:Q12737077;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "fr")
  ?genre rdfs:label ?genreLabel.
  FILTER((LANG(?genreLabel)) = "fr")
}
ORDER BY (?item) (?lemma) (?genre)

List of lexemes in French about occupation items with gender

#title: List of lexemes in French about occupation items with gender
SELECT DISTINCT ?item ?itemLabel ?sense ?lexeme ?lemma ?genre ?genreLabel WHERE {
  ?item (wdt:P31/(wdt:P279*)) wd:Q12737077;
    rdfs:label ?itemLabel.
  FILTER((LANG(?itemLabel)) = "fr")
  OPTIONAL {
    ?lexeme rdf:type ontolex:LexicalEntry;
      dct:language wd:Q150;
      wikibase:lemma ?lemma;
      ontolex:sense ?sense;
      wdt:P5185 ?genre.
    ?sense wdt:P5137 ?item.
    ?genre rdfs:label ?genreLabel.
    FILTER((LANG(?genreLabel)) = "fr")
  }
}
ORDER BY (?item) (?lemma) (?genre)

List of lexemes in French about occupation items with gender