User:Silanoc/donjon

A propos de la série de BD donjon

Entrée principale :
- https://fr.wikipedia.org/wiki/Donjon_(bande_dessin%C3%A9e)
- https://www.wikidata.org/wiki/Q162328

Production

inspirer de https://www.wikidata.org/wiki/Wikidata:WikiProject_Comics,

série (donjon) - série de bande dessinée (Q14406742)
- sous-série (crepuscule, zenith...) - série de bande dessinée (Q14406742)
  - volume (coeur de canard...)

précédé par (P155)/suivi par (P156) sur les sous-série (impossible pour parade, monster et bonus) et les volumes de chaque sous-série

[Property:P478] pour le numérotation des tomes -99, 115..., comme élément.
[Property:P1545] pour l'ordre dans chaque sous série, en qualificatif de partei de "série"

les sous-séries

The following query uses these:

Items: Dungeon (Q162328)

Properties: part of (P361)   , follows (P155)   , followed by (P156)  
```
SELECT ?sous_serie ?sous_serieLabel ?précédé_parLabel ?suivi_parLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  OPTIONAL { ?sous_serie wdt:P155 ?précédé_par. }
  OPTIONAL { ?sous_serie wdt:P156 ?suivi_par. }
}
```

Try it!

les albums

Liste des album

The following query uses these:

Items: Dungeon (Q162328)

Properties: part of (P361)   , part of the series (P179)   , series ordinal (P1545)  
```
SELECT ?album ?albumLabel ?sous_serieLabel ?rang WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  ?album p:P179 ?partie.
         ?partie ps:P179 ?sous_serie;
         pq:P1545 ?rang.
  }
order by ?sous_serieLabel ?rang
```

Try it!

The following query uses these:

Items: Dungeon (Q162328)

Properties: part of (P361)   , part of the series (P179)   , volume (P478)  
```
SELECT ?album ?albumLabel ?sous_serieLabel ?numerotation WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  ?album wdt:P179 ?sous_serie;
         wdt:P478 ?numerotation.
}
order by ?sous_serieLabel ?numerotation
```

Try it!

Participations

Nombre d'album par scénariste

The following query uses these:

Items: Dungeon (Q162328)

Properties: part of (P361)   , part of the series (P179)   , volume (P478)   , screenwriter (P58)  
```
SELECT ?scénariste ?scénaristeLabel (count(?album) as ?nb_album)  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  ?album wdt:P179 ?sous_serie;
    wdt:P478 ?numerotation.
    ?album wdt:P58 ?scénariste.
}
group by ?scénariste ?scénaristeLabel
```

Try it!

Nombre d'album par dessinateur

The following query uses these:

Items: Dungeon (Q162328)

Properties: part of (P361)   , part of the series (P179)   , volume (P478)   , illustrator (P110)  
```
SELECT ?dessin ?dessinLabel (count(?album) as ?nb_album)  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  ?album wdt:P179 ?sous_serie;
    wdt:P478 ?numerotation.
    ?album wdt:P110 ?dessin.
}
group by ?dessin ?dessinLabel
order by desc(?nb_album)
```

Try it!

Nombre d'album par coloriste

The following query uses these:

Items: Dungeon (Q162328)

Properties: part of (P361)   , part of the series (P179)   , volume (P478)   , colorist (P6338)  
```
SELECT ?couleurs ?couleursLabel (count(?album) as ?nb_album)  WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  ?album wdt:P179 ?sous_serie;
    wdt:P478 ?numerotation.
    ?album wdt:P6338 ?couleurs.
}
group by ?couleurs ?couleursLabel
order by desc(?nb_album)
```

Try it!

les personnages

Les races

The following query uses these:

Items: Q118776617

Properties: instance of (P31)  
```
SELECT ?race_de_Terra_Amata ?race_de_Terra_AmataLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?race_de_Terra_Amata wdt:P31 wd:Q118776617.
}
```

Try it!

The following query uses these:

Items: Dungeon (Q162328)   , comics character (Q1114461)

Properties: part of (P361)   , instance of (P31)   , present in work (P1441)  
```
SELECT DISTINCT ?personage_de_Donjon ?personage_de_DonjonLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?sous_serie wdt:P361 wd:Q162328.
  ?personage_de_Donjon wdt:P31 wd:Q1114461;
    wdt:P1441 ?sous_serie.
}
```

Try it!

tout

The following query uses these:

Items: Q118541520

Properties: from narrative universe (P1080)   , instance of (P31)  
```
SELECT ?Univers_de_Donjon ?Univers_de_DonjonLabel (GROUP_CONCAT(DISTINCT ?nature_de_l_élémentLabel; SEPARATOR = ", ") AS ?nature) WHERE {
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?nature_de_l_élément rdfs:label ?nature_de_l_élémentLabel.
    ?Univers_de_Donjon rdfs:label ?Univers_de_DonjonLabel.
  }
  ?Univers_de_Donjon wdt:P1080 wd:Q118541520;
    wdt:P31 ?nature_de_l_élément.
}
GROUP BY ?Univers_de_Donjon ?Univers_de_DonjonLabel
```

Try it!