Wikidata:WikiProject Czech Republic/Showcase Queries

Home

 


Properties

 

Maintenance Queries

 

Showcase Queries

 

Interesting external databases

 

Events

 

Tools

 



Map of Czech castlesEdit

The following query uses these:

Features: Map (Q24515275)     

 1 # Map of Czech castles
 2 #defaultView:Map{"hide":["?coord", "?img"]}
 3 SELECT ?item ?itemLabel ?coord ?img ?styleLabel
 4 WHERE
 5 {
 6 	?item wdt:P31/wdt:P279* wd:Q23413 .
 7 	?item wdt:P17 wd:Q213 .
 8 	?item wdt:P625 ?coord .
 9 	OPTIONAL { ?item wdt:P18 ?img } .
10 	OPTIONAL { ?item wdt:P149 ?style } .
11 	SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } .
12 }

List of Czech companiesEdit

The following query uses these:

Parts of the cultural monument of the Prague CastleEdit

The following query uses these:

Features: ImageGrid (Q24515278)     

1 # Parts of the cultural monument of the Prague Castle
2 #defaultView:ImageGrid{"hide":["?img"]}
3 SELECT ?objectLabel ?img WHERE {
4   ?object p:P1435 [ ps:P1435 wd:Q30118385; pq:P642 wd:Q193369 ] .
5   ?object wdt:P625 ?coord .
6   ?object wdt:P18 ?img .
7   SERVICE wikibase:label { bd:serviceParam wikibase:language "cs" } .
8 }

Municipalities colour-coded by rising or falling population between 1930 and 1950Edit

The following query uses these:

Features: Map (Q24515275)     

 1 # Municipalities colour-coded by rising or falling population between 1930 and 1950
 2 #defaultView:Map{"hide":["?coord"]}
 3 SELECT ?item ?coord ?populace1930 ?populace2001 ?prirustek (IF(?prirustek > 1, CONCAT(">", STR(IF(?prirustek > 4, 4, FLOOR(?prirustek))), "x"), "prirustek") AS ?layer) WHERE {
 4   ?item wdt:P31 wd:Q5153359; wdt:P625 ?coord .
 5   ?item p:P1082 [ ps:P1082 ?populace1930; pq:P585 ?datum1930 ] .
 6   FILTER (YEAR(?datum1930) = 1930) .
 7   ?item p:P1082 [ ps:P1082 ?populace2001; pq:P585 ?datum2001 ] .
 8   FILTER (YEAR(?datum2001) = 1950) .
 9   BIND ( ?populace1930 / ?populace2001 AS ?prirustek ) .
10 }

Male/female ratio in Czech municipalitiesEdit

The following query uses these:

  • Properties: instance of (P31)     , population (P1082)     , male population (P1540)     , female population (P1539)     
     1 #Male/female ratio in Czech municipalities
     2 #defaultView:BarChart
     3 SELECT DISTINCT ((?zeny / ?muzi) AS ?result) ?item ?itemLabel ?muzi ?zeny
     4 WHERE
     5 {
     6     ?item wdt:P31 wd:Q5153359 .
     7     ?item p:P1082 ?populace .
     8     ?populace a wikibase:BestRank .
     9     ?populace pq:P1540 ?muzi .
    10     ?populace pq:P1539 ?zeny .
    11     SERVICE wikibase:label { bd:serviceParam wikibase:language "cs" } .
    12 }
    13 ORDER BY DESC(?result)
    14 LIMIT 50
    

Map of Czech villages with name ending with -noEdit

The following query uses these:

Features: Map (Q24515275)     

 1 #Map of Czech villages with name ending with -no
 2 #defaultView:Map{"hide":["?coord"]}
 3 SELECT DISTINCT ?item ?itemLabel ?coord WHERE {
 4   ?item (wdt:P31/wdt:P279*) wd:Q486972. hint:Prior hint:gearing "forward".
 5   ?item wdt:P17 wd:Q213.
 6   ?item wdt:P625 ?coord.
 7   ?item rdfs:label ?itemLabel.
 8   FILTER((LANG(?itemLabel)) = "cs")
 9   FILTER(STRENDS(?itemLabel, "no"))
10 }

