User:YULdigitalpreservation/loveyourdata2017
This page documents a set of SPARQL queries I wrote in celebration of #loveyourdata week 2017.
Love Your Data Week Monday, 2/13/17 – Friday, 2/17/17 edit
Love Your Data week is a distributed set of events to celebrate our relationships with data.
Yale is participating in Love Your Data week edit
Members of the Yale University Library community will be hosting a series of events for Love Your Data week.
As a volunteer editor of Wikidata, I wanted to use the event as opportunity to highlight Wikidata, the Wikidata Query Service, Yale University Library collections and events.
I thought this would be great way to share these highlights with other people who also #loveyourdata, as we can share links to this page and these queries for others to try live on the Wikidata Query Service via Twitter.
Monday edit
Query edit
Monday People whose papers are held at the Beinecke who participated in the Harlem Renaissance:
SELECT ?person ?personLabel ?archivesatLabel
WHERE {
?person wdt:P485 ?archivesat .
?person wdt:P135 wd:Q829895 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Context edit
The Beinecke Rare Book & Manuscript Library (Q814779) holds the personal papers of many literary figures. Their current exhibit is called Gather Out of Stardust: The Harlem Renaissance and the Beinecke Library. The exhibit will be up until April 17, 2017. I was interested to see that the Beinecke holds the papers of many of the Harlem renaissance luminaries. This query demonstrates how Wikidata and Wikipedias can serve as additional pathways into our collections. Let's get more library metadata into Wikidata!
Tuesday edit
Query edit
SELECT ?person ?personLabel ?occLabel
WHERE {
?person wdt:P21 wd:Q6581072 .
?person wdt:P485 wd:Q814779 .
?person wdt:P106 ?occ .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Women whose papers are at Beinecke who are artists & how to improve these during Art+ Feminism editathon.
Yale University's Robert B. Haas Family Arts Library will be hosting an event for Art+Feminism 2017.
Please join us as we work together to improve the articles about these artists in Wikipedias, and add statements and references to their Wikidata items. We used this query to identify the articles of women we could edit during the event. There is a lot of biographical information about these people available in the finding aid to their archival papers that Beinecke staff have created. It would be great to see the biographical information used to create additional statements on their Wikidata items!
Wednesday edit
Query edit
#defaultView:BubbleChart
SELECT ?archive ?archiveLabel (COUNT(?person) AS ?count)
WHERE {
?person wdt:P31 wd:Q5 .
?person wdt:P485 ?archive .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en" .
}
}
GROUP BY ?archive ?archiveLabel
ORDER BY DESC(?count)
Context edit
This query can be visualized as a bubble chart. The query is asking for the names of institutions that hold archival papers.
The result set that this query currently generates is not the full set of possible results. In order to have a more comple result set, we need more editors to create statements about institutions and what archival papers they hold! Editors can make satements on the Wikidata item for a person by using archives at (P485) and then linking to the item for the institution. In order to reference such a claim, editors can add a link to the finding aid for the collection, as an example.
Thursday edit
Query edit
#defaultView:BubbleChart
SELECT ?app ?appLabel (COUNT(?format) AS ?count)
WHERE {
?app (p:P31/ps:P31/wdt:P279*) wd:Q7397 .
?app wdt:P1072 ?format .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en" .
}
}
GROUP BY ?app ?appLabel
ORDER BY DESC(?count)
Context edit
This query asks for a list of file formats for which we have data about what file formats they can read. We can use this data in external applications that help users automatically identify unknown file formats. In the future, if we get enough of this type of data into Wikidata, we could build tools that will then recommend software applications that are known to be able to read such a file format, and present meaningful choices to users of a framework such as Emulation as a Service.
Friday edit
Query edit
SELECT DISTINCT ?format ?formatLabel ?puid ?fdd ?solve
WHERE {
?format wdt:P2748 ?puid .
?format wdt:P3266 ?fdd .
?format wdt:P3381 ?solve .
SERVICE wikibase:label {
bd:serviceParam wikibase:language "en" .
}
}
Context edit
This query asks for the subset of file formats for which we know the PRONOM file format ID (P2748), the Library of Congress Format Description Document ID (P3266), and the File Format Wiki page ID (P3381).
This query demonstrates how Wikidata is becoming a crosswalk between the different registries of technical metadata.