Wikidata

Divudi85

Joined 14 March 2017
Babel user information
it-N Questo utente può contribuire con un livello madrelingua in italiano.
en-2 This user has intermediate knowledge of English.
es-1 Este usuario tiene un conocimiento básico del español.
fr-1 Cet utilisateur dispose de connaissances de base en français.
de-0 Dieser Benutzer beherrscht Deutsch nicht (oder versteht es nur mit beträchtlichen Schwierigkeiten).
la-0 Hic usor aut parum aut nihil Latine scit.
Questo utente partecipa alle attività del Gruppo Wikidata per Musei, Archivi e Biblioteche
Users by language

Bibliotecario presso Salaborsa Lab a Bologna

Link a editgroups edit

recent edit groups

Mare Magnum edit 

#title:Tabella di controllo
SELECT DISTINCT ?tipograf ?tipografLabel ?llavLabel ?din ?dfi
WHERE {
  ?tipograf wdt:P5323 wd:Q118466009; wdt:P106 ?attività.
  values ?attività { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  Optional {?tipograf wdt:P2031 ?din}.
  Optional {?tipograf wdt:P2032 ?dfi}.
  Optional {?tipograf wdt:P937  ?llav}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
}
Tabella di controllo 
#title:Proprietà mancanti
SELECT ?type (COUNT(DISTINCT ?tipograf ) AS ?count) WHERE {
  hint:Query hint:optimizer "Runtime".
  ?tipograf wdt:P5323 wd:Q118466009; wdt:P106 ?attività.
  values ?attività { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  Optional {?tipograf wdt:P2031 ?din}.
  Optional {?tipograf wdt:P2032 ?dfi}.
  Optional {?tipograf wdt:P937  ?llav}.
  BIND(IF(BOUND(?din) && BOUND(?dfi)&& BOUND(?llav),"all",     
       IF(BOUND(?llav) && BOUND(?dfi),"senza data di inizio",
       IF(BOUND(?din) && BOUND(?llav),"senza data di fine",
       IF(BOUND(?dfi) && BOUND(?din),"senza luogo di lavoro",
       IF(BOUND(?din),"solo data di inizio",
       IF(BOUND(?dfi),"solo data di fine",
       IF(BOUND(?llav),"solo luogo di lavoro",
       "none"))))))) AS ?type)
}
GROUP BY ?type
ORDER BY ?type
Proprietà mancanti 
#title:Query per mappa su WQS
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?città_lavLabel ?coord
WHERE {
  ?item wdt:P5323 wd:Q118466009; wdt:P106 ?attività; wdt:P937 ?città_lav 
 values ?attività { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?città_lav wdt:P625 ?coord.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". } 
}
Query per mappa su WQS 
#title:Query per mappa su Tableau
SELECT DISTINCT ?item ?itemLabel ?città_lavLabel ?long ?lat 
WHERE {
  ?item wdt:P5323 wd:Q118466009; wdt:P106 ?attività; wdt:P937 ?città_lav 
 values ?attività { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?città_lav p:P625 [ psv:P625 ?coord].
  ?coord wikibase:geoLatitude ?lat.
  ?coord wikibase:geoLongitude ?long. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". } 
}
Query per mappa su Tableau

In questo caso anche con DISTINCT permangono dei duplicati legati alle molteplici città in cui hanno operato i tipografi (ignora invece quelli legati all'attività in quanto non dichiarata nella select), a seconda della necessità di rappresentazione si può fareun passaggio su excel importando da csv per la loro rimozione ma ricordarsi di non far intepretare in automatico i valori lat e long altrimenti diventano "illeggibili" su tableau. 

#title:Query per timeline su WQS
#defaultView:Timeline
SELECT DISTINCT ?tipograf ?tipografLabel ?start ?end
WHERE {
  
?tipograf wdt:P5323 wd:Q118466009; wdt:P2031 ?start; wdt:P2032 ?end; wdt:P106 ?activity .
values ?activity { 
    wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
Query per timeline su WQS

Tipografe edit

See it in Wikidata Query Service 
#title:Tipografe italiane
SELECT ?tipografa ?tipografaLabel ?tipografaDescription ?prenomeLabel ?cognomeLabel ?occupazioneLabel ?luogo_lavLabel ?floruit ?data_inizio ?data_fine
WHERE 
{
  ?tipografa wdt:P5008 wd:Q109646556.
  Optional {?tipografa wdt:P106 ?occupazione}.
  Optional {?tipografa wdt:P2031 ?data_inizio}.
  Optional {?tipografa wdt:P2032 ?data_fine}.
  Optional {?tipografa wdt:P1317 ?floruit}.
  Optional {?tipografa wdt:P937  ?luogo_lav}.
  Optional {?tipografa wdt:P735  ?prenome}.
  Optional {?tipografa wdt:P734  ?cognome}.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Tipografe italiane 
#title:Distribuzione tipografi e tipografe per paese e città
SELECT DISTINCT ?paeseLabel ?luogolavLabel  (COUNT (?uomini) AS ?n_uomini) (COUNT (?donne) AS ?n_donne) WHERE {
?tipograf wdt:P31 wd:Q5; wdt:P937 ?luogolav; wdt:P106 ?activity .
 values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
?luogolav wdt:P17 ?paese
OPTIONAL { ?tipograf wdt:P21 wd:Q6581097 . BIND("uomini" as ?uomini) }
OPTIONAL { ?tipograf wdt:P21 wd:Q6581072 . BIND("donne" as ?donne) }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
GROUP BY ?paeseLabel ?luogolavLabel
ORDER BY DESC (?n_donne)
Distribuzione tipografi e tipografe per paese e città 
#title: Mappa distribuzione tipografi e tipografe in Italia
#defaultView:Map
SELECT DISTINCT ?tipograf ?tipografLabel ?luogolavLabel ?coord ?layer WHERE {
?tipograf wdt:P31 wd:Q5; wdt:P937 ?luogolav ; wdt:P106 ?activity .
 values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
?luogolav wdt:P625 ?coord; wdt:P17 wd:Q38. 
OPTIONAL { ?tipograf wdt:P21 wd:Q6581097 . BIND("uomini" as ?layer) }
OPTIONAL { ?tipograf wdt:P21 wd:Q6581072 . BIND("donne" as ?layer) }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
Mappa distribuzione tipografi e tipografe in Italia 
#title:Timeline tipografe (stampatora, editora, libraia e stampatora-libraia) per inizio fine periodo di attività
#defaultView:Timeline
SELECT ?tipografaLabel ?tipografaDescription ?luogolavLabel ?paeseLabel ?inizioatt ?fineatt
WHERE 
{
  ?tipografa wdt:P31 wd:Q5; wdt:P21 wd:Q6581072; wdt:P937 ?luogolav; wdt:P2031 ?inizioatt; wdt:P2032 ?fineatt ; wdt:P106 ?activity .
   values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?luogolav wdt:P17 ?paese

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
Timeline tipografe (stampatora, editora, libraia e stampatora-libraia) per inizio fine periodo di attività 
#title:Tipografe (stampatora, editora, libraia e stampatora-libraia) nel mondo
#defaultView:Map
SELECT ?tipografa ?tipografaLabel ?tipografaDescription ?coord
WHERE 
{
  ?tipografa wdt:P31 wd:Q5; wdt:P21 wd:Q6581072 ; wdt:P106 ?activity .
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?tipografa wdt:P937 [ wdt:P625 ?coord ].

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Tipografe (stampatora, editora, libraia e stampatora-libraia) nel mondo 
#title:Tipografe (stampatora, editora, libraia e stampatora-libraia) senza luogo di lavoro, CERL id optional
SELECT ?tipografa ?tipografaLabel ?tipografaDescription ?luogo_lavLabel (URI(concat("https://data.cerl.org/thesaurus/",?cerl)) AS ?cerlURL)
WHERE 
{
  ?tipografa wdt:P31 wd:Q5; wdt:P21 wd:Q6581072; wdt:P106 ?activity .
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
MINUS {?tipografa wdt:P937 ?luogo_lav.}
  OPTIONAL {?tipografa wdt:P1871 ?cerl }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Tipografe (stampatora, editora, libraia e stampatora-libraia) senza luogo di lavoro, CERL id optional 


#title:Tipografe (stampatora, editora, libraia e stampatora-libraia) nel mondo per paese
SELECT ?paeseLabel  (COUNT(?tipografa) AS ?count)
WHERE 
{
  ?tipografa wdt:P31 wd:Q5; wdt:P21 wd:Q6581072; wdt:P937 ?luogolav ; wdt:P106 ?activity .
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?luogolav wdt:P17 ?paese

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?paeseLabel
ORDER BY DESC(?count)
Tipografe (stampatora, editora, libraia e stampatora-libraia) nel mondo per paese 


#title:Tipografe (stampatora, editora, libraia e stampatora-libraia) nel mondo per città e paese (variante)
SELECT  ?luogolavLabel ?paeseLabel (Count(?tipografa) As ?count)
WHERE 
{
  ?tipografa wdt:P31 wd:Q5; wdt:P21 wd:Q6581072; wdt:P937 ?luogolav ; wdt:P106 ?activity .
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
?luogolav wdt:P17 ?paese
          
          
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

GROUP BY ?luogolavLabel ?paeseLabel
Tipografe (stampatora, editora, libraia e stampatora-libraia) nel mondo per città e paese (variante) 
#title: Mappa distribuzione tipografi e tipografe nel mondo
SELECT DISTINCT ?tipograf ?tipografLabel ?sessoLabel ?paeseLabel ?luogolavLabel ?lat ?long WHERE {
?tipograf wdt:P31 wd:Q5; wdt:P21 ?sesso; wdt:P937 ?luogolav; wdt:P106 ?activity .
  ?luogolav wdt:P17 ?paese.
  values ?activity { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?luogolav p:P625 [ psv:P625 ?coo2].
  ?coo2 wikibase:geoLatitude ?lat.
  ?coo2 wikibase:geoLongitude ?long. 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Mappa distribuzione tipografi e tipografe nel mondo 
#title:relazioni tra tipografi a venezia 
#defaultView:Graph
select ?person ?linkedPerson ?linkedPersonLabel ?type ?personLabel (?type as ?edgeLabel) {
   ?person wdt:P937 wd:Q641;
           wdt:P106 ?activity .
  
  values ?activity { 
    wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196
  }
  
  ?person wdt:P2032|wdt:P570 ?datafine .
  
{ ?person wdt:P1327 ?linkedPerson .  bind("business partner" as ?type)  } union 
{ ?person wdt:P802 ?linkedPerson .  bind("student" as ?type) } union 
{ ?person wdt:P1066 ?linkedPerson .  bind("teacher" as ?type) } union 
{ ?person wdt:P22 ?linkedPerson .  bind("father" as ?type) } union 
{ ?person wdt:P23 ?linkedPerson .  bind("mother" as ?type)  } union 
{ ?person wdt:P40 ?linkedPerson .  bind("son" as ?type) } union 
{ ?person wdt:P26 ?linkedPerson .  bind("partner" as ?type) }
FILTER ("1850-01-01"^^xsd:dateTime > ?datafine) 
SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en" . }
}
relazioni tra tipografi a venezia 
#title:tipografi con dbi ma pochi statements
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?dbi ?number
WHERE {
  ?item wdt:P31 wd:Q5; wdt:P1986 ?dbi; wikibase:statements ?number .
  {?item wdt:P106 wd:Q175151 }UNION {?item wdt:P106 wd:Q1229025}UNION {?item wdt:P106 wd:Q998550}UNION {?item wdt:P106 wd:Q2516866}UNION {?item wdt:P106 wd:Q40881196} .
  FILTER(?number < 10)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
tipografi con dbi ma pochi statements 
#title:query per timeline tableau
SELECT DISTINCT ?tipograf ?tipografLabel ?sessoLabel (MIN(?start) as ?startt) (MAX (?end) as ?endd) ?luogolavLabel ?lat ?long WHERE {
?tipograf wdt:P31 wd:Q5; wdt:P21 ?sesso; wdt:P937 ?luogolav; wdt:P2031 ?st; wdt:P2032 ?en; wdt:P106 ?activity .
values ?activity { 
    wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196
  }
  
?luogolav wdt:P625 ?coord; wdt:P17 wd:Q38. 
 ?luogolav p:P625 [ psv:P625 ?coo2].
  ?coo2 wikibase:geoLatitude ?lat.
  ?coo2 wikibase:geoLongitude ?long. 
  Bind (YEAR(?st) as ?start)
  Bind (YEAR(?en) as ?end)

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
GROUP BY ?tipograf ?tipografLabel ?sessoLabel ?luogolavLabel ?lat ?long
query per timeline tableau 
#title:query per timeline
#defaultView:Timeline
SELECT DISTINCT ?tipograf ?tipografLabel (MAX (?en) as ?endd) (MIN(?st) as ?startt) ?luogolavLabel WHERE {
?tipograf wdt:P31 wd:Q5; wdt:P21 wd:Q6581072; wdt:P937 ?luogolav; wdt:P2031 ?st; wdt:P2032 ?en; wdt:P106 ?activity .
values ?activity { 
    wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196
  }
  
?luogolav wdt:P17 wd:Q38. 

  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
GROUP BY ?tipograf ?tipografLabel ?luogolavLabel
query per timeline 
#title:possibili date di attività importate come date di nascita/morte
SELECT ?tipo ?tipoLabel ?tipoDescription ?dn ?dm ?ntimeprecision WHERE {
  ?tipo wdt:P106 ?v.
  VALUES ?v { wd:Q175151 wd:Q1229025 wd:Q998550 wd:Q2516866 wd:Q40881196 }
  ?tipo wdt:P569 ?dn; wdt:P570 ?dm.  FILTER(((YEAR(?dm)) - (YEAR(?dn))) < 20 )  
  ?tipo (p:P569/psv:P569) ?ntimenode.  ?ntimenode wikibase:timePrecision ?ntimeprecision.  FILTER(?ntimeprecision = 9 )
  ?tipo (wdt:P569|wdt:P2031) ?inizio.  FILTER((YEAR(?inizio)) > 1400 )
  ?tipo (wdt:P570|wdt:P2032) ?fine.  FILTER((YEAR(?fine)) < 1700 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
}
possibili date di attività importate come date di nascita/morte

1lib1ref edit 

#title:italofoni con DBI e data di nascita e morte senza riferiment
SELECT ?item ?itemLabel ?datan ?datam{
  ?item wdt:P1986 ?dbi .
  ?item wdt:P1412 wd:Q652 .
  ?item wdt:P214 ?viaf .
  ?item wdt:P569 ?datan .
  ?item wdt:P570 ?datam. 
  ?item p:P569 ?dn .
  ?item p:P570 ?dm .
  MINUS { ?dm prov:wasDerivedFrom ?refm . }
  MINUS { ?dn prov:wasDerivedFrom ?refn . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
italofoni con DBI e data di nascita e morte senza riferiment 
#title:umani nati e morti in Italia con DBI id, senza VIAF, senza fonte per P570, morti prima del 1861
SELECT ?human ?humanLabel ?datan ?datam ?luogomLabel (URI(CONCAT("https://www.treccani.it/enciclopedia/",?idDBI,"_(Dizionario-Biografico)")) as ?idDBIurl) WHERE {
  ?human wdt:P569 ?datan;   wdt:P570 ?datam;   wdt:P19 ?luogon;   wdt:P20 ?luogom.
  ?luogon wdt:P17 wd:Q38.
  ?luogom wdt:P17 wd:Q38.
  ?human wdt:P1986 ?idDBI .
  ?human p:P570 ?dm.
  MINUS { ?human wdt:P214 ?viaf. }
  MINUS { ?dm prov:wasDerivedFrom ?refm. }
  FILTER("1861-01-01"^^xsd:dateTime < ?datam)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
umani nati e morti in Italia con DBI id, senza VIAF, senza fonte per P570, morti prima del 1861 
#title:vere fonti (esclusione di wikipedia)
SELECT ?human ?humanLabel ?datan ?refn{
  ?human wdt:P31 wd:Q5 .
  ?human wdt:P1986 ?dbi .
  ?human wdt:P569 ?datan .
  ?human p:P569 ?dn .
  ?dn prov:wasDerivedFrom ?ref . 
  { ?ref pr:P143 ?wp . } UNION { ?ref pr:P4656 ?urlwp . }
  MINUS { ?dn prov:wasDerivedFrom ?truerefsource . ?truerefsource pr:P248 ?source . }
  MINUS { ?dn prov:wasDerivedFrom ?truerefurl . ?truerefurl pr:P854 ?url . }
  FILTER ("1800-01-01"^^xsd:dateTime < ?datan)    
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
vere fonti (esclusione di wikipedia) 
#title:Statements referenced only from Wikimedia projects [NOT REALLY WORKING]
SELECT ?item (COUNT(?ref2) AS ?n)
WHERE {
  ?item wdt:P1986 ?dbi; wdt:P396 ?sbn ; p:P19 ?st .
  ?st prov:wasDerivedFrom ?ref, ?ref2 . ?ref2 pr:P143 [] .
}
GROUP BY ?item
HAVING(?n = 1)
Statements referenced only from Wikimedia projects [NOT REALLY WORKING] 
#title:P19 referenced only from a Wikimedia project [NOT REALLY WORKING]
SELECT ?item (COUNT(DISTINCT ?st) AS ?nst) (COUNT(DISTINCT ?ref) AS ?nref) #conteggio di statements e fonti
WHERE
{
  ?item wdt:P1986 ?dbi; wdt:P396 ?sbn; p:P19 ?st.
  ?st prov:wasDerivedFrom ?ref.
  ?ref pr:P143 []. #importato da qualsiasi progetto wiki
  }
GROUP BY ?item
HAVING(?nref=1) #con una sola fonte
P19 referenced only from a Wikimedia project [NOT REALLY WORKING] 
#title:Only one birth date referenced only from a Wikimedia project
SELECT ?item (COUNT(DISTINCT ?st) AS ?nst)
WHERE
{
  hint:Query hint:optimizer "None" .
  ?item wdt:P1986 ?dbi; wdt:P396 ?sbn; p:P19 ?st . ?st prov:wasDerivedFrom ?ref . ?ref pr:P143 [] . #importato da qualsiasi progetto wiki
  FILTER NOT EXISTS { ?st prov:wasDerivedFrom ?other . FILTER( ?other != ?ref ) } #dove non esiste altra fonte diversa dalla prima
}
GROUP BY ?item
HAVING(?nst = 1)
Only one birth date referenced only from a Wikimedia project

Anagrafe delle biblioteche italiane edit

Link alla pagina progetto su GWMAB 

#title:Distribuzione biblioteche per tipologia in Italia. layers (lista ridotta)
#defaultView:Map
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?coord ?layer WHERE {
  {?item wdt:P31/wdt:P279* wd:Q7075} .
  ?item wdt:P17 wd:Q38; wdt:P791 ?isil.
  OPTIONAL { ?item wdt:P31 wd:Q7075 . BIND("biblioteche" as ?layer) }
  OPTIONAL { ?item wdt:P31 wd:Q2326815 . BIND("comunali" as ?layer) }
  OPTIONAL { ?item wdt:P31 wd:Q28564 . BIND("pubbliche" as ?layer) }
  OPTIONAL { ?item wdt:P31 wd:Q385994 . BIND("specializzate" as ?layer) } 
  OPTIONAL { ?item wdt:P31 wd:Q105763925 . BIND("conservazione" as ?layer) } .
 OPTIONAL { ?item wdt:P31 wd:Q1622062. BIND("universitarie" as ?layer) } .
   ?item wdt:P625 ?coord 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
}
Distribuzione biblioteche per tipologia in Italia. layers (lista ridotta) 
#title:Distribuzione biblioteche per tipologia in Italia. layers (color coded)
#defaultView:Map{"hide":"?rgb"}
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?coord ?layer ?rgb WHERE {
  {?item wdt:P31/wdt:P279* wd:Q7075} .
  ?item wdt:P17 wd:Q38; wdt:P791 ?isil.
  OPTIONAL { ?item wdt:P31 wd:Q7075 . BIND("biblioteche" as ?layer) BIND("FF0000" as ?rgb) }
  OPTIONAL { ?item wdt:P31 wd:Q2326815 . BIND("comunali" as ?layer) BIND("00CC00" as ?rgb) } .
  OPTIONAL { ?item wdt:P31 wd:Q1076099 . BIND("scolastiche" as ?layer) BIND("FFFF33" as ?rgb) }
  OPTIONAL { ?item wdt:P31 wd:Q28564 . BIND("pubbliche" as ?layer) BIND("B266FF" as ?rgb) }
 OPTIONAL { ?item wdt:P31 wd:Q385994 . BIND("specializzate" as ?layer) BIND("66FFB2" as ?rgb) } 
 OPTIONAL { ?item wdt:P31 wd:Q105763925 . BIND("conservazione" as ?layer) BIND("FF9933" as ?rgb) } .
 OPTIONAL { ?item wdt:P31 wd:Q1622062 . BIND("universitarie" as ?layer) BIND("3333FF" as ?rgb) } .

  BIND(IF(!BOUND(?rgb),"6600CC",?rgb) as ?rgb) # covers cases not dealt with by the OPTIONALs above
   ?item wdt:P625 ?coord 
  FILTER ((xsd:integer(SUBSTR(STR(?item),33))) < 113610669) . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it, en". }
  }
Distribuzione biblioteche per tipologia in Italia. layers (color coded) 
#title: Timeline importazione anagrafe biblioteche (Usando il primo elemento per ogni batch come filtro temporale)
#defaultView:Map
SELECT DISTINCT ?isil ?item ?itemLabel ?itemDescription ?istanzaLabel ?coord ?layer
WHERE {
  ?item wdt:P31/wdt:P279* wd:Q7075; wdt:P31 ?istanza; wdt:P17 wd:Q38; wdt:P791 ?isil .
  Optional {?item wdt:P625 ?coord}
  FILTER ((xsd:integer(SUBSTR(STR(?item),33))) < 113086038) . 
# Maggio 2022 (Q111818703) Marche bibliografiche
# 27/06/2022 (Q112759221) emilia romagna (subset pubbliche - comunali) (366)
# 29/06/2022 (Q112804055) emilia romagna (subset pubbliche - specializzate) (45)
# 01/07/2022 (Q112843713) abruzzo (subset pubbliche - comunali) (109) - calabria (subset pubbliche - comunali) (327)
# 02/07/2022 (Q112862695) puglia (subset pubbliche - comunali) (204) - sicilia (subset pubbliche - comunali) (330)
# 03/07/2022 (Q112872511) sardegna (subset pubbliche - comunali) (368) - molise (subset pubbliche - comunali) (81) - Lazio (subset pubbliche - comunali) (222) - Umbria (subset pubbliche - comunali) (71) - Friuli-Venezia Giulia (subset pubbliche - comunali) (212)
# 04/07/2022 (Q112893597) liguria (subset pubbliche - comunali) (150)
# 05/07/2022 (Q112913965) val d'Aosta (subset pubbliche - comunali) (46) - piemonte (subset pubbliche - comunali) (667)
# 06/07/2022 (Q112940188) lombardia (subset pubbliche - comunali) (1170)
# 14/07/2022 (Q113086038) biblioteche (subset comunali - specializzate - di conservazione) (197) - ecclesiastiche CON ente controllante (subset pubbliche - specializzate - di conservazione - scolastiche) (175) - ecclesiastiche senza ente controllante (subset pubbliche - specializzate - di conservazione - scolastiche) (751)
# 21/07/2022 (Q113169385) universitarie di abruzzoꓹ basilicataꓹ calabriaꓹ campaniaꓹ friuliꓹ lazio e liguria (subset università statali - istituti di istruzione superiore) (397)
# 26/07/2022 (Q113295616) universitarie di moliseꓹ piemonteꓹ sardegnaꓹ siciliaꓹ toscanaꓹ trentino (subset università statali - istituti di istruzione superiore) (191)
# 27/07/2022 (Q113298461) universitarie di pugliaꓹ lombardiaꓹ emilia romagnaꓹ umbria e veneto (subset università statali - istituti di istruzione superiore) (542)
# 28/07/2022 (Q113319229) biblioteche (subset private - specializzate) (549)
# 30/07/2022 (Q113359029) biblioteche (subset enti ecclesiastici - conservazione) - biblioteche italiane (subset scolastiche) (801)
# 01/08/2022 (Q113378261) biblioteche archivi di stato (109)
# 08/08/2022 (Q113468889) biblioteche universitarie (subset università non statali) (31)
# 14/08/2022 (Q113515229) biblioteche italiane (subset enti pubblici - specializzate) (551)
# 15/08/2022 (Q113525881) creazione biblioteche afferenti al ministero della cultura (subset pubbliche - di conservazione - specializzate) (31) - biblioteche afferenti al ministero della cultura (subset pubbliche - di conservazione - specializzate) (64) - biblioteche italiane (subset enti pubblici) (165) - biblioteche ministeriali (subset pubbliche - di conservazione - specializzate) (148)
# 16/08/2022 (Q113535612) biblioteche ministeriali (subset pubbliche - di conservazione - specializzate) (23) - biblioteche (subset enti privati - di conservazione - pubbliche - specializzate) (301)
# 24/08/2022 (Q113610669) biblioteche mancanti poli SBN (430)
  ?istanza rdfs:label ?label . FILTER(LANG(?label) = "it"). BIND(?label AS ?layer)
SERVICE wikibase:label { bd:serviceParam wikibase:language "it,en". }
}
Timeline importazione anagrafe biblioteche (Usando il primo elemento per ogni batch come filtro temporale)

query di controllo edit

Elenco batch di importazione edit

Corsi Wikidata per bibliotecari edit

Elementi da usare come esempio edit

WLM 19 edit

tools edit

query d'essai edit

sparql edit

proprietà/qualificatori interessanti edit

works in progressss edit 

#title:scrittrici senza viaf
SELECT ?human ?humanLabel ?datan ?datam  {
   ?human wdt:P31 wd:Q5; wdt:P106 wd:Q36180; wdt:P27 wd:Q172579; wdt:P21 wd:Q6581072.
       ?human wdt:P569 ?datan;    wdt:P570 ?datam.
MINUS {  ?human wdt:P214 ?viaf . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
scrittrici senza viaf 
#title:cittadini italiani Q38 ma morti prima del 1946 (cercare corrispondenti stati pre-unitari)
SELECT ?human ?humanLabel ?nato ?natoCLabel ?morte ?morteCLabel WHERE {
  ?human wdt:P31 wd:Q5;
         wdt:P27 wd:Q38;
         wdt:P569 ?nato;
         wdt:P19 ?natoC;
         wdt:P570 ?morte;
         wdt:P20 ?morteC;
  FILTER ("1946-06-18"^^xsd:dateTime > ?morte)  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
  }
cittadini italiani Q38 ma morti prima del 1946 (cercare corrispondenti stati pre-unitari) 
#title:cittadini italiani Q38 ma nati prima del 1946, senza P580
SELECT ?human ?humanLabel ?nato ?morte WHERE {
  ?human wdt:P31 wd:Q5;
    wdt:P27 wd:Q38;
    wdt:P569 ?nato;
    wdt:P570 ?morte;
    p:P27 ?statement.
  FILTER NOT EXISTS { ?statement pq:P580 ?datainizio. }
  FILTER("1946-06-18"^^xsd:dateTime > ?nato)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
}
cittadini italiani Q38 ma nati prima del 1946, senza P580 
#title:cittadini italiani Q38 ma nati in una città che al momento della loro nascita e morte faceva parte di un'altro stato (pre-unitario)
SELECT ?human ?humanLabel ?nato ?natoCLabel ?paeseLabel ?inizioPaese ?finePaese?morte ?morteCLabel ?paese2Label ?inizioPaese2 ?finePaese2 WHERE {
  ?human wdt:P31 wd:Q5;
         wdt:P27 wd:Q38;
         wdt:P569 ?nato;
         wdt:P19 ?natoC;
         wdt:P570 ?morte;
         wdt:P20 ?morteC.
  ?natoC p:P17 ?statmt.
         ?statmt ps:P17 ?paese.
         ?statmt pq:P580 ?inizioPaese.
         ?statmt pq:P582 ?finePaese.
  ?morteC p:P17 ?statmt2.
         ?statmt2 ps:P17 ?paese2.
         ?statmt2 pq:P580 ?inizioPaese2.
         ?statmt2 pq:P582 ?finePaese2
  FILTER ("1946-06-18"^^xsd:dateTime > ?morte) 
  FILTER (year(?inizioPaese) < year(?nato) && year(?nato) < year(?finePaese))
  FILTER (year(?inizioPaese2) < year(?morte) && year(?morte) < year(?finePaese2))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
  }
cittadini italiani Q38 ma nati in una città che al momento della loro nascita e morte faceva parte di un'altro stato (pre-unitario)
  • same but optimized(?)
SELECT ?human ?humanLabel ?nato ?natoCLabel ?paeseLabel ?inizioPaese ?finePaese?morte ?morteCLabel ?paese2Label ?inizioPaese2 ?finePaese2 WHERE {
  ?human wdt:P31 wd:Q5;
         wdt:P27 wd:Q38;
         wdt:P569 ?nato;
         wdt:P19 ?natoC;
         wdt:P570 ?morte;
         wdt:P20 ?morteC.
  ?natoC p:P17 [ps:P17 ?paese; pq:P580 ?inizioPaese; pq:P582 ?finePaese].
  ?morteC p:P17 [ps:P17 ?paese2; pq:P580 ?inizioPaese2; pq:P582 ?finePaese2]
  FILTER ("1946-06-18"^^xsd:dateTime > ?morte) 
  FILTER (?inizioPaese < ?nato && ?nato < ?finePaese)
  FILTER (?inizioPaese2 < ?morte && ?morte < ?finePaese2)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it,en". }
  }
Try it!


RDF mapping edit

  • fonti della data di morte con tutti i passaggi da statement a reference al valore

  

SELECT ?item ?itemLabel ?datamorte ?dmstmnt ?dmrefnode ?dmfonteLabel
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P27 wd:Q172579; wdt:P570 ?datamorte.
  ?item p:P570 ?dm.
  ?dmstmnt prov:wasDerivedFrom ?dmrefnode.
  ?dmrefnode pr:P248 ?dmfonte.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!
  • compattato
SELECT ?item ?itemLabel ?datamorte ?dmfonteLabel
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P27 wd:Q172579; wdt:P570 ?datamorte.
  ?item p:P570 [prov:wasDerivedFrom [pr:P248 ?dmfonte]].
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Biografie edit

Dizionario biografico dell'educazione edit

See it in Wikidata Query Service 
#title:elementi con id DBE ma senza fonte per P106
SELECT ?item ?itemLabel ?datam (URI(Concat("http://dbe.editricebibliografica.it/cgi-bin/dbe/Scheda?",?idDBE)) as ?idDBEURL)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P9625 ?idDBE.
  ?item p:P106 ?dm.
   MINUS { ?dm prov:wasDerivedFrom ?dmref.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBE ma senza fonte per P106 
#title:elementi con fonte Url DBE ma senza P248 (fonte dell'affermazione) 
SELECT ?item ?itemLabel ?datanascita(URI(?dnfonte) as ?dnfonteURL)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P27 wd:Q172579; wdt:P569 ?datanascita.
  ?item p:P569 ?dn.
  ?dn prov:wasDerivedFrom ?dnref.
  ?dnref pr:P854 ?dnfonte.
  FILTER(CONTAINS(STR(?dnfonte),"http://dbe.editricebibliografica.it/cgi-bin/dbe/Scheda?")).
  MINUS {?dnref pr:P248 ?dnafferm}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con fonte Url DBE ma senza P248 (fonte dell'affermazione) 
#title:elementi con id DBE ma senza P106 occupazione
SELECT ?item ?itemLabel ?workLabel (URI(Concat("http://dbe.editricebibliografica.it/cgi-bin/dbe/Scheda?",?idDBE)) as ?idDBEURL)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P9625 ?idDBE.
   MINUS { ?item wdt:P106 ?work.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBE ma senza P106 occupazione 
#title:elementi con id DBE ma senza luogo di nascita o morte
SELECT ?item ?itemLabel (URI(CONCAT("http://dbe.editricebibliografica.it/cgi-bin/dbe/Scheda?", ?idDBE)) AS ?idDBEURL) WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P9625 ?idDBE.
  { MINUS { ?item wdt:P19 ?luogon. } }
  UNION
  { MINUS { ?item wdt:P20 ?luogom. } }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBE ma senza luogo di nascita o morte

Dizionario Biografico dei Bibliotecari del XX Sec. edit

See it in Wikidata Query Service 
#title:elementi con id DBBI20 ma senza fonte per l'occupazione
SELECT ?item ?itemLabel ?itemDescription (URI(Concat("https://www.aib.it/aib/editoria/dbbi20/",?idDBBI20)) as ?idDBBI20url)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P8985 ?idDBBI20.
  ?item p:P106 ?occ.
   MINUS { ?occ prov:wasDerivedFrom ?occref.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBBI20 ma senza fonte per l'occupazione 


#title:elementi con id DBBI20 ma senza descrizione
SELECT ?item ?itemLabel ?itemDescription (URI(Concat("https://www.aib.it/aib/editoria/dbbi20/",?idDBBI20)) as ?idDBBI20url)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P8985 ?idDBBI20.
  MINUS {?item schema:description ?itemdesc.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBBI20 ma senza descrizione

Dizionario Biografico degli Italiani edit

See it in Wikidata Query Service 
#title:elementi con url di riferimento treccani nella fonte ma senza fonte dell'affermazione
SELECT ?item ?itemLabel ?datamorte (URI(?dmfonte) as ?dmfonteURL)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P27 wd:Q172579; wdt:P570 ?datamorte.
  ?item p:P570 ?dm.
  ?dm prov:wasDerivedFrom ?dmref.
  ?dmref pr:P854 ?dmfonte.
  FILTER(CONTAINS(STR(?dmfonte),"http://www.treccani.it/enciclopedia/")).
  MINUS {?dmref pr:P248 ?dmafferm}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con url di riferimento treccani nella fonte ma senza fonte dell'affermazione 
#title:elementi con id DBI ma senza luogo di nascita o morte
SELECT ?item ?itemLabel (URI(CONCAT("https://www.treccani.it/enciclopedia/", ?idDBI, "_(Dizionario-Biografico)")) AS ?idDBIURL) WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P1986 ?idDBI.
  { MINUS { ?item wdt:P19 ?luogon. } }
  UNION
  { MINUS { ?item wdt:P20 ?luogom. } }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBI ma senza luogo di nascita o morte 
#title:elementi con id DBI ma senza fonte per il X
SELECT ?item ?itemLabel (URI(Concat("https://www.treccani.it/enciclopedia/",?idDBI,"_(Dizionario-Biografico)")) as ?idDBIURL)
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P1986 ?idDBI.
  ?item p:P106 ?dm.
   MINUS { ?dm prov:wasDerivedFrom ?dmref.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
elementi con id DBI ma senza fonte per il X


Periodici edit

Bollettino dell'archiginnasio edit

See it in Wikidata Query Service 


#title:Completamento minimo schede autori bollettino archiginnasio
SELECT Distinct ?autore ?autoreLabel ?autoreDescription ?lnLabel ?dn ?lmLabel ?dm
WHERE 
{
  ?article wdt:P1433 wd:Q27715489; wdt:P50 ?autore.
  OPTIONAL {?autore wdt:P569 ?dn}
  OPTIONAL {?autore wdt:P570 ?dm}
  OPTIONAL {?autore wdt:P19 ?ln}
  OPTIONAL {?autore wdt:P20 ?lm}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Completamento minimo schede autori bollettino archiginnasio 
#title:Check autori con viaf
SELECT Distinct ?autore ?autoreLabel ?autoreDescription ?dn ?dm
WHERE 
{
  ?article wdt:P1433 wd:Q27715489; wdt:P50 ?autore.
  ?autore wdt:P214 ?viaf
  Minus {?autore wdt:P569 ?dn}
  Minus {?autore wdt:P570 ?dm}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Check autori con viaf 
#title:Numero di articoli pubblicati nel bollettino dell'Archiginnasio per autore
SELECT ?autoreLabel (COUNT(?autore) AS ?count)
WHERE 
{
  ?item wdt:P1433 wd:Q27715489; wdt:P50 ?autore; wdt:P577 ?anno . 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
}
GROUP BY ?autoreLabel
ORDER BY DESC(?count)
Numero di articoli pubblicati nel bollettino dell'Archiginnasio per autore 
#title:Articoli pubblicati nel bollettino dell'Archiginnasio
SELECT ?item ?itemLabel ?titolo ?autoreLabel ?linguaLabel ?anno ?volume ?numero ?pagina 
WHERE {  ?item wdt:P1433 wd:Q27715489.
  OPTIONAL { ?item wdt:P50 ?autore }
  OPTIONAL { ?item wdt:P1476 ?titolo }
  OPTIONAL { ?item wdt:P577 ?anno }
  OPTIONAL { ?item wdt:P478 ?volume }
  OPTIONAL { ?item wdt:P433 ?numero }
  OPTIONAL { ?item wdt:P304 ?pagina }
  OPTIONAL { ?item wdt:P407 ?lingua }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it" . }
}
Articoli pubblicati nel bollettino dell'Archiginnasio 
#title:Provenienza autori bollettino
#defaultView:Map
SELECT Distinct ?autore ?autoreLabel ?placebLabel ?coord
WHERE 
{
  ?article wdt:P1433 wd:Q27715489; wdt:P50 ?autore.
  ?autore wdt:P19 ?placeb.
  ?placeb wdt:P625 ?coord.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Provenienza autori bollettino

Archivio Storico Pratese edit 

#title:Articoli pubblicati nell'Archivio Storico Pratese
SELECT ?item ?itemLabel ?titolo ?autoreLabel ?linguaLabel ?anno ?volume ?numero ?pagina ?numeropagine 
WHERE {  ?item wdt:P1433 wd:Q109908428.
  OPTIONAL { ?item wdt:P50 ?autore }
  OPTIONAL { ?item wdt:P1476 ?titolo }
  OPTIONAL { ?item wdt:P577 ?anno }
  OPTIONAL { ?item wdt:P478 ?volume }
  OPTIONAL { ?item wdt:P433 ?numero }
  OPTIONAL { ?item wdt:P304 ?pagina }
  OPTIONAL { ?item wdt:P1104 ?numeropagine }
  OPTIONAL { ?item wdt:P407 ?lingua }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "it" . }
}
Articoli pubblicati nell'Archivio Storico Pratese

Professioni edit 

#title:elementi con "bibliotecario" nella descrizione ma senza relativa P106
SELECT ?item ?itemLabel ?itemdesc WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P27 wd:Q172579;
    schema:description ?itemdesc.
  FILTER((LANG(?itemdesc)) = "it")
  FILTER(CONTAINS(STR(?itemdesc), "bibliotecario"))
  MINUS { ?item wdt:P106 wd:Q182436. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
elementi con "bibliotecario" nella descrizione ma senza relativa P106 
#title:elementi descritto come "scrittore" e con id SBN  ma senza relativa P106
SELECT ?item ?itemLabel ?itemdesc WHERE {
  ?item wdt:P31 wd:Q5; wdt:P396 ?SBNid; schema:description ?itemdesc.
  FILTER((LANG(?itemdesc)) = "it")
  FILTER(CONTAINS(STR(?itemdesc), "scrittore"))
  MINUS { ?item (wdt:P106/(wdt:P279*)) wd:Q36180. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],it". }
}
elementi descritto come "scrittore" e con id SBN ma senza relativa P106


Prove edit 

#title: distribuzione fonti per statement occupazione scrittore del regno
SELECT ?fonteoccLabel (COUNT(?item) AS ?count) WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P27 wd:Q172579;
    wdt:P106 wd:Q36180.
?item p:P106 ?statement.
?statement prov:wasDerivedFrom ?ref.
  ?ref pr:P248 ?fonteocc.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?fonteoccLabel
distribuzione fonti per statement occupazione scrittore del regno 
#title: distribuzione fonti per statement occupazione scrittore del regno raggruppate per occupazione
SELECT ?occupazioneLabel ?fonteoccLabel (COUNT(?item) AS ?count) WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P27 wd:Q172579;
    wdt:P106 ?occupazione;
    p:P106 ?statement.
  ?statement prov:wasDerivedFrom ?ref.
  ?ref pr:P248 ?fonteocc.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?occupazioneLabel ?fonteoccLabel
distribuzione fonti per statement occupazione scrittore del regno raggruppate per occupazione 
#title:Professori universitari con datore di lavoro ma senza luogo di lavoro
SELECT ?item ?itemLabel ?datorelavLabel ?luogoLabel ?coord
WHERE 
{
  ?item wdt:P31 wd:Q5; wdt:P27 wd:Q38; wdt:P106 wd:Q1622272; wdt:P108 ?datorelav.
  ?datorelav wdt:P131 ?luogo.
  ?luogo wdt:P625 ?coord.
  MINUS {?item wdt:P937 ?luogolav}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
  }
Professori universitari con datore di lavoro ma senza luogo di lavoro 
#title:autori di opere (work) in italiano ma senza occupazione e lingua di scrittura
SELECT ?item ?itemLabel ?autore ?autoreLabel 
WHERE 
{
  ?item wdt:P31 wd:Q47461344; wdt:P407 wd:Q652; wdt:P50 ?autore.
  ?autore wdt:P31 wd:Q5
  MINUS {?autore wdt:P1412 ?lingua}
  MINUS {?autore wdt:P6886 ?linguascrit}
  MINUS {?autore wdt:P106 wd:Q36180}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } 
  }
autori di opere (work) in italiano ma senza occupazione e lingua di scrittura
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Divudi85&oldid=2140905651"