User:PAC2/Ministres

Comment obtenir la liste des ministres de la 5ème République ?

TL;DR edit

Les données sur les gouvernements sont encore très parcellaires. L'approche par membre des différents gouvernements ne renvoie quasiment pas de résultats.
Les numéros de série des gouvernement ne sont pas bien remplis
Les dates de début et de fin ne sont pas bien remplies
Il y a une ambiguité entre inception (P571) et start time (P580)
L'approche par les ministères (sous-classes du gouvernement français) n'est pas concluantes. On n'a que les données du gouvernement Edouard Philippe !
Georges Pompidou (Q2185) est le Prime Minister of France (Q1587677) qui a passé le plus de jours à Hôtel Matignon (Q912192) devant François Fillon (Q101410) et Lionel Jospin (Q187099) !

Liste des gouvernements edit

Liste des gouvernements de la 5ème République française avec leur numéro dans la série, leur date de début et leur date de fin.

SELECT ?item ?itemLabel ?numero ?start ?end
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?item p:P31 ?statement.
     ?statement ps:P31 wd:Q1450662.
  OPTIONAL {?statement pq:P1545 ?numero.}
  OPTIONAL {?item wdt:P571 ?start}
  OPTIONAL {?item wdt:P576 ?end}
}
ORDER BY DESC(?start)

Try it!

Liste des membres des gouvernements edit

SELECT ?item ?itemLabel ?gouvernement ?gouvernementLabel 
WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
  ?item wdt:P463 ?gouvernement.
  ?gouvernement wdt:P31 wd:Q1450662.
}
ORDER BY ?gouvernementLabel ?itemLabel

Try it!

Liste des dirigeants des filiales du gouvernement de la République française edit

SELECT DISTINCT ?ministre ?ministreLabel ?starttime ?endtime ?ministere ?ministereLabel WHERE {
  wd:Q1450662 wdt:P355 ?ministere.
  ?ministere p:P1037 ?statement.
     ?statement ps:P1037 ?ministre.
     OPTIONAL {?statement pq:P580 ?starttime.}
     OPTIONAL {?statement pq:P582 ?endtime.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
ORDER BY DESC(?starttime) DESC(?endtime)

Try it!

Liste des ministres ou secrétaires d'Etat edit

SELECT ?item ?itemLabel ?ministere ?ministereLabel ?datedebut ?datefin  WHERE {
  VALUES ?target { wd:Q83307 wd:Q736559 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
    ?item p:P39 ?statement.
    ?statement ps:P39 ?ministere.
    ?ministere (wdt:P279*) ?target ;
      wdt:P17 wd:Q142.
  OPTIONAL { ?statement pq:P580 ?datedebut. }
  OPTIONAL { ?statement pq:P582 ?datefin. }
}
ORDER BY DESC (?datedebut)

Try it!

Trombinoscope des ministres et secrétaires d'Etat edit

#defaultView:ImageGrid
SELECT ?item ?itemLabel ?ministere ?ministereLabel ?datedebut ?datefin ?image WHERE {
  VALUES ?target { wd:Q83307 wd:Q736559 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
    ?item p:P39 ?statement.
    ?statement ps:P39 ?ministere.
    ?ministere (wdt:P279*) ?target ;
      wdt:P17 wd:Q142.
  OPTIONAL { ?statement pq:P580 ?datedebut. }
  OPTIONAL { ?statement pq:P582 ?datefin. }
  OPTIONAL { ?item wdt:P18 ?image. }
}
ORDER BY DESC (?datedebut)

Try it!

Gouvernement actuel edit

SELECT ?item ?itemLabel ?ministere ?ministereLabel ?datedebut ?datefin  WHERE {
  VALUES ?target { wd:Q83307 wd:Q736559 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
    ?item p:P39 ?statement.
    ?statement ps:P39 ?ministere.
    ?ministere (wdt:P279*) ?target ;
      wdt:P17 wd:Q142.
  OPTIONAL { ?statement pq:P580 ?datedebut. }
  MINUS { ?statement pq:P582 ?datefin. }
}
ORDER BY DESC (?datedebut)

Try it!

Durée des mandats des premiers ministres edit

SELECT ?item ?itemLabel ?ministere ?ministereLabel ?datedebut ?datefin ?image ?duree_mandat WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
    ?item p:P39 ?statement.
    ?statement ps:P39 ?ministere.
    ?ministere (wdt:P279*) wd:Q1587677 ;
      wdt:P17 wd:Q142.
   ?statement pq:P580 ?datedebut.
   ?statement pq:P582 ?datefin.
   BIND( (?datefin - ?datedebut) AS ?duree_mandat )
  OPTIONAL { ?item wdt:P18 ?image. }
  FILTER(YEAR(?datedebut) >= 1945).
}
ORDER BY DESC (?duree_mandat)

Try it!

Durée des mandats cumulés des Premiers ministres edit

SELECT ?item ?itemLabel (SUM (?duree_mandat) AS ?duree) WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
    ?item p:P39 ?statement.
    ?statement ps:P39 ?ministere.
    ?ministere (wdt:P279*) wd:Q1587677 ;
      wdt:P17 wd:Q142.
   ?statement pq:P580 ?datedebut.
   ?statement pq:P582 ?datefin.
   BIND( (?datefin - ?datedebut) AS ?duree_mandat )
  FILTER(YEAR(?datedebut) >= 1945).
}
GROUP BY ?item ?itemLabel
ORDER BY DESC (?duree)

Try it!