Samwilson

Babel user information
en-N This user has a native understanding of English. en-GB-N This user has a native understanding of British English. nys-0 This user has no knowledge of Nyunga (or understands it with considerable difficulty).
Users by language

This user is a member of the WikiProject Books.

• 19th Century Australian literature
• Australian population data
• CiteProperties.json
• CiteTool.js
• CreateNewEntity.js
• Libraries in Australia
• common.js

Western Australian railway stations (with no end dates)

The following query uses these:

• Items: railway station (Q55488)   , Western Australia (Q3206)   

• Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , coordinate location (P625)   , connecting line (P81)   , image (P18)   , end time (P582)   

  SELECT ?station ?stationLabel ?article ?lgaLabel ?connectingLineLabel ?image ?coords WHERE {
    ?station wdt:P31 wd:Q55488 .
    ?station wdt:P131* wd:Q3206 .
    ?station wdt:P131 ?lga .
    OPTIONAL{
      ?article schema:about ?station .
      ?article schema:isPartOf <https://en.wikipedia.org/>
    } .
    OPTIONAL{ ?station wdt:P625 ?coords } .
    OPTIONAL{ ?station wdt:P81 ?connectingLine } .
    OPTIONAL{ ?station wdt:P18 ?image } .
    MINUS { OPTIONAL{ ?station wdt:P582 ?endDate } } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  ORDER BY ?stationLabel
  

Run it!

WA local history GLAMs

These can also be browsed via the Monumental GLAM tool at https://tools.wmflabs.org/monumental-glam/#/list/3206?c=-25.5226:123.2446:5

The following query uses these:

• Items: local museum (Q1595639)   , local history archive (Q27032320)   , historical society (Q13723070)   , Western Australia (Q3206)   

• Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , official website (P856)   , coordinate location (P625)   

  SELECT DISTINCT ?instanceOfLabel ?item ?itemLabel ?lgaLabel ?website ?coords
  WHERE {
    { ?item wdt:P31 wd:Q1595639 }
    UNION { ?item wdt:P31 wd:Q27032320 }
    UNION { ?item wdt:P31 wd:Q13723070 } .
    ?item wdt:P31 ?instanceOf .
    ?item wdt:P131* wd:Q3206 .
    ?item wdt:P131 ?lga .
    OPTIONAL{ ?item wdt:P856 ?website } .
    OPTIONAL{ ?item wdt:P625 ?coords } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  ORDER BY ?itemLabel
  

Run it!

Libraries in Australia

The following query uses these:

• Items: library (Q7075)   , public library (Q28564)   , academic library (Q856234)   , Australia (Q408)   

• Properties: instance of (P31)   , country (P17)   , coordinate location (P625)   , image (P18)   , official website (P856)   

Features: Map (Q24515275)   

#defaultView:Map
SELECT ?library ?libraryLabel ?libraryDescription ?coordinate_location ?image ?website ?layer WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  { ?library wdt:P31 wd:Q7075 }
    UNION { ?library wdt:P31 wd:Q28564 }
    UNION { ?library wdt:P31 wd:Q856234 } .
  ?library wdt:P17 wd:Q408 .
  OPTIONAL { ?library wdt:P625 ?coordinate_location }
  OPTIONAL { ?library wdt:P18 ?image }
  BIND( IF( BOUND(?image), "", "Image needed!" ) AS ?layer )
  OPTIONAL { ?library wdt:P856 ?website }
}

Run it!

Streets in Fremantle

SELECT ?street ?streetLabel ?osmRelation ?namedAfterLabel ?image
  ( GROUP_CONCAT( DISTINCT ?coordinateLocation; SEPARATOR=' ' ) AS ?coordinateLocations )
  ( GROUP_CONCAT( DISTINCT ?locationLabel; SEPARATOR='; ' ) AS ?locations )
  ( GROUP_CONCAT( DISTINCT ?connectsWithLabel; SEPARATOR='; ' ) AS ?connectsWiths )
WHERE {
  { ?street wdt:P31 wd:Q79007 . } UNION { ?street wdt:P31 wd:Q34442 . } .
  ?street wdt:P131 wd:Q1455046 .
  OPTIONAL { ?street wdt:P625 ?coordinateLocation }
  OPTIONAL { ?street wdt:P2789 ?connectsWith }
  OPTIONAL { ?street wdt:P402 ?osmRelation }
  OPTIONAL { ?street wdt:P138 ?namedAfter }
  OPTIONAL { ?street wdt:P18 ?image }
  OPTIONAL { ?street wdt:P276 ?location }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" .
    ?street rdfs:label ?streetLabel .
    ?namedAfter rdfs:label ?namedAfterLabel .
    ?location rdfs:label ?locationLabel .
    ?connectsWith rdfs:label ?connectsWithLabel .
  }
}
GROUP BY ?street ?streetLabel ?osmRelation ?namedAfterLabel ?image
ORDER BY ?streetLabel