Number of descendants of Bořivoj I.Edit

277298 📈
End of automatically generated list.


List of hospitalsEdit

Map of railway linesEdit

The following query uses these:

Features: Map (Q24515275)     

 1 #defaultView:Map{"hide":["?coord1", "?coord2", "?str", "?line"]}
 2 SELECT * WHERE {
 3   ?comm1 p:P31/ps:P31/wdt:P279* wd:Q55488 ; wdt:P17 wd:Q213 ; wdt:P625 ?coord1 ; wdt:P197 ?comm2 .
 4   MINUS { ?comm1 p:P31 [ ps:P31 wd:Q55488 ; pq:P582 [] ] } .
 5   MINUS { ?comm2 p:P31 [ ps:P31 wd:Q55488 ; pq:P582 [] ] } .
 6   MINUS { ?comm1 p:P31 [ ps:P31 wd:Q928830 ] } .
 7   MINUS { ?comm2 p:P31 [ ps:P31 wd:Q928830 ] } .
 8   ?comm2 wdt:P625 ?coord2 .
 9   ?comm1 p:P625 [ ps:P625 []; psv:P625 [ wikibase:geoLongitude ?coord1lon; wikibase:geoLatitude ?coord1lat; ] ] .
10   ?comm2 p:P625 [ ps:P625 []; psv:P625 [ wikibase:geoLongitude ?coord2lon; wikibase:geoLatitude ?coord2lat; ] ] .
11   BIND(CONCAT('LINESTRING (', STR(?coord1lon), ' ', STR(?coord1lat), ',', STR(?coord2lon), ' ', STR(?coord2lat), ')') AS ?str) .
12   BIND(STRDT(?str, geo:wktLiteral) AS ?line) .
13 }

CEO of Ředitelství silnic a dálnicEdit

The following query uses these:

  • Properties: position held (P39)     , start time (P580)     , end time (P582)     
    1 #defaultView:Timeline
    2 select ?reditel ?reditelLabel ?start ?end where {
    3   ?reditel p:P39 ?position.
    4   ?position ps:P39 wd:Q63486417;
    5             pq:P580 ?start;
    6             pq:P582 ?end.
    7   SERVICE wikibase:label { bd:serviceParam wikibase:language "cs,en" } .
    8 }
    

Pták rokuEdit

The following query uses these:

Features: ImageGrid (Q24515278)     

 1 #defaultView:ImageGrid{"hide":["?obrazek"]}
 2 select ?item (?sitelink_Label AS ?itemLabel) ?rok (sample(?img) as ?obrazek) where {
 3 
 4   ?item p:P166 [ ps:P166 wd:Q12047564 ; pq:P585 ?datum ] .
 5   ?sitelink schema:about ?item . ?sitelink schema:inLanguage "cs" . ?sitelink schema:name ?sitelink_Label .
 6   ?item wdt:P18 ?img . 
 7   bind(year(?datum) as ?rok) .
 8 }
 9 group by ?item ?sitelink_Label ?rok 
10 order by desc(?rok)

Buildings on Wenceslas SquareEdit

The following query uses these:

Features: ImageGrid (Q24515278)     

 1 #defaultView:ImageGrid{"hide":["?img"]}
 2 SELECT DISTINCT ?item ?itemLabel ?streetno ?cons ?img
 3 WHERE 
 4 {
 5   ?item wdt:P31/wdt:P279* wd:Q41176.
 6   ?item p:P669 ?street .
 7   ?street ps:P669 wd:Q847613 .
 8   OPTIONAL { ?street pq:P670 ?streetno } . 
 9   OPTIONAL { ?item wdt:P4856 ?cons } .
10   OPTIONAL { ?item wdt:P18 ?img } .
11   SERVICE wikibase:label { bd:serviceParam wikibase:language "cs,en" } .
12 }
13 ORDER BY xsd:integer(?streetno)