Wikidata:WikiProject Zika Corpus/Queries

Home

Items

Properties

Queries

Statements involving Zika virus (Q202864)

The following query uses these:

• Items: Zika virus (Q202864)   

  DESCRIBE wd:Q202864
  LIMIT 1000
  

Try it!

Get items with "Zika" in the item label

The following query uses these:

• Items: scholarly article (Q13442814)   

• Properties: instance of (P31)   , PubMed ID (P698)   

  SELECT DISTINCT ?item ?itemLabel ?_PubMed_ID
  WHERE
  {
    ?item wdt:P31 wd:Q13442814 ;
          rdfs:label ?itemLabel .
    OPTIONAL { ?item wdt:P698 ?_PubMed_ID. }
    FILTER(CONTAINS(LCASE(?itemLabel), "zika"))
    FILTER (LANG(?itemLabel)="en") 
  }
  LIMIT 1000
  

Try it!

Most common Zika authors

The following query uses these:

• Items: Zika virus (Q202864)   , Zika fever (Q8071861)   

• Properties: main subject (P921)   , author name string (P2093)   , author (P50)   

  SELECT ?short_author ?short_authorLabel (count(?item) as ?count)
  WHERE
  {
    { ?item wdt:P921 wd:Q202864 . } UNION { ?item wdt:P921 wd:Q8071861 . }
    {?item wdt:P2093 ?short_author .} UNION {?item wdt:P50 ?short_author .}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
  }
  GROUP BY ?short_author ?short_authorLabel
  ORDER BY DESC(?count)
  

Try it!

Scientific articles that have subject Zika virus or fever and that are used as a reference in another item

The following query uses these:

• Items: scholarly article (Q13442814)   , Zika virus (Q202864)   , Zika fever (Q8071861)   

• Properties: instance of (P31)   , main subject (P921)   

  #added before 2016-10
  SELECT ?item ?itemLabel ?reference  ?referenceType
  WHERE
  {
    ?item wdt:P31 wd:Q13442814#Scientific article
    { ?item wdt:P921 wd:Q202864 } #Zika virus
    UNION
    { ?item wdt:P921 wd:Q8071861 } #Zika fever
    ?reference ?referenceType ?item  #find references to item having any property and store reference type
    SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
  }
  

Try it!

Number of Zika virus publications that have author (P50) statements but no author name string (P2093) statement

The following query uses these:

• Items: Zika virus (Q202864)   

• Properties: author (P50)   , main subject (P921)   , author name string (P2093)   

  SELECT (COUNT(DISTINCT ?item) AS ?count) WHERE {
    ?item wdt:P50 ?author;
          wdt:P921 wd:Q202864.
    MINUS {?item wdt:P2093 []}
  }
  

Try it!

Timeline of number of items for publications about the Zika virus

The following query uses these:

• Items: Zika virus (Q202864)   , QID milestone (Q38074555)   

• Properties: main subject (P921)   , quantity (P1114)   , point in time (P585)   

  # Horizontal axis: dates when Wikidata reached some milestone in item numbers
  # Vertical axis: number of items for publications about the Zika virus
  # adapted from https://www.wikidata.org/w/index.php?oldid=957875282#Query_for_approximate_creation_dates_of_a_series_of_items
  
  #defaultView:AreaChart
  SELECT ?date ?cumulativecount 
  {
      hint:Query hint:optimizer "None".
      {   SELECT ?milestonep (COUNT(?item) as ?cumulativecount)
          WHERE
          {
            { SELECT ?item { ?item wdt:P921 wd:Q202864 .}  LIMIT 100000 }
            BIND( xsd:integer( substr(str(?item), 33)) as ?qid)
            wd:Q38074555 p:P1114 ?milestonep .
            ?milestonep ps:P1114 ?milestone .
            FILTER( ?milestone > ?qid ) 
          }
          GROUP BY ?milestonep
      }          
      ?milestonep pq:P585 ?date
  }
  

Try it!