Run it!

OSM export of street names in a given area.

Wikisource books to download

The following query uses these:

• Properties: publication date (P577)   

  SELECT
    ?item ?itemLabel ?articleTitle ?pubDate
    (URI(CONCAT("https://tools.wmflabs.org/wsexport/tool/book.php?lang=he&format=epub-3&page=", ?articleTitle)) AS ?epubDownload)
  WHERE {
    ?item wdt:P577 ?pubDate .
    ?article schema:about ?item .
    ?article schema:name ?articleTitle .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],he". }
    ?article schema:isPartOf <https://he.wikisource.org/>
  }
  

Run it!

Fremantle suburbs

The following query uses these:

• Items: suburb (Q188509)   , City of Fremantle (Q1455046)   

• Properties: instance of (P31)   , located in the administrative territorial entity (P131)   , OpenStreetMap relation ID (P402)   , named after (P138)   

  SELECT ?suburb ?suburbLabel ?OSM_relation_ID ?named_afterLabel WHERE {
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    ?suburb wdt:P31 wd:Q188509.
    ?suburb wdt:P131 wd:Q1455046.
    OPTIONAL { ?suburb wdt:P402 ?OSM_relation_ID. }
    OPTIONAL { ?suburb wdt:P138 ?named_after. }
  }
  LIMIT 100
  

Run it!

Fremantle heritage places

The following query uses these:

• Items: City of Fremantle (Q1455046)   

• Properties: located in the administrative territorial entity (P131)   , inHerit Place Number (P2618)   , located on street (P669)   , OpenStreetMap relation ID (P402)   , named after (P138)   , coordinate location (P625)   , house number (P670)   

  SELECT ?item ?itemLabel ?inheritId ?streetLabel ?streetNumber ?osmRelation ?namedAfterLabel ?coords WHERE {
    ?item wdt:P131 wd:Q1455046 .
    ?item wdt:P2618 ?inheritId .
    OPTIONAL { ?item wdt:P669 ?street }
    OPTIONAL { ?item p:P669/pq:P670 ?streetNumber }
    OPTIONAL { ?item wdt:P402 ?osmRelation }
    OPTIONAL { ?item wdt:P138 ?namedAfter }
    OPTIONAL { ?item wdt:P625 ?coords }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Run it!

Geocoding from OpenStreetMap, with OpenRefine: https://gist.github.com/pdbartsch/5987932 (after house numbers are in OSM).

Burial plots at Fremantle cemetery

Search the MCB: https://portal.mcb.wa.gov.au/name-search/

The following query uses these:

• Items: human (Q5)   , Fremantle Cemetery (Q5501472)   

• Properties: instance of (P31)   , place of burial (P119)   , image of grave (P1442)   , burial plot reference (P965)   , coordinate location (P625)   

  SELECT DISTINCT ?item ?itemLabel ?itemDescription ?image ?plotRef ?plotCoords WHERE {
    ?item wdt:P31 wd:Q5 .
    ?item wdt:P119 wd:Q5501472 .
    OPTIONAL { ?item wdt:P1442 ?image . }
    OPTIONAL { ?item p:P119/pq:P965 ?plotRef . }
    OPTIONAL { ?item p:P119/pq:P625 ?plotCoords . }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Run it!