Wikidata:WikiProject Aviation/Lists

Home

Items

Properties

Reference Lists

List of airports named after people

The following query uses these:

• Items: airport (Q1248784)   , human (Q5)   

• Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , coordinate location (P625)   , named after (P138)   

  #Airports named after people
  #2016-12-20, Jura1
  SELECT ?countryLabel ?item ?itemLabel ?itemDescription ?person ?personLabel ?personDescription (sample(?coor) as ?coor)
  {
    	?item wdt:P31/wdt:P279* wd:Q1248784 .
      ?item p:P138/ps:P138 ?person .
    	?person wdt:P31 wd:Q5 . 
    	?item wdt:P17 ?country .
    	OPTIONAL { ?item wdt:P625 ?coor } .
  	SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
  }
  GROUP BY ?countryLabel ?item ?itemLabel ?itemDescription ?person ?personLabel ?personDescription
  ORDER BY ?countryLabel ?itemLabel
  LIMIT 1000
  

Try it!

Map of aerodromes in a country

The following query uses these:

• Items: aerodrome (Q62447)   , Brazil (Q155)   

• Properties: subclass of (P279)   , country (P17)   , dissolved, abolished or demolished date (P576)   , coordinate location (P625)   , instance of (P31)   

Features: map (Q24515275)   

#Airfields
#Airfields
#defaultView:Map
SELECT ?item ?itemLabel (sample(?coordinate_location) as ?coord) WHERE {
  ?item (p:P31/ps:P31/wdt:P279*) wd:Q62447.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE], en". }
  ?item wdt:P17 wd:Q155.
  MINUS { ?item wdt:P576 _:b2. }                                # remove items with P576 (dissolved, abolished or demolished) as a main property
  OPTIONAL { ?item wdt:P625 ?coordinate_location. }
} group by ?item ?itemLabel

Try it!