Wikidata:WikiProject PCC Wikidata Pilot/Philadelphia Museum of Art Library and Archives

Aim and Scope

This is the project hub for wikidata projects underway at the Philadelphia Museum of Art (Q510324) which are conducted and maintained by the Philadelphia Museum of Art Library and Archives (Q89574171). We seek to create and enhance records relevant to our institution, our collections, and our community, with particular attention to highlighting underrepresented groups in our library, archival, and museum collections.

Background

PMA Library and Archives staff became active Wikidata editors in March 2020, with the launch of its PMA African American Artists (Q94124522) project. They are currently working with museum's curatorial departments to evaluate metadata needs and develop staff training materials.

Contributors

• PMAlibcat (talk • contribs • logs)
• ASR06 (talk • contribs • logs)
• PMAavcat (talk • contribs • logs)

Projects

Resource	Status	Size	Associated ID	Query	Items Created or Edited
PMA African American Artists	In Progress	203 names	PMA African American Artists (Q94124522)	Names A-Z	Totals list
PMA Entity IDs	In Progress	9581 of 41000 names	Philadelphia Museum of Art entity ID (P8317)	Names A-Z	list too big to generate
PMA Latinx Artists	Pending
PMA Institutional names	Pending

Sample Queries

Residence of Black PMA artists

SELECT ?item ?itemLabel ?itemDescription ?residence ?residenceLabel WHERE {
?item wdt:P31 wd:Q5; #instance of: human
wdt:P172 wd:Q49085; #ethnic group: African Americans
wdt:P6379 wd:Q510324; #has works in the collection: Philadelphia Museum of Art
wdt:P551 ?residence
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Try it!

Black PMA artists educated within 80 kilometers of Philadelphia

SELECT DISTINCT 
  ?item ?itemLabel ?itemDescription
  ?p ?pLabel 
  ?coords ?distance
WHERE
{
  wd:Q1345 wdt:P625 ?a0 .
  SERVICE wikibase:around {
      ?p wdt:P625 ?coords .
      bd:serviceParam wikibase:center ?a0 .
      bd:serviceParam wikibase:radius "80" .
      bd:serviceParam wikibase:distance ?distance .      
  }
  hint:Query hint:optimizer "None".
  ?item wdt:P69 ?p .
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P172 wd:Q49085 .
   ?item wdt:P6379 wd:Q510324.  

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?distance

Try it!

PMA Gees Bend quilters with no date of death

SELECT ?item ?itemLabel ?itemDescription ?movementLabel ?movement WHERE {
?item wdt:P31 wd:Q5;
wdt:P172 wd:Q49085;
wdt:P6379 wd:Q510324;
wdt:P135 wd:Q7759116.
FILTER(NOT EXISTS { ?item wdt:P570 _:b4. })
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
OPTIONAL { ?item wdt:P135 ?movement. }
}

Try it!

Wikidata records of Black PMA artists without an image

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P5008 wd:Q94124522.
  OPTIONAL {?item wdt:P18 ?p18 }
  FILTER(!BOUND(?p18))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel

Try it!