Theklan

Babel user information
eu-N Erabiltzaile hau euskaldun zaharra da (euskara du ama hizkuntza). es-N Este usuario tiene una comprensión nativa del español. en-3 This user has advanced knowledge of English. fr-1 Cet utilisateur dispose de connaissances de base en français. ca-1 Aquest usuari té un coneixement bàsic de català. ss-0 Umuntfu cha ukhulúma siSwati (cha uva).
Users by language

Queries

Mammals that are in catalan Wikipedia but not in Basque

PREFIX schema: <http://schema.org/>

SELECT DISTINCT ?item ?taxonname ?familyLabel ?orderLabel ?sitelinks ?itemLabel WHERE {
  ?item wdt:P31 wd:Q16521.
  ?item wdt:P105 wd:Q7432.
  ?item wdt:P225 ?taxonname.
  ?item wdt:P171+ wd:Q7377.
  ?item wdt:P171+ ?family.
  ?family wdt:P105 wd:Q35409.
  ?family wdt:P171+ ?order.
  ?order wdt:P105 wd:Q36602.
  ?item wikibase:sitelinks ?sitelinks.
  ?cat schema:about ?item.
  ?cat schema:isPartOf <https://ca.wikipedia.org/>.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "la,eu". }
  FILTER(NOT EXISTS {
    ?wen schema:about ?item.
    ?wen schema:inLanguage "eu".
  })
  MINUS {?item wdt:P141 wd:Q237350.}
}
ORDER BY DESC(?sitelinks)
LIMIT 1000

Try it!

Wikidata Query Service + QuickCategories = ♥

SELECT ?titleEu ("+Category:Alemaniako futbolariak" AS ?command) WHERE {
  hint:Query hint:optimizer "None".
  SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:api "Generator";
                     wikibase:endpoint "en.wikipedia.org";
                     mwapi:generator "categorymembers";
                     mwapi:gcmtitle "Category:German_footballers";
                     mwapi:gcmnamespace 0;
                     mwapi:gcmprop "title";
                     mwapi:gcmlimit "max".
     ?titleEn_ wikibase:apiOutput mwapi:title.
  }
  BIND(STRLANG(?titleEn_, "en") AS ?titleEn)
  ?articleEn schema:name ?titleEn;
             schema:isPartOf <https://en.wikipedia.org/>;
             schema:about ?item.
  ?articleEu schema:about ?item;
             schema:isPartOf <https://eu.wikipedia.org/>;
             schema:name ?titleEu.
}

Copy the result, paste it into QuickCategories, submit the batch and run the commands. Try it out! --Lucas Werkmeister (eztabaida) 20:19, 29 martxoa 2019 (UTC)

With subcategory support:

SELECT ?titleEu ("+Category:BASQUE CATEGORY HERE" AS ?command) WHERE {
  hint:Query hint:optimizer "None".
  SERVICE <https://query.wikidata.org/bigdata/namespace/categories/sparql> {
    SERVICE mediawiki:categoryTree {
      bd:serviceParam mediawiki:start <https://en.wikipedia.org/wiki/Category:ENGLISH_CATEGORY_URL_HERE>;
                      mediawiki:direction "Reverse";
                      mediawiki:depth 5 . # change this if needed
    }
  }
  ?out schema:name ?categoryEn.
  SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:api "Generator";
                     wikibase:endpoint "en.wikipedia.org";
                     mwapi:generator "categorymembers";
                     mwapi:gcmtitle ?categoryEn;
                     mwapi:gcmnamespace 0;
                     mwapi:gcmprop "title";
                     mwapi:gcmlimit "max".
     ?titleEn_ wikibase:apiOutput mwapi:title.
  }
  BIND(STRLANG(?titleEn_, "en") AS ?titleEn)
  ?articleEn schema:name ?titleEn;
             schema:isPartOf <https://en.wikipedia.org/>;
             schema:about ?item.
  ?articleEu schema:about ?item;
             schema:isPartOf <https://eu.wikipedia.org/>;
             schema:name ?titleEu.
}
LIMIT 100