Wikidata:WikiProject NFDI/SPARQL-queries
Consortia edit
Give me all accepted NFDI consortia! edit
SELECT ?p ?pLabel ?pAltLabel ?pDescription ?inception
WHERE
{
?p wdt:P31 wd:Q98270496 .
OPTIONAL { ?p wdt:P571 ?inception }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?inception) ASC(?pLabel)
Which organisations are (co-)applicants in which NFDI consortia? (Graph) edit
#defaultView:Graph
SELECT ?w ?wLabel ?wpicture ?p ?pLabel ?ppicture ("EC0000" AS ?rgb)
WHERE
{
?p wdt:P31 wd:Q98270496 .
?p wdt:P1416 ?w .
OPTIONAL { ?w wdt:P154 ?wpicture }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)
Which organisations are in which consortium? edit
If you replace ?s by the ID of your consortium, you can get the basis for the question "If one or more members of your consortium are participating in other NFDI consortia, please list these multiple participations here" from the interim report
#defaultView:Table
SELECT DISTINCT ?consortium ?consortiumLabel ?affiliation ?affiliationLabel
WHERE {
?s wdt:P1416 ?affiliation.
wd:Q61658497 wdt:P355 ?consortium.
?consortium wdt:P1416 ?affiliation.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY DESC(?consortiumLabel) ASC(?affiliationLabel)
Which organisations are (co-)applicants in the most NFDI consortia? (Bubble Chart) edit
#defaultView:BubbleChart
SELECT ?w ?wLabel (COUNT(?p) AS ?number)
WHERE
{
?p wdt:P31 wd:Q98270496 .
?p wdt:P1416 ?w .
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} GROUP BY ?w ?wLabel
ORDER BY DESC(?number) ASC(?wLabel)
Give me all accepted consortia and their fields of work! (as a Graph) edit
(Comment: Data is not yet complete.)
#defaultView:Graph
SELECT ?p ?pLabel ("EC0000" AS ?rgb) ?w ?wLabel
WHERE
{
?p wdt:P31 wd:Q98270496 .
?p wdt:P101 ?w .
OPTIONAL { ?w wdt:P154 ?wpicture }
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)
Where are (co-)applicants located? (Map) edit
#defaultView:Map
SELECT DISTINCT ?w ?wLabel ?geo
WHERE
{
?p wdt:P31 wd:Q98270496 .
?p wdt:P1416 ?w .
?w wdt:P625 ?geo .
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?wLabel)
NFDI association edit
Show all members of the NFDI association - with additional data about them! edit
SELECT DISTINCT ?w ?wLabel ?bundeslandLabel ?rechtsformLabel (SAMPLE(?leitungname) AS ?leitungname) (SAMPLE(?website) AS ?website) ?email ?telefon (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?facebook) AS ?facebook) ?rorid ?lobbyregister (SAMPLE(?beschaeftigte) AS ?beschaeftigte) (SAMPLE(?gruendung) AS ?gruendung)
WHERE
{
?w wdt:P463 wd:Q105757481 .
OPTIONAL {?w wdt:P10301 ?lobbyregister }
OPTIONAL {?w wdt:P856 ?website .}
OPTIONAL {?w wdt:P2002 ?twitter .}
OPTIONAL {?w wdt:P2769 ?budget .}
OPTIONAL {?w wdt:P6782 ?rorid .}
OPTIONAL {?w wdt:P9934 ?zenodoid }
OPTIONAL {?w wdt:P2013 ?facebook }
OPTIONAL {?w wdt:P1329 ?telefon }
OPTIONAL {?w wdt:P571 ?gruendung }
OPTIONAL {?w wdt:P1128 ?beschaeftigte }
OPTIONAL {?w wdt:P1454 ?rechtsform}
OPTIONAL {?w wdt:P968 ?email}
OPTIONAL {?w wdt:P11647*/wdt:P1037 ?leitung . ?leitung rdfs:label ?leitungname .}
OPTIONAL {
?w wdt:P131+ ?bundesland .
?bundesland wdt:P31 wd:Q1221156 .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
} GROUP BY ?w ?wLabel ?wAltLabel ?wDescription ?bundeslandLabel ?rechtsformLabel ?telefon ?rorid ?lobbyregister ?email
ORDER BY ASC(?wLabel)
Sections edit
Show all sections of NFDI - with additional data about them! edit
SELECT DISTINCT ?w ?wLabel ?wAltLabel ?wDescription ?speakerLabel (SAMPLE(?website) AS ?website) ?email ?telefon (SAMPLE(?twitter) AS ?twitter) (SAMPLE(?facebook) AS ?facebook) ?zenodoid (SAMPLE(?inception) AS ?inception)
WHERE
{
?w wdt:P31 wd:Q111582288 .
OPTIONAL {?w wdt:P10301 ?lobbyregister }
OPTIONAL {?w wdt:P856 ?website .}
OPTIONAL {?w wdt:P2002 ?twitter .}
OPTIONAL {?w wdt:P2769 ?budget .}
OPTIONAL {?w wdt:P6782 ?rorid .}
OPTIONAL {?w wdt:P9934 ?zenodoid }
OPTIONAL {?w wdt:P2013 ?facebook }
OPTIONAL {?w wdt:P1329 ?telefon }
OPTIONAL {?w wdt:P968 ?email}
OPTIONAL {?w wdt:P571 ?inception }
OPTIONAL {?w wdt:P1128 ?beschaeftigte }
OPTIONAL {?w wdt:P488 ?speaker }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de" . }
} GROUP BY ?w ?wLabel ?wAltLabel ?wDescription ?telefon ?zenodoid ?email ?speakerLabel
ORDER BY ASC(?wLabel)
Explore edit
Show the NFDI as an expandable graph! edit
Hint: Click on node to expand the graph!
#defaultView:Graph
SELECT ?p ?pLabel ?s ?sLabel
WHERE
{
?s ?p ?o
FILTER(?s = wd:Q61658497 )
SERVICE wikibase:label { bd:serviceParam wikibase:language "de" . }
}