Kq-hit

Babel user information
de-N Dieser Benutzer spricht Deutsch als Muttersprache. en-4 This user has near native speaker knowledge of English. fi-3 Tämä käyttäjä osaa suomea erinomaisesti. fr-2 Cet utilisateur dispose de connaissances intermédiaires en français. nl-1 Deze gebruiker heeft elementaire kennis van het Nederlands. sv-1 Den här användaren har grundläggande kunskaper i svenska. nb-1 Denne brukeren har grunnleggende kjennskap til norsk bokmål. nn-1 Denne brukaren meistrar nynorsk på eit grunnleggjande nivå. da-1 Denne bruger har grundlæggende kendskab til dansk.
Users by language

LNG

SPARQL queries

Vessels

Items with an IMO number and their labels in Chinese and English

SELECT ?item ?imo ?itemLabelZH ?itemLabelEN  where {
  ?item wdt:P458 ?imo.
  ?item rdfs:label ?itemLabelZH.
  FILTER(LANG(?itemLabelZH) = 'zh').
  OPTIONAL {
    ?item rdfs:label ?itemLabelEN.
    FILTER(LANG(?itemLabelEN) = 'en')
  }
}

Try it!

Ports

Related:

• passenger ship terminal

Items of type port

SELECT ?wpi ?port ?portLabel ?countryLabel (GROUP_CONCAT(DISTINCT ?unlocode;separator=", ") AS ?unlocodes) ?mt (GROUP_CONCAT(DISTINCT ?website;separator=", ") AS ?websites) (GROUP_CONCAT(DISTINCT ?typeLabel;separator=", ") AS ?types) ?coordinates
  WHERE {
    ?port wdt:P31 wd:Q44782 .
    OPTIONAL { ?port wdt:P17 ?country } .
    OPTIONAL { ?port wdt:P7625 ?wpi } .
    #?port rdf:type wdno:P7625 .
    OPTIONAL { ?port wdt:P1937 ?unlocode } .
    OPTIONAL { ?port wdt:P856 ?website } .
    OPTIONAL { ?port wdt:P625 ?coordinates } .
    OPTIONAL { ?port wdt:P1624 ?mt } .
    FILTER NOT EXISTS {
      ?port p:P31 ?instance_of_statement .
      ?instance_of_statement ps:P31 wd:Q44782 .
      ?instance_of_statement ?qualifier ?value .
      ?prop wikibase:qualifier ?qualifier
    }
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,fr".
                           ?port rdfs:label ?portLabel .
                           ?type rdfs:label ?typeLabel .
                           ?country rdfs:label ?countryLabel .
                           }
}
GROUP BY ?wpi ?port ?portLabel ?countryLabel ?coordinates ?mt
ORDER BY ASC(?countryLabel) ASC(?portLabel)

Try it!

World Port Index

Items with a World Port Index Number

SELECT ?wpi ?port ?portLabel (GROUP_CONCAT(DISTINCT ?unlocode;separator=", ") AS ?unlocodes) ?mt (GROUP_CONCAT(DISTINCT ?website;separator=", ") AS ?websites) (GROUP_CONCAT(DISTINCT ?typeLabel;separator=", ") AS ?types) ?coordinates
  WHERE {
    ?port wdt:P7625 ?wpi
    OPTIONAL { ?port wdt:P31 ?type } .
    OPTIONAL { ?port wdt:P7625 ?wpi } .
    OPTIONAL { ?port wdt:P1937 ?unlocode } .
    OPTIONAL { ?port wdt:P856 ?website } .
    OPTIONAL { ?port wdt:P625 ?coordinates } .
    OPTIONAL { ?port wdt:P1624 ?mt } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en,de,fr".
                           ?port rdfs:label ?portLabel .
                           ?type rdfs:label ?typeLabel}
}
GROUP BY ?wpi ?port ?portLabel ?coordinates ?mt
ORDER BY ASC(xsd:integer(?wpi))

Try it!

Port of Shenzhen map

Map of the locations for the port of Shenzhen

#defaultView:Map
SELECT ?part ?partLabel ?coords
WHERE {
  {
    wd:Q1116518 wdt:P527 ?part.
    ?part wdt:P625 ?coords
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Ports in Saudi Arabia

SELECT ?item ?label ?_coords ?_unlocode ?_wpi ?_mt ?_operator ?_water WHERE {
  ?item wdt:P31 wd:Q44782.
  ?item wdt:P17 wd:Q851
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "en" . 
    ?item rdfs:label ?label .
    ?_operatorId rdfs:label ?_operator .
    ?_waterId rdfs:label ?_water .
  }
  
OPTIONAL { ?item wdt:P625 ?_coords. }
OPTIONAL { ?item wdt:P1937 ?_unlocode. }
OPTIONAL { ?item wdt:P7625 ?_wpi. }
OPTIONAL { ?item wdt:P1624 ?_mt. }
OPTIONAL { ?item wdt:P137 ?_operatorId. }
OPTIONAL { ?item wdt:P206 ?_waterId. }
}

Try it!