Julia.athen

Babel user information

ru-N	Русский — родной язык этого участника.

en-2	This user has intermediate knowledge of English.

de-1	Dieser Benutzer beherrscht Deutsch auf grundlegendem Niveau.

I'm interested in edit

editing Wikidata in Machine Learning, AI, scientists in these fields
translating documentation,
making DIY for newcomers.

I would happy any comments about my activities hier.

I have edit

Wikidata review in Russian that can be helpful for beginners in Wikidata.

Please If you have any ideas what I can do with this work, please contact me.

SPARQL queries (Bibliographic data) edit

1. Get scholarly works for the authors edit

Get works for Maria A. Mikheyenkova (Q63809637), Victor Konstantinovich Finn (Q4484888), Oleg Anshakov (Q63759170), Dmitry Vinogradov (Q63808847).

SELECT DISTINCT ?date ?work ?workLabel 
WHERE 
{
  VALUES ?authors { wd:Q63809637 wd:Q4484888 wd:Q63759170 wd:Q63808847 }
  ?work wdt:P50 ?authors.
  OPTIONAL {
    ?work wdt:P577 ?date.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?date

Try it!

2. Get topics for the authors edit

Get topics for Maria A. Mikheyenkova (Q63809637), Victor Konstantinovich Finn (Q4484888), Oleg Anshakov (Q63759170), Dmitry Vinogradov (Q63808847).

#defaultView:BubbleChart
SELECT ?topic ?topicLabel (COUNT(?topic) as ?count)
WHERE 
{
  VALUES ?authors { wd:Q63809637 wd:Q4484888 wd:Q63759170 wd:Q63808847 }
  ?work wdt:P50 ?authors.
  ?work wdt:P921 ?topic.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?topic ?topicLabel
ORDER BY DESC (?count)

Try it!

3. Get venues for the authors edit

Get venues for Maria A. Mikheyenkova (Q63809637), Victor Konstantinovich Finn (Q4484888), Oleg Anshakov (Q63759170), Dmitry Vinogradov (Q63808847).

#defaultView:BubbleChart
SELECT ?venue ?venueLabel (COUNT(?venue) as ?count)
WHERE 
{
  VALUES ?authors { wd:Q63809637 wd:Q4484888 wd:Q63759170 wd:Q63808847 }
  ?work wdt:P50 ?authors.
  ?work wdt:P1433 ?venue.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?venue ?venueLabel
ORDER BY DESC (?count)

Try it!

4. Get publishers for the authors edit

#defaultView:BubbleChart
SELECT ?publisher ?publisherLabel (COUNT(?work) as ?works_qtty)
WHERE 
{
  VALUES ?authors { wd:Q63809637 wd:Q4484888 wd:Q63759170 wd:Q63808847 }
  ?work wdt:P50 ?authors.
  ?work wdt:P1433 [wdt:P123 ?publisher].

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?publisher ?publisherLabel
ORDER BY DESC(?works_qtty)

Try it!

5. Get citation statistic by years for the authors edit

#defaultView:BarChart
SELECT  ?year (count(?citing_work) as ?count)
WITH {
  SELECT DISTINCT ?work WHERE {
    VALUES ?authors { wd:Q63809637 wd:Q4484888 wd:Q63759170 wd:Q63808847 }
    ?work wdt:P50 ?authors.
  }
} AS %works
WHERE {
  INCLUDE %works
  ?citing_work wdt:P2860 ?work.
  ?citing_work wdt:P577 ?date.
  BIND(str(YEAR(?date)) AS ?year)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?year 
ORDER BY DESC(?year)

Try it!

6. Count citation for every original work of the author plus cittations of versions edit

SELECT ?original_work ?original_workLabel (COUNT(?citingArticles) AS ?count) (GROUP_CONCAT(DISTINCT ?version_name; separator =", ") as ?versions)
WHERE {
  ?original_work wdt:P50 wd:Q63809637.
  FILTER NOT EXISTS { ?original_work wdt:P31 wd:Q3331189.}
  OPTIONAL{
    
    {?citingArticles wdt:P2860 ?original_work.}   
    UNION {
      ?original_work wdt:P747 ?version.
       OPTIONAL{?version wdt:P1476 ?version_name.}
      OPTIONAL{?citingArticles wdt:P2860  ?version.}
    }
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language
    "[AUTO_LANGUAGE], en". }
}
GROUP BY ?original_work ?original_workLabel
ORDER BY DESC(?count)

Try it!

7. Show information about works of the author edit

#defaultView:Table
SELECT ?work ?date ?workLabel ?info (GROUP_CONCAT(?author_label; separator=", ") AS ?authors)
WHERE {
  ?work wdt:P921 wd:Q4153449. 
  {
    ?work p:P50 ?author_statement.
    ?author_statement ps:P50 ?item_author.
    ?item_author rdfs:label ?item_author_label.
    FILTER(LANG(?item_author_label) = "ru").
    OPTIONAL {?author_statement pq:P1932 ?short_author.}
    BIND(IF(BOUND(?short_author), ?short_author, ?item_author_label) as ?author_label)
  }
  UNION
  { ?work wdt:P2093 ?author_label. }
  
  ?work wdt:P1433 ?journal.
  ?journal wdt:P1476 ?journal_label.
  
  OPTIONAL {?work wdt:P478 ?volume.}
  OPTIONAL {?work wdt:P433 ?issue.}
  OPTIONAL {?work wdt:P304 ?pages.}
  OPTIONAL {?work wdt:P577 ?date.}
  
  BIND(IF(LANG(?journal_label) = "ru", "Т. ", "vol. ") AS ?volume_prefix)
  BIND(IF(LANG(?journal_label) = "ru", "№ ", "No. ") AS ?issue_prefix)
  BIND(IF(LANG(?journal_label) = "ru", "C. ", "pp. ") AS ?pages_prefix)
  
  BIND(COALESCE (CONCAT(", ", str(YEAR(?date)), ", "), "") as ?str_date).
  BIND(COALESCE (CONCAT(?volume_prefix, ?volume, ", "), "") as ?str_volume).
  BIND(COALESCE (CONCAT(?issue_prefix, ?issue, ", "), "") as ?str_issue).
  BIND(COALESCE (CONCAT(?pages_prefix, ?pages, "."), "") as ?str_pages).
  BIND(CONCAT(?journal_label, ?str_date, ?str_volume, ?str_issue, ?str_pages) AS ?info)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ru, en". }  
}
GROUP BY ?work ?date ?workLabel ?info
ORDER BY DESC(?date)

Try it!

8. Number of publications per year for group of the authors edit

#defaultView:BarChart
SELECT ?year ?number_of_works ?author_label WHERE {
  {
    SELECT ?year ?number_of_works ?author ?author_label_
    WHERE {
      {
        SELECT ?author ?year (COUNT(?work) AS ?number_of_works) WHERE {
          hint:Query hint:optimizer "None".
          VALUES ?author {    wd:Q4484888  wd:Q63809637  wd:Q63808847  wd:Q63759170  }
          ?work wdt:P50 ?author .
          ?work wdt:P577 ?publication_date .
          BIND(STR(YEAR(?publication_date)) AS ?year)
        }
        GROUP BY ?author ?year 
      } 
      ?author rdfs:label ?author_label_ .
      FILTER (LANG(?author_label_) = 'en')
    }
  }
  # Represent the author by name and Q identifier
  BIND (CONCAT(?author_label_, " (", SUBSTR(STR(?author), 32), ")") AS ?author_label)
}
ORDER BY ?year

Try it!

9. citation statistic for authors edit

#defaultView:LineChart
SELECT ?year ?number_of_citations ?author_label WHERE {
  {
    SELECT ?year ?number_of_citations ?author ?author_label_
    WHERE {
      {
        SELECT ?author ?year (COUNT(?citing_work) AS ?number_of_citations) WHERE {
          hint:Query hint:optimizer "None".
          VALUES ?author {   wd:Q4484888  wd:Q63809637  wd:Q63808847  wd:Q63759170    }
          ?work wdt:P50 ?author .
          ?work wdt:P577 ?publication_date .
          ?citing_work wdt:P2860 ?work
          BIND(STR(YEAR(?publication_date)) AS ?year)
        }
        GROUP BY ?author ?year 
      } 
      ?author rdfs:label ?author_label_ .
      FILTER (LANG(?author_label_) = 'en')
    }
  }
  # Represent the author by name and Q identifier
  BIND (CONCAT(?author_label_, " (", SUBSTR(STR(?author), 32), ")") AS ?author_label)
}
ORDER BY ?year

Try it!