Wikidata:WikiProject Informatics/Hardware/Supercomputers

This project has the goal of full description of all instances of supercomputer (Q121117).

See full classification at Talk:Q121117.

Thanks User:TOP500 importer for initial import.

Queries

All recent edits on supercomputer items

History of Top1

The following query uses these:

Items: supercomputer (Q121117)   , TOP500 (Q633765)

Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , country of origin (P495)   , manufacturer (P176)   , computer performance (P7256)   , power consumed (P2791)   , TOP500 System ID (P7307)   , operating system (P306)   , number of processor cores (P1141)   , inception (P571)   , service entry (P729)   , bus (P8107)   , ranking (P1352)   , review score by (P447)   , point in time (P585)   , start time (P580)   , end time (P582)  
```
#title:timeline of #1 in Top500
#defaultView:Timeline
SELECT distinct ?item ?itemLabel ?countryLabel ?creatorLabel ?perf ?procs ?heat ?top500 ?osLabel ?time ?totime ?busLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q121117.
  OPTIONAL {?item wdt:P17|wdt:P495 ?country.}
  OPTIONAL {?item wdt:P176 ?creator.}
  OPTIONAL {?item wdt:P7256 ?perf.}
  OPTIONAL {?item wdt:P2791 ?heat.}
  OPTIONAL {?item wdt:P7307 ?top500.}
  OPTIONAL {?item wdt:P306 ?os.}
  OPTIONAL {?item wdt:P1141 ?procs.}
  OPTIONAL {?item wdt:P571|wdt:P729 ?creat.}
  OPTIONAL {?item wdt:P8107 ?bus.}
  FILTER (STR(?rank)="1") 
  ?item p:P1352 [ps:P1352 ?rank; pq:P447 wd:Q633765].
  OPTIONAL { {?item p:P1352 [ps:P1352 ?rank; pq:P585 ?time].} UNION
     {?item p:P1352 [ps:P1352 ?rank; pq:P580 ?time].} }
  OPTIONAL {?item p:P1352 [ps:P1352 ?rank; pq:P582 ?totime].}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?time ?fromtime
```

timeline of #1 in Top500

Most recent ranking

The following query uses these:

Items: supercomputer (Q121117)   , TOP500 (Q633765)

Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , country of origin (P495)   , manufacturer (P176)   , computer performance (P7256)   , power consumed (P2791)   , TOP500 System ID (P7307)   , operating system (P306)   , number of processor cores (P1141)   , inception (P571)   , service entry (P729)   , bus (P8107)   , ranking (P1352)   , point in time (P585)   , review score by (P447)   , start time (P580)   , end time (P582)  
```
#title:current ranking in Top500
SELECT distinct ?rank ?item ?itemLabel ?countryLabel ?perf ?procs ?heat ?top500 ?osLabel ?time ?busLabel
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q121117.
  OPTIONAL {?item wdt:P17|wdt:P495 ?country.}
  OPTIONAL {?item wdt:P176 ?creator.}
  OPTIONAL {?item p:P7256 [ps:P7256 ?perf; pq:P585 []].}
#  OPTIONAL {?item wdt:P7256 ?perf.}
  OPTIONAL {?item wdt:P2791 ?heat.}
  OPTIONAL {?item wdt:P7307 ?top500.}
  OPTIONAL {?item wdt:P306 ?os.}
  OPTIONAL {?item wdt:P1141 ?procs.}
  OPTIONAL {?item wdt:P571|wdt:P729 ?creat.}
  OPTIONAL {?item wdt:P8107 ?bus.}
#  ?item wdt:P1352 ?rank.  # use only for the recent ranking
  ?item p:P1352 [ps:P1352 ?rank; pq:P447 wd:Q633765].
  OPTIONAL { {?item p:P1352 [ps:P1352 ?rank; pq:P585 ?time].} 
      UNION {?item p:P1352 [ps:P1352 ?rank; pq:P580 ?time].} 
      UNION {?item p:P1352 [ps:P1352 ?rank; pq:P582 ?time].} }
  BIND (YEAR(?time) as ?year).
  BIND (MONTH(?time) as ?month).
  FILTER (?year = 2023).
  FILTER (?month = 6). 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?rank
```

current ranking in Top500

Список суперкомпьютеров с характеристиками

The following query uses these:

Items: supercomputer (Q121117)   , TOP500 (Q633765)

Properties: instance of (P31)   , subclass of (P279)   , country (P17)   , country of origin (P495)   , manufacturer (P176)   , computer performance (P7256)   , power consumed (P2791)   , TOP500 System ID (P7307)   , operating system (P306)   , number of processor cores (P1141)   , inception (P571)   , service entry (P729)   , ranking (P1352)   , review score by (P447)  
```
#title:all supercomupers in the world
SELECT ?item ?itemLabel ?countryLabel (SAMPLE(?creators) AS ?creator) (MAX(?perfs) AS ?perf) 
(MAX(?procs) AS ?proc) (MAX(?heats) AS ?heat) ?top500 (SAMPLE(?oss) AS ?os) ?created (MIN(?ranks) AS ?rank)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q121117.
  OPTIONAL {?item wdt:P17|wdt:P495 ?country.}
  OPTIONAL {?item wdt:P176 ?creators.}
  OPTIONAL {?item wdt:P7256 ?perfs.}
  OPTIONAL {?item wdt:P2791 ?heats.}
  OPTIONAL {?item wdt:P7307 ?top500.}
  OPTIONAL {?item wdt:P306 ?oss.}
  OPTIONAL {?item wdt:P1141 ?procs.}
  OPTIONAL {?item wdt:P571|wdt:P729 ?created.}
  OPTIONAL {?item wdt:P1352 ?ranks; p:P1352 [ps:P1352 ?ranks; pq:P447 wd:Q633765].}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel ?country ?countryLabel ?top500 ?created
```

all supercomupers in the world

Все используемые свойства

The following query uses these:

Items: supercomputer (Q121117)

Properties: instance of (P31)   , subclass of (P279)  
```
#title:count of statements by property for instances
SELECT ?property ?propertyLabel ?count WITH {
  SELECT ?property (count(?property) as ?count)
WHERE 
{
  ?item wdt:P31/wdt:P279* wd:Q121117.
  ?item ?predicate [].
  ?property wikibase:directClaim ?predicate .
} group by ?property ?propertyLabel } as %props
WHERE
{
  INCLUDE %props
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY DESC(?count)
```