English Wikipedia profile / Profil français sur Wikipédia / Curation UdeM

On the Shoulders of Cloud Giants: TTRPG Citation PracticesEdit

More details on the ongoing project (en français)

A cloudy graphEdit

#defaultView:Graph
SELECT DISTINCT ?item ?itemLabel ?cited_works ?cited_worksLabel 
WHERE
{
    {
      {?item wdt:P31 wd:Q1643932} 
      UNION 
      {?item wdt:P31 wd:Q2164067}
      UNION
      {?item wdt:P31 wd:Q71631512}
      UNION
      {?item wdt:P31 wd:Q4418079}      
    }. # instance = TTRPG or TTRPG system or supplement or setting
    ?item  wdt:P2860    ?cited_works. # which cites works
    {
      {?cited_works wdt:P31 wd:Q1643932}
      UNION 
      {?cited_works wdt:P31 wd:Q2164067}
      UNION
      {?cited_works wdt:P31 wd:Q71631512}
      UNION
      {?cited_works wdt:P31 wd:Q4418079} 
    }. # that are TTRPG or TTRPG system or supplement or setting  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Try it!

Or a clean tableEdit

SELECT DISTINCT ?item ?itemLabel ?cited_works ?cited_worksLabel 
WHERE
{
    {
      {?item wdt:P31 wd:Q1643932} 
      UNION 
      {?item wdt:P31 wd:Q2164067}
      UNION
      {?item wdt:P31 wd:Q71631512}
      UNION
      {?item wdt:P31 wd:Q4418079}      
    }. # instance = TTRPG or TTRPG system or supplement or setting
    ?item  wdt:P2860    ?cited_works. # which cites works
    {
      {?cited_works wdt:P31 wd:Q1643932}
      UNION 
      {?cited_works wdt:P31 wd:Q2164067}
      UNION
      {?cited_works wdt:P31 wd:Q71631512}
      UNION
      {?cited_works wdt:P31 wd:Q4418079} 
    }. # that are TTRPG or TTRPG system or supplement or setting  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}
ORDER BY ?item ?cited_works

Try it!

TTRPG tool boxEdit

Mix'n'Match with RPGGeekEdit

Access to MnM:RPGGeek (follow-up page)

NB: if several editions of the same item, please link to the 1st edition only (or manually link to /rpg or /rpgfamily).

List of all TTRPG related items in WikidataEdit

SELECT DISTINCT ?item ?itemLabel ?instance ?instanceLabel ?date ?author ?authorLabel ?RPGGeek_ID WHERE {
  {
    { ?item wdt:P31 wd:Q1643932. } #TTRPG
    UNION
    { ?item wdt:P31 wd:Q2164067. } #System
    UNION
    { ?item wdt:P31 wd:Q71631512. } #supplement
    UNION
    { ?item wdt:P31 wd:Q4418079. } #setting
    UNION
    { ?item wdt:P31 wd:Q4686479. } #adventure, campaign
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  OPTIONAL { ?item wdt:P31 ?instance. }
  OPTIONAL { ?item wdt:P577 ?date.}
  OPTIONAL { ?item (wdt:P50|wdt:P170|wdt:P2093) ?author.}  
  OPTIONAL { ?item wdt:P7226 ?RPGGeek_ID. }
}
ORDER BY (?itemLabel)

Try it!

Game mechanics (Q1751513) tool boxesEdit

All items with Instance/Part/Subclass = Q1751513Edit

SELECT DISTINCT ?item ?itemLabel ?instanceof ?partof ?subclassof
WHERE 
{
  ?item (wdt:P31|wdt:P361|wdt:P279) wd:Q1751513.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  OPTIONAL { ?item wdt:P31 ?instanceof. }
  OPTIONAL { ?item wdt:P361 ?partof. }
  OPTIONAL { ?item wdt:P279 ?subclassof. }  
}

Try it!

Subclasses of Q1751513 as graphEdit

#defaultView:Graph
SELECT DISTINCT ?item ?itemLabel ?instanceof ?partof ?subclassof ?linkTo
WHERE 
{
  ?item wdt:P279* wd:Q1751513.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  OPTIONAL { ?item wdt:P279 ?linkTo. }  
}

Try it!

All Q1751513 currently used, and by whatEdit

SELECT ?game_mechanic ?game_mechanicLabel ?item ?itemLabel 
WHERE 
{
  ?item wdt:P4151 ?game_mechanic
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
ORDER BY ?game_mechanic

Try it!

RPG designersEdit

All Q54845077 (RPG designers) with RPGGeek ID or notEdit

SELECT ?role_playing_game ?role_playing_gameLabel ?RPGGeek_ID ?role_playing_gameDescription WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?role_playing_game wdt:P106 wd:Q54845077.
  OPTIONAL { ?role_playing_game wdt:P7226 ?RPGGeek_ID. }
}

Try it!


All works by an authorEdit

Use the full name AND the item Q of the designer

SELECT DISTINCT  ?author ?authorLabel ?book ?date_de_publication WHERE {
 {?author ?label "Greg Stafford". #enter the full name here
  ?book ((wdt:P170)|(wdt:P50)|(wdt:P287)|(wdt:P123)|(wdt:P61)|(wdt:P86)|(wdt:P178)|(wdt:P943)|(wdt:P112)|(wdt:P193)|(wdt:P676)|(wdt:P175)|(wdt:P84)|(wdt:P110)|(wdt:P1779)|(wdt:P6338))  ?author .}
  UNION
 {?author ((wdt:P170)|(wdt:P50)|(wdt:P287)|(wdt:P123)|(wdt:P61)|(wdt:P86)|(wdt:P178)|(wdt:P943)|(wdt:P112)|(wdt:P193)|(wdt:P676)|(wdt:P175)|(wdt:P84)|(wdt:P110)|(wdt:P1779)|(wdt:P6338)) wd:Q2246520.} #enter the item Q of the author here
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
   OPTIONAL { ?author wdt:P577 ?date_de_publication. }
}

Try it!