User:YULdigitalpreservation/SPARQLsoftware

This page lists SPARQL queries related to software that I have written

Software

How many pieces of software have minimal set of props

The following query uses these:

• Items: software (Q7397)   

• Properties: subclass of (P279)   , official website (P856)   , developer (P178)   , operating system (P306)   , programmed in (P277)   , source code repository URL (P1324)   , copyright license (P275)   , readable file format (P1072)   , writable file format (P1073)   , instance of (P31)   

  SELECT DISTINCT ?app ?appLabel ?url ?devLabel ?osLabel ?lanLabel ?repoLabel ?licenseLabel ?rfflabel ?wffLabel
  WHERE {
  ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P856 ?url.
    ?app wdt:P178 ?dev.
    ?app wdt:P306 ?os.
    ?app wdt:P277 ?lan.
    ?app wdt:P1324 ?repo.
    ?app wdt:P275 ?license.
    ?app wdt:P1072 ?rff.
    ?app wdt:P1073 ?wff.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  LIMIT 100
  

Try it!

How many pieces of software have minimal set of props using OPTIONAL

The following query uses these:

• Items: software (Q7397)   

• Properties: subclass of (P279)   , official website (P856)   , developer (P178)   , operating system (P306)   , programmed in (P277)   , source code repository URL (P1324)   , copyright license (P275)   , readable file format (P1072)   , writable file format (P1073)   , instance of (P31)   

  SELECT DISTINCT ?app ?appLabel ?url ?devLabel ?osLabel ?lanLabel ?repoLabel ?licenseLabel ?rfflabel ?wffLabel
  WHERE {
  ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    OPTIONAL {?app wdt:P856 ?url}.
     OPTIONAL {?app wdt:P178 ?dev}.
     OPTIONAL {?app wdt:P306 ?os}.
     OPTIONAL {?app wdt:P277 ?lan}.
     OPTIONAL {?app wdt:P1324 ?repo}.
     OPTIONAL {?app wdt:P275 ?license}.
     OPTIONAL {?app wdt:P1072 ?rff}.
     OPTIONAL {?app wdt:P1073 ?wff}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  LIMIT 10000
  

Try it!

How many pieces of software have these 4 props

The following query uses these:

• Items: software (Q7397)   

• Properties: subclass of (P279)   , operating system (P306)   , programmed in (P277)   , copyright license (P275)   , readable file format (P1072)   , instance of (P31)   

  SELECT DISTINCT ?app ?appLabel ?url ?devLabel ?osLabel ?lanLabel ?repoLabel ?licenseLabel ?rfflabel ?wffLabel
  WHERE {
  ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P306 ?os.
     ?app wdt:P277 ?lan.
    ?app wdt:P275 ?license.
    ?app wdt:P1072 ?rff.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Return a graph of the class/subclass relationships for software licenses

There is a button on WQS labled "Display". Clicking on that button will trigger a drop-down menu of visualization options. To see this as a graph select "Graph".

The following query uses these:

• Items: software license (Q207621)   

• Properties: subclass of (P279)   

  SELECT DISTINCT ?license ?licenseLabel ?subclassOf 
  WHERE {
    ?license wdt:P279* wd:Q207621 .
    OPTIONAL { ?license wdt:P279 ?subclassOf } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
  }
  ORDER BY ?licenseLabel
  

Try it!

Return a list of software titles, their licenses, and the superclass of licenses to which they belong

The following query uses these:

• Items: software (Q7397)   

• Properties: subclass of (P279)   , copyright license (P275)   , instance of (P31)   

  SELECT DISTINCT ?app ?appLabel ?licenseLabel ?classLabel
  WHERE {
    ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P275 ?license.
    ?license wdt:P279 ?class
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Create a bubble chart showing the license superclasses with the most software titles assigned to them

There is a button on WQS labled "Display". Clicking on that button will trigger a drop-down menu of visualization options. To see this as a graph select "Bubble Chart".

The following query uses these:

• Items: software (Q7397)   

• Properties: subclass of (P279)   , copyright license (P275)   , instance of (P31)   

  SELECT DISTINCT  ?license ?licenseLabel (COUNT(?app) AS ?count)
  WHERE {
    ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P275 ?license.
    ?license wdt:P279 ?class
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  
  GROUP BY ?license ?licenseLabel
  ORDER BY DESC(?count)
  

Try it!

Return a ranked list of the classes used to model 3D computing resources

There is a button on WQS labled "Display". Clicking on that button will trigger a drop-down menu of visualization options. To see this as a graph select "Bubble Chart".

The following query uses these:

• Items: 3D computer graphics (Q189177)   

• Properties: instance of (P31)   , has use (P366)   

  SELECT ?class ?classLabel (count(?software) AS ?count)
  
  WHERE {
    
    ?software wdt:P31 ?class .
    ?software wdt:P366 wd:Q189177 .
              
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  
  GROUP BY ?class ?classLabel
  ORDER BY DESC(?count)
  

Try it!

Return a list of all browsers based on Firefox

The following query uses these:

• Items: web browser (Q6368)   , Mozilla Firefox (Q698)   

• Properties: instance of (P31)   , based on (P144)   

  SELECT ?browser ?browserLabel 
  WHERE {
    ?browser wdt:P31 wd:Q6368.
    ?browser wdt:P144 wd:Q698.
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Return a timeline of all versions of Netscape Navigator

The following query uses these:

• Items: Netscape Navigator (Q235419)   

• Properties: subclass of (P279)   , publication date (P577)   

  #defaultView:Timeline
  SELECT ?version ?versionLabel ?year
  WHERE {
    ?version wdt:P279 wd:Q235419.
    ?version wdt:P577 ?year
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Return a timeline of all versions of Maya

The following query uses these:

• Items: Maya (Q272597)   

• Properties: subclass of (P279)   , publication date (P577)   

  #defaultView:Timeline
  SELECT ?app ?appLabel ?year WHERE {
    ?app wdt:P279 wd:Q272597.
    ?app wdt:P577 ?year .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Return an image grid of all creative works that used Autodesk Maya for animation

The following query uses these:

• Items: Maya (Q272597)   

• Properties: uses (P2283)   , image (P18)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT ?work ?workLabel ?image
WHERE {
  ?work wdt:P2283 wd:Q272597.
  ?work wdt:P18 ?image
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Return an image grid of all creative works that used Renderman for animation

The following query uses these:

• Items: RenderMan (Q855971)   

• Properties: uses (P2283)   , image (P18)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT ?work ?workLabel ?image WHERE {
  ?work wdt:P2283 wd:Q855971.
  ?work wdt:P18 ?image.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Return a list of all creative works that used Autodesk Maya for animation

The following query uses these:

• Items: Maya (Q272597)   

• Properties: uses (P2283)   

  SELECT ?work ?workLabel 
  WHERE {
    ?work wdt:P2283 wd:Q272597.
  
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Return a list of software titles that are used for 3D computer graphics

The following query uses these:

• Items: software (Q7397)   , 3D computer graphics (Q189177)   

• Properties: subclass of (P279)   , has use (P366)   , instance of (P31)   

  SELECT ?software ?softwareLabel 
  
  WHERE {
    
    ?software (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P366 wd:Q189177 .
              
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Return a list of scientific software and their associated Twitter accounts

The following query uses these:

• Items: software (Q7397)   , science (Q336)   

• Properties: subclass of (P279)   , has use (P366)   , X username (P2002)   , instance of (P31)   

  SELECT ?softwareLabel ?twitter
  
  WHERE {
    ?software (p:P31/ps:P31/wdt:P279*) wd:Q7397 .
    ?software wdt:P366 wd:Q336 .
    ?software wdt:P2002 ?twitter          
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Audio player software by license type

The following query uses these:

• Items: audio player software (Q758895)   

• Properties: subclass of (P279)   , copyright license (P275)   , instance of (P31)   

  SELECT DISTINCT ?player ?playerLabel ?licenseLabel
  WHERE {
    ?player (p:P31/ps:P31/wdt:P279*) wd:Q758895 .
    ?player wdt:P275 ?license .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
  }
  ORDER BY ?licenseLabel
  

Try it!

Return a list of CAD software by license type

The following query uses these:

• Items: computer-aided design software (Q15548076)   

• Properties: instance of (P31)   , subclass of (P279)   , copyright license (P275)   

  SELECT ?app ?appLabel ?licenseLabel ?date
  
  WHERE {
    ?app wdt:P31/wdt:P279* wd:Q15548076.
    ?app wdt:P275 ?license .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  
  ORDER BY ?license
  

Try it!

Software by Adventure Soft

The following query uses these:

• Items: video game (Q7889)   , Adventure Soft (Q379959)   

• Properties: instance of (P31)   , developer (P178)   

  SELECT ?item ?label 
  WHERE {
    ?item wdt:P31 wd:Q7889 .
    ?item wdt:P178 wd:Q379959 .
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
    
  }
  LIMIT 100
  

Try it!

Web server software and the languages they are written in

The following query uses these:

• Items: web server (Q11288)   

• Properties: instance of (P31)   , programmed in (P277)   

  SELECT ?app ?appLabel ?langLabel WHERE {
    ?app wdt:P31 wd:Q11288.
    ?app wdt:P277 ?lang .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

IRC clients and the operating systems they run on

The following query uses these:

• Items: IRC client (Q10417670)   

• Properties: instance of (P31)   , operating system (P306)   

  SELECT ?item ?itemLabel ?osLabel
  WHERE 
  {
    ?item wdt:P31 wd:Q10417670 .
    ?item wdt:P306 ?os .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Image grid of logo images for projects of the apache software foundation

The following query uses these:

• Items: Apache Software Foundation (Q489709)   

• Properties: developer (P178)   , logo image (P154)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT ?project ?projectLabel ?image
WHERE 
{
  ?project wdt:P178 wd:Q489709.
  ?project wdt:P154 ?image
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Software projects affiliated with Software in the Public Interest

The following query uses these:

• Items: Software in the Public Interest (Q685777)   

• Properties: affiliation (P1416)   

  SELECT ?item ?label WHERE {
    ?item wdt:P1416 wd:Q685777.
   
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
  }
  

Try it!

Image grid of logo images of software projects affiliated with Software in the Public Interest

The following query uses these:

• Items: Software in the Public Interest (Q685777)   

• Properties: affiliation (P1416)   , logo image (P154)   

Features: ImageGrid (Q24515278)   

#defaultView:ImageGrid
SELECT ?item ?label ?image WHERE {
  ?item wdt:P1416 wd:Q685777.
  ?item wdt:P154 ?image
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label
  }
}

Try it!

Software with entry on Open Hub

The following query uses these:

• Properties: Open Hub ID (P1972)   

  SELECT ?software ?softwareLabel  ?valueLabel
  {
  	?software wdt:P1972 ?value .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
  }
  LIMIT 1000
  

Try it!

Return a list of all intelligent personal assistant software in Wikidata

The following query uses these:

• Items: virtual assistant (Q3467906)   

• Properties: instance of (P31)   

  SELECT ?item ?label WHERE {
    {?item wdt:P31 wd:Q3467906}
    UNION {?item wdt:P31 wd:Q3467906}.
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
  }
  LIMIT 100
  

Try it!

Software repositories

The following query uses these:

• Items: software repository (Q1334294)   

• Properties: instance of (P31)   

  SELECT ?item ?label  WHERE {
    ?item wdt:P31 wd:Q1334294.
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
  }
  

Try it!

Media Player software by license type

The following query uses these:

• Items: media player software (Q210337)   

• Properties: subclass of (P279)   , copyright license (P275)   , instance of (P31)   

  SELECT DISTINCT ?player ?playerLabel ?licenseLabel WHERE {
    ?player (p:P31/ps:P31/wdt:P279*) wd:Q210337.
    ?player wdt:P275 ?license.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  ORDER BY ?licenseLabel
  

Try it!

Software for the Apple IIGS

The following query uses these:

• Items: Apple IIGS (Q1282269)   

• Properties: platform (P400)   , game mode (P404)   

  SELECT DISTINCT ?software ?softwareLabel ?modeLabel WHERE {
    ?software wdt:P400 wd:Q1282269.
    OPTIONAL {?software wdt:P404 ?mode}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software that have FLAC as a readable file format

The following query uses these:

• Items: software (Q7397)   , Free Lossless Audio Codec (Q27881556)   

• Properties: subclass of (P279)   , readable file format (P1072)   , instance of (P31)   

  SELECT DISTINCT ?app ?appLabel WHERE {
    ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P1072 wd:Q27881556.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software available under a free software license that can read FLAC and logos

The following query uses these:

• Items: software (Q7397)   , Free Lossless Audio Codec (Q27881556)   , free software license (Q3943414)   

• Properties: subclass of (P279)   , readable file format (P1072)   , copyright license (P275)   , instance of (P31)   , logo image (P154)   

  SELECT DISTINCT ?app ?appLabel ?licenseLabel ?logo WHERE {
    ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P1072 wd:Q27881556.
    ?app wdt:P275 ?license.
    ?license wdt:P31/wdt:P279* wd:Q3943414.
    ?app wdt:P154 ?logo.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software developed by Autodesk

The following query uses these:

• Items: software (Q7397)   , Autodesk (Q628051)   

• Properties: subclass of (P279)   , developer (P178)   , instance of (P31)   

  SELECT ?item ?itemLabel WHERE {
    ?item (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?item wdt:P178 wd:Q628051.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Feed readers and the languages they are written in

The following query uses these:

• Items: news aggregator (Q498267)   

• Properties: instance of (P31)   , programmed in (P277)   

  SELECT ?app ?appLabel ?langLabel WHERE {
    ?app wdt:P31 wd:Q498267.
    ?app wdt:P277 ?lang.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software titles that contain the word "winter"

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   

  SELECT DISTINCT ?app ?appLabel 
  WHERE {
    ?app (wdt:P31/wdt:P279*) wd:Q7397.
    ?app rdfs:label ?appLabel.
    FILTER(CONTAINS(?appLabel, "winter")).
    
  }
  LIMIT 100
  

Try it!

Graph of subclasses of computer graphics software

The following query uses these:

• Items: graphics software (Q868410)   

• Properties: subclass of (P279)   , image (P18)   

Features: Graph (Q24515287)   

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q868410 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Debuggers and the operating systems they run on

The following query uses these:

• Items: debugger (Q193231)   

• Properties: instance of (P31)   , operating system (P306)   

  SELECT ?debugger ?debuggerLabel ?osLabel
  WHERE 
  {
    ?debugger wdt:P31 wd:Q193231.
    ?debugger wdt:P306 ?os.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software used for 3D graphics by license

The following query uses these:

• Items: software (Q7397)   , 3D computer graphics (Q189177)   

• Properties: subclass of (P279)   , has use (P366)   , copyright license (P275)   , instance of (P31)   

  SELECT ?software ?softwareLabel ?licenseLabel
  
  WHERE {
    
    ?software (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P366 wd:Q189177 .
    ?software wdt:P275 ?license.
              
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Software use for 3D graphics by license with logo image

The following query uses these:

• Items: software (Q7397)   , 3D computer graphics (Q189177)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , copyright license (P275)   , logo image (P154)   

  SELECT DISTINCT ?software ?softwareLabel ?licenseLabel ?image
  
  WHERE {
    
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P366 wd:Q189177 .
    ?software wdt:P275 ?license.
    OPTIONAL {?software wdt:P154 ?image}.
              
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Bubble chart of 3d graphics software titles ranked by count of readable file formats

The following query uses these:

• Items: software (Q7397)   , 3D computer graphics (Q189177)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , readable file format (P1072)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart
SELECT DISTINCT ?software ?softwareLabel  (count (?ff) as ?count)

WHERE {
  
  ?software wdt:P31/wdt:P279* wd:Q7397.
  ?software wdt:P366 wd:Q189177 .
  ?software wdt:P1072 ?ff.
           
  SERVICE wikibase:label {
		bd:serviceParam wikibase:language "en" .
    
}
  }

GROUP BY ?software ?softwareLabel

ORDER BY DESC(?count)

Try it!

Bubble chart of women developers in order of number of software titles they have developed

The following query uses these:

• Items: software (Q7397)   , human (Q5)   , female (Q6581072)   

• Properties: subclass of (P279)   , developer (P178)   , instance of (P31)   , sex or gender (P21)   

  SELECT ?developer ?developerLabel (COUNT(?software) AS ?count) WHERE {
    ?software (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P178 ?developer.
    ?developer wdt:P31 wd:Q5.
    ?developer wdt:P21 wd:Q6581072.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  GROUP BY ?developer ?developerLabel
  ORDER BY DESC(?count)
  

Try it!

Bubble chart of CAD software by count of readable file formats

The following query uses these:

• Items: computer-aided design software (Q15548076)   

• Properties: instance of (P31)   , subclass of (P279)   , readable file format (P1072)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart
SELECT ?app ?appLabel (count (?ff) as ?count)

WHERE {
  ?app wdt:P31/wdt:P279* wd:Q15548076.
  OPTIONAL {?app wdt:P1072 ?ff.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

GROUP BY ?app ?appLabel


ORDER BY DESC(?count)

Try it!

Software with an external ID for the FSF Resource Directory

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Free Software Directory entry (P2537)   

  SELECT ?software ?softwareLabel WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P2537 ?entry.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software with an external ID for the FSF Resource Directory with logo images

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Free Software Directory entry (P2537)   , logo image (P154)   

  SELECT ?software ?softwareLabel ?image WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P2537 ?entry.
    ?software wdt:P154 ?image
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Feed readers by OS and license

The following query uses these:

• Items: news aggregator (Q498267)   

• Properties: instance of (P31)   , operating system (P306)   , copyright license (P275)   , logo image (P154)   

  SELECT DISTINCT ?app ?appLabel ?osLabel ?licLabel ?image WHERE {
    ?app wdt:P31 wd:Q498267.
    ?app wdt:P306 ?os.
    ?app wdt:P275 ?lic.
    ?app wdt:P154 ?image.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software of the Gnu Project

The following query uses these:

• Items: GNU Project (Q7598)   

• Properties: developer (P178)   , logo image (P154)   

  SELECT ?software ?softwareLabel ?logo WHERE {
    ?software  wdt:P178 wd:Q7598.
    OPTIONAL {?software wdt:P154 ?logo.}
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software that powers Wikidata and license info

The following query uses these:

• Items: Wikidata (Q2013)   

• Properties: software engine (P408)   , copyright license (P275)   

  SELECT ?engine ?engineLabel ?license ?licenseLabel
  WHERE 
  {
    wd:Q2013 wdt:P408 ?engine.
    ?engine wdt:P275 ?license.
    SERVICE wikibase:label 
            { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software available under a free software license that can read .epub files

The following query uses these:

• Items: software (Q7397)   , EPUB (Q475488)   , free software license (Q3943414)   

• Properties: subclass of (P279)   , readable file format (P1072)   , copyright license (P275)   , instance of (P31)   , logo image (P154)   

  SELECT DISTINCT ?app ?appLabel ?licenseLabel ?logo WHERE {
    ?app (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P1072 wd:Q475488.
    ?app wdt:P275 ?license.
    ?license (wdt:P31/wdt:P279*) wd:Q3943414.
    ?app wdt:P154 ?logo.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

SDKs and logo images

The following query uses these:

• Items: software development kit (Q467707)   

• Properties: instance of (P31)   , logo image (P154)   

  SELECT ?sdk ?sdkLabel ?image WHERE {
    ?sdk wdt:P31 wd:Q467707.
    OPTIONAL {?sdk wdt:P154 ?image.}
    
    SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
  }
  

Try it!

Scientific software by license and logo

The following query uses these:

• Items: software (Q7397)   , science (Q336)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , copyright license (P275)   , logo image (P154)   

  SELECT ?software ?softwareLabel ?licenseLabel ?logo WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P366 wd:Q336.
    OPTIONAL {?software wdt:P275 ?license.}
    OPTIONAL {?software wdt:P154 ?logo.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software of KDE Applications bundle and external identifiers

The following query uses these:

• Items: software (Q7397)   , KDE Gear (Q20712193)   

• Properties: instance of (P31)   , subclass of (P279)   , part of (P361)   , Free Software Directory entry (P2537)   , Open Hub ID (P1972)   , Framalibre ID (P4107)   , logo image (P154)   

  SELECT ?software ?softwareLabel ?fsf ?hub ?fram ?logo WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P361 wd:Q20712193.
    OPTIONAL {?software wdt:P2537 ?fsf.}
    OPTIONAL {?software wdt:P1972 ?hub.}
    OPTIONAL {?software wdt:P4107 ?fram.}
    OPTIONAL {?software wdt:P154 ?logo.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software used for sequence alignment by license and programming language

The following query uses these:

• Items: software (Q7397)   , sequence alignment (Q827246)   , multiple sequence alignment (Q1377767)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , copyright license (P275)   , programmed in (P277)   

  SELECT DISTINCT ?software ?softwareLabel ?licenseLabel ?langLabel WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    {?software wdt:P366 wd:Q827246}
    UNION {?software wdt:P366 wd:Q1377767.}
    OPTIONAL {?software wdt:P275 ?license.}
    OPTIONAL {?software wdt:P277 ?lang}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software for the CP/M operating system

The following query uses these:

• Items: software (Q7397)   , CP/M (Q219528)   

• Properties: instance of (P31)   , subclass of (P279)   , operating system (P306)   , image (P18)   

  SELECT ?software ?softwareLabel ?image
  WHERE 
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P306 wd:Q219528.
    OPTIONAL {?software wdt:P18 ?image}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software named after Pi

The following query uses these:

• Items: software (Q7397)   , pi (Q167)   

• Properties: instance of (P31)   , subclass of (P279)   , named after (P138)   

  SELECT ?software ?softwareLabel  WHERE {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P138 wd:Q167.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }
  

Try it!

Software that is described in the FSF resource directory and also has a Flatpack ID

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Free Software Directory entry (P2537)   , Flathub ID (P4655)   

  SELECT ?software ?softwareLabel ?entryLabel ?flatLabel WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P2537 ?entry.
    ?software wdt:P4655 ?flat
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software developers and their ISNI numbers

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , developer (P178)   , ISNI (P213)   

  SELECT DISTINCT ?software ?softwareLabel ?devLabel ?ISNI
  WHERE 
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P178 ?dev.
    ?dev wdt:P213 ?ISNI.
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles and their subreddits

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , subreddit (P3984)   

  SELECT DISTINCT ?software ?softwareLabel ?subreddit
  WHERE 
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P3984 ?subreddit.
   
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Free Software External IDs

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Free Software Directory entry (P2537)   , Debian stable package (P3442)   , Fedora package (P3463)   , Ubuntu package (P3473)   , Gentoo package (P3499)   , Arch Linux package (P3454)   

  SELECT ?software ?softwareLabel ?deb ?fed ?gen ?arch WHERE {
    ?software (wdt:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P2537 ?entry.
    OPTIONAL {?software wdt:P3442 ?deb.}
    OPTIONAL {?software wdt:P3463 ?fed.}
    OPTIONAL {?software wdt:P3473 ?ubu.}
    OPTIONAL {?software wdt:P3499 ?gen.}
    OPTIONAL {?software wdt:P3454 ?arch.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software developed by United States Department of Energy national laboratories

The following query uses these:

• Items: United States national laboratory (Q2624320)   

• Properties: instance of (P31)   , developer (P178)   

  SELECT ?item ?itemLabel ?software ?softwareLabel
  WHERE 
  {
    ?item wdt:P31 wd:Q2624320.
    ?software wdt:P178 ?item.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software written in Lisp

The following query uses these:

• Items: Lisp (Q132874)   

• Properties: programmed in (P277)   

  SELECT DISTINCT ?software  ?softwareLabel 
  
  WHERE {
    ?software wdt:P277 wd:Q132874
    
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Software written in Lisp and logo images

The following query uses these:

• Items: Lisp (Q132874)   

• Properties: programmed in (P277)   , logo image (P154)   

  SELECT DISTINCT ?software  ?softwareLabel ?logo
  
  WHERE {
    ?software wdt:P277 wd:Q132874.
    OPTIONAL {?software wdt:P154 ?logo.}
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Member projects of the Software Freedom Conservancy by license and logo

The following query uses these:

• Items: Software Freedom Conservancy (Q2896872)   

• Properties: part of (P361)   , copyright license (P275)   , logo image (P154)   

  SELECT ?app ?appLabel ?licenseLabel ?image WHERE {
    ?app wdt:P361 wd:Q2896872.
    OPTIONAL {?app wdt:P275 ?license.}
    OPTIONAL {?app wdt:P154 ?image.}
    
    
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

File formats that Diffoscope can compare

The following query uses these:

• Items: diffoscope (Q50989245)   

• Properties: readable file format (P1072)   , file extension (P1195)   , media type (P1163)   

  SELECT ?fileformat ?fileformatLabel ?ext ?media WHERE {
    wd:Q50989245 wdt:P1072 ?fileformat.
    OPTIONAL { ?fileformat wdt:P1195 ?ext. }
    OPTIONAL { ?fileformat wdt:P1163 ?media. }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software used for crystallography

The following query uses these:

• Items: software (Q7397)   , crystallography (Q160398)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   

  SELECT DISTINCT ?software ?softwareLabel WHERE {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P366 wd:Q160398.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Package Managers

The following query uses these:

• Items: package management system (Q891055)   

• Properties: instance of (P31)   , logo image (P154)   

  SELECT ?item ?itemLabel ?logo
  WHERE 
  {
    ?item wdt:P31 wd:Q891055.
    OPTIONAL {?item wdt:P154 ?logo.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software used for Crystallography

The following query uses these:

• Items: software (Q7397)   , crystallography (Q160398)   , X-ray crystallography (Q826582)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   

  SELECT DISTINCT ?software ?softwareLabel WHERE {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    {?software wdt:P366 wd:Q160398}
    UNION {?software wdt:P366 wd:Q826582.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software used for crystallography and scientific articles about the software titles

The following query uses these:

• Items: software (Q7397)   , crystallography (Q160398)   , X-ray crystallography (Q826582)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , main subject (P921)   

  SELECT DISTINCT ?software ?softwareLabel ?articleLabel WHERE {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    {?software wdt:P366 wd:Q160398}
    UNION {?software wdt:P366 wd:Q826582.}
    OPTIONAL {?article wdt:P921 ?software.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Software titles that can read .PNG files

The following query uses these:

• Items: Portable Network Graphics (Q178051)   

• Properties: readable file format (P1072)   , copyright license (P275)   , logo image (P154)   

  SELECT DISTINCT ?software ?softwareLabel ?licenseLabel ?image WHERE {
    ?software wdt:P1072 wd:Q178051.
    OPTIONAL { ?software wdt:P275 ?license. }
    OPTIONAL { ?software wdt:P154 ?image. }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

GAS graph of subclasses of compiler

The following query uses these:

• Items: compiler (Q47506)   

• Properties: subclass of (P279)   , image (P18)   

Features: Graph (Q24515287)   

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q47506 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Software titles (that are not video games) that do not have any readable file formats listed yet

The following query uses these:

• Items: software (Q7397)   , video game (Q7889)   

• Properties: instance of (P31)   , subclass of (P279)   , readable file format (P1072)   

  SELECT DISTINCT ?software ?softwareLabel 
  WHERE 
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    FILTER NOT EXISTS {?software wdt:P1072 ?ff}.
    MINUS {?software wdt:P31/wdt:P279* wd:Q7889.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles that have a link to their user's manual

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , user manual URL (P2078)   , logo image (P154)   

  SELECT ?software ?softwareLabel ?userManualLink ?logo
  WHERE 
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P2078 ?userManualLink.
    OPTIONAL {?software wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Scientific software and their user manuals and logo image

The following query uses these:

• Items: software (Q7397)   , science (Q336)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , user manual URL (P2078)   , logo image (P154)   

  SELECT DISTINCT ?software ?softwareLabel ?userManualLink ?logo
  
  WHERE {
    ?software wdt:P31/wdt:P279* wd:Q7397 .
     ?software wdt:P366 wd:Q336.
     ?software wdt:P2078 ?userManualLink.
    OPTIONAL {?software wdt:P154 ?logo}.      
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  

Try it!

Software titles with records in the LOC NAF with logo images

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Library of Congress authority ID (P244)   , logo image (P154)   

  SELECT DISTINCT ?software ?softwareLabel ?locNAFid ?logo
  WHERE 
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P244 ?locNAFid.
    OPTIONAL {?software wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles and dependencies

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , depends on software (P1547)   

  SELECT ?application ?applicationLabel ?softwareLabel
  WHERE 
  {
    ?application wdt:P31/wdt:P279* wd:Q7397.
    ?application wdt:P1547 ?software.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Bubble chart of software titles ranked by the number of dependencies listed for them in Wikidata

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , depends on software (P1547)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart
SELECT ?application ?applicationLabel  (COUNT(?software) AS ?count)
WHERE 
{
  ?application wdt:P31/wdt:P279* wd:Q7397.
  ?application wdt:P1547 ?software.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?application ?applicationLabel
ORDER BY DESC (?count)

LIMIT 60

Try it!

Software dependencies for systemd

The following query uses these:

• Items: systemd (Q286124)   

• Properties: depends on software (P1547)   , instance of (P31)   

  SELECT ?software ?softwareLabel ?classLabel
  WHERE 
  {
    
    wd:Q286124 wdt:P1547 ?software.
    ?software wdt:P31 ?class.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Bubble chart of Research Institutes by # of software titles developed

The following query uses these:

• Items: research institute (Q31855)   , software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , developer (P178)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart
SELECT  ?institute ?instituteLabel (COUNT (?software) AS ?COUNT)
WHERE 
{
  ?institute wdt:P31 wd:Q31855.
  ?software wdt:P31/wdt:P279* wd:Q7397.
  ?software wdt:P178 ?institute.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?institute ?instituteLabel

ORDER BY DESC (?count)

Try it!

Research institutes and the software they have developed with license info

The following query uses these:

• Items: research institute (Q31855)   , software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , developer (P178)   , copyright license (P275)   

  SELECT  ?institute ?instituteLabel ?software ?softwareLabel ?license ?licenseLabel
  WHERE 
  {
    ?institute wdt:P31 wd:Q31855.
    ?software wdt:P31/wdt:P279* wd:Q7397.
    ?software wdt:P178 ?institute.
    OPTIONAl {?software wdt:P275 ?license}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Individuals who are software developers by the number of software titles credited to them

The following query uses these:

• Items: software (Q7397)   , human (Q5)   , video game (Q7889)   

• Properties: subclass of (P279)   , developer (P178)   , instance of (P31)   

  SELECT ?developer ?developerLabel (COUNT(?software) AS ?count) WHERE {
    ?software (p:P31/ps:P31/wdt:P279*) wd:Q7397.
    ?software wdt:P178 ?developer.
    ?developer wdt:P31 wd:Q5
     MINUS {?software wdt:P31/wdt:P279* wd:Q7889.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  GROUP BY ?developer ?developerLabel
  ORDER BY DESC(?count)
  LIMIT 50
  

Try it!

Operating systems by the number of other operating systems based on them

The following query uses these:

• Items: operating system (Q9135)   

• Properties: instance of (P31)   , subclass of (P279)   , based on (P144)   

  SELECT ?os ?osLabel (COUNT(?item) AS ?count)
  WHERE 
  {
    ?item wdt:P31/wdt:P279* wd:Q9135.
    ?item wdt:P144 ?os.
    ?os wdt:P31/wdt:P279* wd:Q9135.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  
  GROUP BY ?os ?osLabel
  ORDER BY DESC (?count)
  

Try it!

Software that can read .stl files with license info and logo images

The following query uses these:

• Items: software (Q7397)   , STereoLithography (Q1238229)   

• Properties: instance of (P31)   , subclass of (P279)   , readable file format (P1072)   , copyright license (P275)   , logo image (P154)   

  SELECT DISTINCT ?app ?appLabel ?licLabel ?logo WHERE {
    ?app (wdt:P31/wdt:P279*) wd:Q7397.
    ?app wdt:P1072 wd:Q1238229.
    OPTIONAL {?app wdt:P275 ?lic.}
    OPTIONAL {?app wdt:P154 ?logo.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Timeline of software repositories

The following query uses these:

• Items: repository (Q3133368)   , software repository (Q1334294)   

• Properties: instance of (P31)   , inception (P571)   , logo image (P154)   

  SELECT ?item ?itemLabel ?date ?logo WHERE {
    {?item wdt:P31 wd:Q3133368.}
    UNION {?item wdt:P31 wd:Q1334294}.
    OPTIONAL {?item wdt:P571 ?date}.
    OPTIONAL {?item wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }
  

Try it!

Software funded by sponsor

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , sponsor (P859)   

  SELECT DISTINCT ?item ?itemLabel ?funder ?funderLabel
  WHERE 
  {
    ?item wdt:P31/wdt:P279* wd:Q7397.
    ?item wdt:P859 ?funder.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Everything with use 3D by type

The following query uses these:

• Items: 3D computer graphics (Q189177)   

• Properties: instance of (P31)   , has use (P366)   

  SELECT ?class ?classLabel  (COUNT(?software) AS ?count)
  
  WHERE {
    
    ?software wdt:P31 ?class.
    ?software wdt:P366 wd:Q189177 .
              
    SERVICE wikibase:label {
  		bd:serviceParam wikibase:language "en" .
      
  }
    }
  GROUP BY ?class ?classLabel
  
  ORDER BY DESC(?count)
  

Try it!

Research Projects that are credited with the development of software

The following query uses these:

• Items: research project (Q1298668)   

• Properties: instance of (P31)   , subclass of (P279)   , developer (P178)   

  SELECT ?item ?itemLabel ?software ?softwareLabel
  WHERE {
    ?item (wdt:P31/wdt:P279*) wd:Q1298668.
    ?software wdt:P178 ?item.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Organizations with a CrossRef Funder ID by the number of software titles they are credited with developing

The following query uses these:

• Properties: Open Funder Registry funder ID (P3153)   , developer (P178)   

  SELECT ?item ?itemLabel (COUNT(?software) AS ?count)
  WHERE 
  {
    ?item wdt:P3153 ?value .
    ?software wdt:P178 ?item.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  
  GROUP BY ?item ?itemLabel
  
  ORDER BY DESC(?count)
  

Try it!

software and sources of inspiration

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , inspired by (P941)   

  SELECT DISTINCT ?application ?applicationLabel ?inspirationLabel
  WHERE 
  {
    ?application wdt:P31/wdt:P279* wd:Q7397.
    ?application wdt:P941 ?inspiration.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

software that depends on a software title that is a member of the GNU project

The following query uses these:

• Items: GNU Project (Q7598)   

• Properties: part of (P361)   , depends on software (P1547)   

Features: Graph (Q24515287)   

#defaultView:Graph
SELECT ?char ?charLabel ?group ?groupLabel ("7FFF00" AS ?rgb) WHERE {
  ?group wdt:P361 wd:Q7598.
  ?char wdt:P1547 ?group.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Programming Languages that the software of the GNU Project is written in

The following query uses these:

• Items: GNU Project (Q7598)   

• Properties: developer (P178)   , programmed in (P277)   

Features: Graph (Q24515287)   

#Programming laguages in which software of the Gnu Project is written
#defaultView:Graph
SELECT ?software ?softwareLabel ?plang ?plangLabel ("00FFFF" AS ?rgb) WHERE {
  ?software wdt:P178 wd:Q7598.
  ?software wdt:P277 ?plang.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Types of software described in Wikidata

The following query uses these:

• Items: software category (Q28530532)   

• Properties: instance of (P31)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P31 wd:Q28530532.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software written in Rust and the type of software it is

The following query uses these:

• Items: software category (Q28530532)   , Rust (Q575650)   

• Properties: instance of (P31)   , subclass of (P279)   , programmed in (P277)   

  SELECT ?type ?typeLabel ?software ?softwareLabel 
  WHERE 
  {
    ?type wdt:P31 wd:Q28530532.
    ?software wdt:P31/wdt:P279* ?type.
    ?software wdt:P277 wd:Q575650.
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Content Management Systems described in Wikidata

The following query uses these:

• Items: content management system (Q131093)   

• Properties: instance of (P31)   , subclass of (P279)   

  SELECT DISTINCT ?item ?itemLabel WHERE {
    ?item wdt:P31/wdt:P279* wd:Q131093.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Content Management Systems by license

The following query uses these:

• Items: content management system (Q131093)   

• Properties: instance of (P31)   , subclass of (P279)   , copyright license (P275)   

  SELECT DISTINCT ?item ?itemLabel ?licenseLabel WHERE {
    ?item wdt:P31/wdt:P279* wd:Q131093.
    OPTIONAL {?item wdt:P275 ?license}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Content Management Systems available under free software licenses

The following query uses these:

• Items: content management system (Q131093)   , free software license (Q3943414)   

• Properties: instance of (P31)   , subclass of (P279)   , copyright license (P275)   

  SELECT DISTINCT ?item ?itemLabel ?licenseLabel 
  WHERE {
    ?item wdt:P31/wdt:P279* wd:Q131093.
    ?item wdt:P275 ?license.
    ?license (wdt:P31/wdt:P279*) wd:Q3943414.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

bubble chart of free software licenses used by cms software

The following query uses these:

• Items: content management system (Q131093)   , free software license (Q3943414)   

• Properties: instance of (P31)   , subclass of (P279)   , copyright license (P275)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart
SELECT DISTINCT  ?licenseLabel (COUNT(?item) AS ?count)
WHERE {
  ?item wdt:P31/wdt:P279* wd:Q131093.
  ?item wdt:P275 ?license.
  ?license (wdt:P31/wdt:P279*) wd:Q3943414.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?license ?licenseLabel

ORDER BY DESC(?count)

Try it!

software developed by a space agency

The following query uses these:

• Items: space agency (Q17505024)   

• Properties: instance of (P31)   , developer (P178)   

  SELECT ?item ?itemLabel ?software ?softwareLabel
  WHERE 
  {
    ?item wdt:P31 wd:Q17505024.
    ?software wdt:P178 ?item.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

javascript frameworks

The following query uses these:

• Items: JavaScript framework (Q24789150)   

• Properties: instance of (P31)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P31 wd:Q24789150.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

software developed by a federal agency of the United States

The following query uses these:

• Items: United States federal agency (Q20857065)   

• Properties: instance of (P31)   , subclass of (P279)   , developer (P178)   , logo image (P154)   

  SELECT ?agency ?agencyLabel ?softwareLabel ?logo
  WHERE 
  {
    ?agency wdt:P31/wdt:P279* wd:Q20857065.
    ?software wdt:P178 ?agency.
    OPTIONAL {?software wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

TedTalks that have a software title as a main subject

The following query uses these:

• Items: TED talk (Q23011722)   , software (Q7397)   

• Properties: instance of (P31)   , main subject (P921)   , subclass of (P279)   , logo image (P154)   

  SELECT ?talk ?talkLabel ?subjectLabel ?logo
  WHERE 
  {
    ?talk wdt:P31 wd:Q23011722.
    ?talk wdt:P921 ?subject.
    ?subject wdt:P31/wdt:P279* wd:Q7397.
    OPTIONAL {?subject wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Subclasses of software that are the topic of a Wikimedia list

The following query uses these:

• Items: software (Q7397)   

• Properties: subclass of (P279)   , has list (P2354)   

  SELECT ?item ?itemLabel ?list ?listLabel
  WHERE 
  {
    ?item wdt:P279* wd:Q7397.
    ?item wdt:P2354 ?list.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Disk partitioning software by OS

The following query uses these:

• Items: partition editor (Q24877948)   

• Properties: instance of (P31)   , operating system (P306)   

  SELECT ?item ?itemLabel ?osLabel
  WHERE 
  {
    ?item wdt:P31 wd:Q24877948.
    OPTIONAL {?item wdt:P306 ?os.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Apache modules and their stack exchange tags

The following query uses these:

• Items: Apache module (Q39690758)   

• Properties: instance of (P31)   , Stack Exchange tag (P1482)   

  SELECT ?item ?itemLabel ?stacktag
  WHERE 
  {
    ?item wdt:P31 wd:Q39690758.
    OPTIONAL {?item wdt:P1482 ?stacktag}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Audio player software by license and date

The following query uses these:

• Items: audio player software (Q758895)   

• Properties: instance of (P31)   , copyright license (P275)   , inception (P571)   

  SELECT ?item ?itemLabel ?licenseLabel ?inception
  WHERE 
  {
    ?item wdt:P31 wd:Q758895.
    OPTIONAL {?item wdt:P275 ?license.}
    OPTIONAL {?item wdt:P571 ?inception.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Audio player software by license, date, and logo

The following query uses these:

• Items: audio player software (Q758895)   

• Properties: instance of (P31)   , copyright license (P275)   , inception (P571)   , logo image (P154)   

  SELECT ?item ?itemLabel ?licenseLabel ?inception ?logo
  WHERE 
  {
    ?item wdt:P31 wd:Q758895.
    OPTIONAL {?item wdt:P275 ?license.}
    OPTIONAL {?item wdt:P571 ?inception.}
    OPTIONAL {?item wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

businesses related to software

The following query uses these:

• Items: software (Q7397)   

• Properties: product or material produced or service provided (P1056)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P1056 ?software.
    ?software wdt:P31/wdt:P279*   wd:Q7397.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

disk part software

The following query uses these:

• Items: partition editor (Q24877948)   

• Properties: instance of (P31)   , programmed in (P277)   , copyright license (P275)   , developer (P178)   

  SELECT ?item ?itemLabel ?programmingLabel ?licenseLabel ?devLabel WHERE {
    ?item wdt:P31 wd:Q24877948.
    OPTIONAL {?item wdt:P277 ?programming. }
    OPTIONAL {?item wdt:P275 ?license. }
    OPTIONAL {?item wdt:P178 ?dev. }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

software libraries that have their own twitter account and logo

The following query uses these:

• Items: software library (Q188860)   

• Properties: instance of (P31)   , X username (P2002)   , logo image (P154)   

  SELECT ?item ?itemLabel ?twitter ?logo
  WHERE 
  {
    ?item wdt:P31 wd:Q188860.
    ?item wdt:P2002 ?twitter.
    OPTIONAL {?item wdt:P154 ?logo.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles that use the Qt framework

The following query uses these:

• Items: Qt (Q201904)   

• Properties: GUI toolkit or framework (P1414)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P1414 wd:Q201904.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Computer Algebra Systems

The following query uses these:

• Items: computer algebra system (Q830340)   

• Properties: instance of (P31)   , developer (P178)   , copyright license (P275)   , programmed in (P277)   

  SELECT ?item ?itemLabel ?devLabel ?licLabel ?plangLabel
  WHERE 
  {
    ?item wdt:P31 wd:Q830340.
    OPTIONAL {?item wdt:P178 ?dev.}
    OPTIONAL {?item wdt:P275 ?lic.}
    OPTIONAL {?item wdt:P277 ?plang.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Webservices

The following query uses these:

• Items: web service (Q193424)   

• Properties: instance of (P31)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P31 wd:Q193424.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Knowledgebases and content

The following query uses these:

• Items: knowledge base (Q593744)   

• Properties: instance of (P31)   , subclass of (P279)   , field of work (P101)   , industry (P452)   , main subject (P921)   

  SELECT ?item ?itemLabel ?fieldLabel ?industryLabel ?subjectLabel
  WHERE 
  {
    ?item (wdt:P31/wdt:P279*) wd:Q593744.
    OPTIONAL {?item wdt:P101 ?field.}
    OPTIONAL {?item wdt:P452 ?industry.}
    OPTIONAL {?item wdt:P921 ?subject.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Genealogy software

The following query uses these:

• Items: genealogy software (Q75050)   

• Properties: instance of (P31)   , developer (P178)   , inception (P571)   , logo image (P154)   

  SELECT ?item ?itemLabel ?developerLabel ?date ?logo
  WHERE 
  {
    ?item wdt:P31 wd:Q75050.
    OPTIONAL {?item wdt:P178 ?developer}.
    OPTIONAL {?item wdt:P571 ?date}.
    OPTIONAL {?item wdt:P154 ?logo}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software for the Amstrad CPC

The following query uses these:

• Items: Amstrad CPC (Q478829)   

• Properties: platform (P400)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P400 wd:Q478829.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles with BBC Things ID

The following query uses these:

• Items: software (Q7397)   

• Properties: BBC Things ID (P1617)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?thingsID 
  WHERE 
  {
    ?item wdt:P1617 ?thingsID.
    ?item wdt:P31/wdt:P279* wd:Q7397.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles with a GoogleNews ID

The following query uses these:

• Items: software (Q7397)   

• Properties: Google News topics ID (P5337)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel ?newsID 
  WHERE 
  {
    ?item wdt:P5337 ?newsID.
    ?item wdt:P31/wdt:P279* wd:Q7397.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software GraphViz depends on

The following query uses these:

• Items: Graphviz (Q260889)   

• Properties: depends on software (P1547)   , logo image (P154)   

  SELECT ?software ?softwareLabel ?logo WHERE {
    wd:Q260889 wdt:P1547 ?software.
    OPTIONAL {?software wdt:P154 ?logo}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Anything with product or material produced software

The following query uses these:

• Items: software (Q7397)   

• Properties: product or material produced or service provided (P1056)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P1056 wd:Q7397.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Orgs with a GRID id and by the count of software titles they have developed

The following query uses these:

• Properties: GRID ID (P2427)   , developer (P178)   

  SELECT ?item ?itemLabel (COUNT(?software) AS ?count)
  WHERE 
  {
    ?item wdt:P2427 ?value .
    ?software wdt:P178 ?item.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  
  GROUP BY ?item ?itemLabel
  
  ORDER BY DESC(?count)
  

Try it!

Orgs with a GRID id and the count of software titles (that are not video games) that they have developed

The following query uses these:

• Items: software (Q7397)   , video game (Q7889)   

• Properties: GRID ID (P2427)   , developer (P178)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel (COUNT(?software) AS ?count)
  WHERE 
  {
    ?item wdt:P2427 ?value .
    ?software wdt:P178 ?item.
    ?software wdt:P31/wdt:P279* wd:Q7397.
    MINUS {?software wdt:P31/wdt:P279* wd:Q7889.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  
  GROUP BY ?item ?itemLabel
  
  ORDER BY DESC(?count)
  

Try it!

Orgs with Ringgold ID and the count of software titles (that are not video games) that they have developed

The following query uses these:

• Items: software (Q7397)   , video game (Q7889)   

• Properties: Ringgold ID (P3500)   , developer (P178)   , instance of (P31)   , subclass of (P279)   

  SELECT ?item ?itemLabel (COUNT(?software) AS ?count)
  WHERE 
  {
    ?item wdt:P3500 ?value .
    ?software wdt:P178 ?item.
    ?software wdt:P31/wdt:P279* wd:Q7397.
    MINUS {?software wdt:P31/wdt:P279* wd:Q7889.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  
  GROUP BY ?item ?itemLabel
  
  ORDER BY DESC(?count)
  

Try it!

Software developed by organizations with a Ringgold ID

The following query uses these:

• Items: software (Q7397)   , video game (Q7889)   

• Properties: Ringgold ID (P3500)   , developer (P178)   , instance of (P31)   , subclass of (P279)   

  SELECT DISTINCT ?item ?itemLabel ?software ?softwareLabel
  WHERE 
  {
    ?item wdt:P3500 ?value .
    ?software wdt:P178 ?item.
    ?software wdt:P31/wdt:P279* wd:Q7397.
    MINUS {?software wdt:P31/wdt:P279* wd:Q7889.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Graph of subclasses of OS

The following query uses these:

• Items: operating system (Q9135)   

• Properties: subclass of (P279)   , image (P18)   

Features: Graph (Q24515287)   

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q9135 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Graph of subclasses of macos

The following query uses these:

• Items: Macintosh operating systems (Q43627)   

• Properties: subclass of (P279)   , image (P18)   

Features: Graph (Q24515287)   

#defaultView:Graph
PREFIX gas: <http://www.bigdata.com/rdf/gas#>

SELECT ?item ?itemLabel ?pic ?linkTo
WHERE
{
  SERVICE gas:service {
    gas:program gas:gasClass "com.bigdata.rdf.graph.analytics.SSSP" ;
                gas:in wd:Q43627 ;
                gas:traversalDirection "Reverse" ;
                gas:out ?item ;
                gas:out1 ?depth ;
                gas:maxIterations 4 ;
                gas:linkType wdt:P279 .
  }
  OPTIONAL { ?item wdt:P279 ?linkTo }
  OPTIONAL { ?item wdt:P18 ?pic }
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en" }
}

Try it!

Quantum computers

The following query uses these:

• Items: quantum computer (Q176555)   

• Properties: instance of (P31)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P31 wd:Q176555.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

NVIDIA manufactures

The following query uses these:

• Items: Nvidia (Q182477)   

• Properties: manufacturer (P176)   

  SELECT  ?NVIDIAmanufactures ?NVIDIAmanufacturesLabel 
  WHERE 
  {
    ?NVIDIAmanufactures wdt:P176 wd:Q182477.
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

NVIDIA develops

The following query uses these:

• Items: Nvidia (Q182477)   

• Properties: developer (P178)   

  SELECT  ?NVIDIAdevelops  ?NVIDIAdevelopsLabel 
  WHERE 
  {
    ?NVIDIAdevelops wdt:P178 wd:Q182477.
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software with Internet Archive ID

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Internet Archive ID (P724)   

  SELECT ?software ?softwareLabel ?archiveID
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
     ?software wdt:P724 ?archiveID.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software (minus video games) with Internet Archive Id

The following query uses these:

• Items: software (Q7397)   , video game (Q7889)   

• Properties: instance of (P31)   , subclass of (P279)   , Internet Archive ID (P724)   

  SELECT ?software ?softwareLabel ?archiveID
  {
    ?software wdt:P31/wdt:P279* wd:Q7397.
     ?software wdt:P724 ?archiveID.
    MINUS {?software wdt:P31/wdt:P279* wd:Q7889.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Types of Software

The following query uses these:

• Items: software category (Q28530532)   

• Properties: instance of (P31)   

  SELECT ?item ?itemLabel 
  WHERE 
  {
    ?item wdt:P31 wd:Q28530532.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Audio software titles by the count of readable file formats

The following query uses these:

• Items: audio software (Q15562063)   

• Properties: instance of (P31)   , subclass of (P279)   , readable file format (P1072)   

Features: BubbleChart (Q24515280)   

#defaultView:BubbleChart
SELECT ?app ?appLabel (count (?ff) as ?count)

WHERE {
  ?app wdt:P31/wdt:P279* wd:Q15562063.
  OPTIONAL {?app wdt:P1072 ?ff.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

GROUP BY ?app ?appLabel


ORDER BY DESC(?count)

Try it!

Software titles with articles with Encyclopædia Britannica Online ID

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Encyclopædia Britannica Online ID (P1417)   

  SELECT ?item ?itemLabel ?ebLabel
  WHERE 
  {
    ?item wdt:P31/wdt:P279*  wd:Q7397.
    ?item wdt:P1417 ?eb.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software developed by members of German Research Network

The following query uses these:

• Items: Verein zur Förderung eines Deutschen Forschungsnetzes (Q2514863)   

• Properties: member of (P463)   , developer (P178)   

  SELECT ?member ?memberLabel ?software ?softwareLabel WHERE {
    ?member wdt:P463 wd:Q2514863.
    ?software wdt:P178 ?member.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Software titles with Encyc Britannica id by license class

The following query uses these:

• Items: software (Q7397)   

• Properties: instance of (P31)   , subclass of (P279)   , Encyclopædia Britannica Online ID (P1417)   , copyright license (P275)   

  SELECT ?item ?itemLabel ?ebLabel ?license ?licenseLabel ?class ?classLabel
  WHERE 
  {
    ?item wdt:P31/wdt:P279*  wd:Q7397.
    ?item wdt:P1417 ?eb.
   ?item wdt:P275 ?license.
    ?license wdt:P31 ?class.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!