Wikidata:WikiProject Anime and Manga/Splitting shared items

Context

Wikipedia articles often cover multiple anime/manga works in one article − for example, en:Hajime no Ippo is about a manga, three anime series, a TV film, an OAV and a couple of video games.

Wikidata has inherited this organization, resulting in items conflating all these works together. On Wikidata, we much prefer to have an item about each work.

Previous discussions

• Wikidata_talk:WikiProject_Anime_and_Manga#Splitting_shared_items_for_anime/manga/light_novels_into_separate_items
• Wikidata_talk:WikiProject_Anime_and_Manga#Splitting_combined_manga_and_anime_items
• Wikidata:Project_chat/Archive/2022/08#Anime_and_Manga_project
• Wikidata:Project_chat/Archive/2020/10#How_to_cleanly_split_an_item_into_separate_items?
• Wikidata:Project_chat/Archive/2018/09#TV_anime_described_as_film
• Wikidata:Project_chat/Archive/2018/04#Conflict_with_separate_Wikidata_items_vs._single,_combined_Wikipedia_articles_about_distinct_works

Potential issues

• Wikipedia might be reusing data expecting this conflation.
• ...

Maintenance queries

#title: Instances of "media franchise" that are also instances of "anime television series", "manga series", "light novel", "visual novel", "original video animation", or "original net animation"; "media franchise" items should be separate from those of instances of any of the six.
SELECT ?item ?itemLabel ?instanceofLabel
WHERE
{
  ?item wdt:P31 wd:Q196600 .
  { ?item wdt:P31 wd:Q63952888 . } UNION
  { ?item wdt:P31 wd:Q21198342 . } UNION
  { ?item wdt:P31 wd:Q747381 . } UNION
  { ?item wdt:P31 wd:Q689445 . } UNION
  { ?item wdt:P31 wd:Q220898 . } UNION 
  { ?item wdt:P31 wd:Q1047299 . }
  ?item wdt:P31 ?instanceof .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Instances of "media franchise" that are also instances of "anime television series", "manga series", "light novel", "visual novel", "original video animation", or "original net animation"; "media franchise" items should be separate from those of instances of any of the six.

#title: Instances of either "anime television series" or of "manga series"; items that are instances of both of them are essentially about media franchises.
SELECT ?item ?itemLabel ?instanceofLabel
WHERE
{
  ?item wdt:P31 wd:Q63952888 . 
  ?item wdt:P31 wd:Q21198342 . 
  ?item wdt:P31 ?instanceof .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Instances of either "anime television series" or of "manga series"; items that are instances of both of them are essentially about media franchises.

#title: Items that have both MyAnimeList manga ID (P4087) and MyAnimeList anime ID (P4086)
SELECT ?item ?itemLabel ?manga ?anime WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  ?item wdt:P4087 ?manga.
  ?item wdt:P4086 ?anime.
}

Items that have both MyAnimeList manga ID (P4087) and MyAnimeList anime ID (P4086)

#title: Shows items that are either an instance of manga series or anime television series but have more than one instance of statement.
# NOTE: The total # of instance of statements is wrong in some cases but is always guaranteed to be > 1.
SELECT DISTINCT ?item (COUNT(?instanceOf) AS ?total) WHERE {
  { ?item (wdt:P31/(wdt:P279*)) wd:Q21198342. }
  UNION
  { ?item (wdt:P31/(wdt:P279*)) wd:Q63952888. }
  ?item wdt:P31 ?instanceOf.
}
GROUP BY ?item
HAVING (?total > 1 )
ORDER BY DESC (?total)

Shows items that are either an instance of manga series or anime television series but have more than one instance of statement.