User:YULdigitalpreservation/SoftwareCitation

Prep for Software Citation/Modeling discussion

Open Questions

1. How might we best express the relationship (stated on SHELX homepage) that OLEX2, and WinGX can call SHELX?

Example Items

• SHELX (Q51715613)
• SHELXL (Q51795628)
• SHELXT (Q51795853)
• WinGX (Q51796009)
• Olex2 (Q7086477)

SPARQL Queries

Crystallography software and scientific literature related to them

The following query uses these:

• Items: software (Q7397)   , crystallography (Q160398)   , X-ray crystallography (Q826582)   

• Properties: instance of (P31)   , subclass of (P279)   , has use (P366)   , main subject (P921)   

  SELECT DISTINCT ?software ?softwareLabel ?articleLabel WHERE {
    ?software wdt:P31/wdt:P279* wd:Q7397.
    {?software wdt:P366 wd:Q160398}
    UNION {?software wdt:P366 wd:Q826582.}
    OPTIONAL {?article wdt:P921 ?software.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  }
  

Try it!

Everything with a CORDIS ID

The following query uses these:

• Properties: CORDIS Project ID (P3400)   

  SELECT ?item ?itemLabel ?value ?valueLabel
  {
  	?item wdt:P3400 ?value .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en"  }    
  }
  

Try it!

Software developed within projects with a CORDIS ID

The following query uses these:

• Properties: CORDIS Project ID (P3400)   , developer (P178)   

  SELECT ?item ?itemLabel ?value ?software ?softwareLabel
  {
  	?item wdt:P3400 ?value .
      ?software wdt:P178 ?item.
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }    
  }
  

Try it!

NSF career award

The following query uses these:

• Items: Faculty Early Career Development (CAREER) Award (Q23055141)   

• Properties: award received (P166)   , image (P18)   

  SELECT ?item ?label ?_image WHERE {
    ?item wdt:P166 wd:Q23055141.
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
    
  OPTIONAL { ?item wdt:P18 ?_image. }
  }
  

Try it!

ERC Advanced grant

The following query uses these:

• Items: ERC Advanced Grant (Q20588568)   

• Properties: award received (P166)   , image (P18)   

  SELECT ?item ?label ?_image WHERE {
    ?item wdt:P166 wd:Q20588568.
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
    
  OPTIONAL { ?item wdt:P18 ?_image. }
  }
  LIMIT 100
  

Try it!

All items with sponsor as ERC

The following query uses these:

• Items: European Research Council (Q1377836)   

• Properties: sponsor (P859)   , image (P18)   

  SELECT ?item ?label ?_image WHERE {
    ?item wdt:P859 wd:Q1377836.
    SERVICE wikibase:label {
      bd:serviceParam wikibase:language "en" . 
      ?item rdfs:label ?label
    }
    
  OPTIONAL { ?item wdt:P18 ?_image. }
  }
  LIMIT 100
  

Try it!

Software used in publications for which ERC is the sponsor

The following query uses these:

• Items: scholarly article (Q13442814)   , European Research Council (Q1377836)   

• Properties: instance of (P31)   , sponsor (P859)   , describes a project that uses (P4510)   

  SELECT ?item ?itemLabel ?software ?softwareLabel
  WHERE 
  {
    ?item wdt:P31 wd:Q13442814.
    ?item wdt:P859 wd:Q1377836.
    ?item wdt:P4510 ?software.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

Biological Databases by sponsor

The following query uses these:

• Items: biological database (Q4117139)   

• Properties: instance of (P31)   , sponsor (P859)   

  SELECT ?item ?itemLabel ?sponsor ?sponsorLabel 
  WHERE {
    ?item wdt:P31 wd:Q4117139.
    ?item wdt:P859 ?sponsor.
   SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    }
  

Try it!

Databases by sponsor

The following query uses these:

• Items: database (Q8513)   

• Properties: instance of (P31)   , subclass of (P279)   , sponsor (P859)   

  SELECT DISTINCT ?item ?itemLabel ?sponsor ?sponsorLabel WHERE {
    ?item wdt:P31/wdt:P279* wd:Q8513.
    ?item wdt:P859 ?sponsor.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  }
  

Try it!

zenodo id

The following query uses these:

• Properties: Zenodo ID (P4901)   

  SELECT ?item ?itemLabel ?value 
  {
  	?item wdt:P4901 ?value .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }   
  }
  

Try it!