User:MartinPoulter/queries/memory of the world
Baseline report edit
Initial data collected 16 and 19 February 2024
External links edit
- Links to the old site http://www.unesco.org/new/en/communication-and-information/flagship-project-activities/memory-of-the-world/ are broken.
There is a data table on Commons of basic information that was scraped from this old website in January of 2019. All its URLs are broken.
Data completeness edit
- 2787 Wikidata items have heritage designation (P1435) Memory of the World (Q473858). Of these, all except 21 have start time (P580).
#title:Memory of the World inscriptions known to Wikidata
SELECT ?item ?itemLabel ?itemDescription (YEAR(?date) AS ?year) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858 # Heritage designation: MotW
OPTIONAL{?s pq:P580 ?date} # Start date
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY ?year
- Of these, 2707 lack associated images.
#title:Memory of the World inscriptions without associated images
SELECT ?item ?itemLabel ?itemDescription (YEAR(?date) AS ?year) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858 # Heritage designation: MotW
OPTIONAL{?s pq:P580 ?date} # Start date
MINUS {?item wdt:P18 ?img}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
} GROUP BY ?item ?itemLabel ?itemDescription ?date
ORDER BY ?year
This is an image gallery of the (presently 80) inscriptions that have images:
#defaultView:ImageGrid
#title:Memory of the World inscriptions with associated images
SELECT ?item ?itemLabel ?itemDescription (YEAR(?date) AS ?year) (SAMPLE(?img) AS ?image) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858 # Heritage designation: MotW
OPTIONAL{?s pq:P580 ?date} # Start date
?item wdt:P18 ?img
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
} GROUP BY ?item ?itemLabel ?itemDescription ?date
ORDER BY ?year
- The 2787 items have a total of 6318 labels in 184 different languages.
#title:Labels for Memory of the World inscriptions
SELECT ?langname (COUNT(?item) AS ?count) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858. # Heritage designation: MotW
?item rdfs:label ?label BIND(lang(?label) AS ?langcode)
OPTIONAL { ?language wdt:P218 ?langcode; rdfs:label ?langlabel FILTER(lang(?langlabel) = "en") } # Convert short code to full language name
BIND(COALESCE(?langlabel, ?langcode) AS ?langname)
} GROUP BY ?langname
ORDER BY DESC(?count)
| Language | Labels | Missing label |
|---|---|---|
| Korean | 2468 | 319 |
| English | 1856 | 931 |
| French | 242 | 2545 |
| German | 88 | 2699 |
| Spanish | 69 | 2718 |
| Japanese | 68 | 2719 |
| Dutch | 65 | 2722 |
| Chinese | 53 | 2734 |
| Russian | 51 | 2736 |
| Italian | 49 | 2738 |
| Polish | 40 | 2747 |
| Portuguese | 39 | 2748 |
| Indonesian | 38 | 2749 |
| Esperanto | 34 | 2753 |
| Catalan | 33 | 2752 |
- Of the 2787 items,
- 4 lack a instance of (P31) statement indicating what type of thing they are.
- 333 lack a inception (P571) statement indicating when they were created.
- 338 lack a location of creation (P1071) statement indicating where they were created.
- 293 lack a location (P276) statement indicating their present location.
- 308 lack a language of work or name (P407) statement indicating their original language.
#title:Memory of the World inscriptions without a type statement
SELECT ?item ?itemLabel (YEAR(?date) AS ?year) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858 # Heritage designation: MotW
OPTIONAL{?s pq:P580 ?date} # Start date
MINUS{?item wdt:P31 ?type}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} ORDER BY ?year
#title:Memory of the World inscriptions and their properties
SELECT ?prop ?propLabel ?count ?missing WHERE {
{
SELECT ?prop (COUNT(DISTINCT ?item) AS ?count) (2787 - COUNT(DISTINCT ?item) AS ?missing) WHERE {
hint:Query hint:optimizer "None" .
?item wdt:P1435 wd:Q473858 .
?item ?p ?id .
?prop wikibase:directClaim ?p FILTER(?prop != wd:P1435)
} GROUP BY ?prop
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
} ORDER BY DESC (?count)
This is a summary table with all of the properties had by more than 1000 items:
| property | with statement | without |
|---|---|---|
| instance of (P31) | 2783 | 4 |
| country (P17) | 2773 | 14 |
| collection (P195) | 2502 | 285 |
| location (P276) | 2494 | 293 |
| language of work or name (P407) | 2479 | 308 |
| country of origin (P495) | 2468 | 319 |
| title (P1476) | 2466 | 321 |
| main subject (P921) | 2464 | 323 |
| inception (P571) | 2454 | 333 |
| inventory number (P217) | 2453 | 334 |
| time period (P2348) | 2449 | 338 |
| location of creation (P1071) | 2449 | 338 |
| archives at (P485) | 2448 | 339 |
| collection creator (P6241) | 2442 | 345 |
| online access status (P6954) | 2439 | 348 |
| access restriction status (P7228) | 2438 | 349 |
| width (P2049) | 2186 | 601 |
| length (P2043) | 2174 | 613 |
| thickness (P2610) | 2171 | 616 |
- Memory of the World (Q473858) has labels in 60 languages (Click "All entered languages").
Files edit
Petscan finds 39,086 files on Commons in the category Memory of the World Register, with a depth of 6 (larger depths don't give a result; the tool times out). It's difficult to tell how many of these are images are directly of objects that are part of a MotW inscription: a lot seem to be only tangentially related.
GLAMorgan reports 247,169,844 image views for these images in January 2024. However, a lot of these image views are from flags and emblems such as commons:Flag of Queensland.svg, so the category seems insufficiently precise.
Wikipedia articles edit
- There are a total of 1560 articles about individual inscriptions in 159 languages, including 74 in English and 58 in French.
#title:Wikipedia articles about specific Memory of the World inscriptions
SELECT ?langname (COUNT(?item) AS ?count) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858. # Heritage designation: MotW
?site schema:about ?item ; schema:inLanguage ?langcode. FILTER(CONTAINS(str(?site), ".wikipedia.org/") )
OPTIONAL { ?language wdt:P218 ?langcode; rdfs:label ?langlabel FILTER(lang(?langlabel) = "en") } # Convert short code to full language name
BIND(COALESCE(?langlabel, ?langcode) AS ?langname)
} GROUP BY ?langname
ORDER BY DESC(?count)
| Language | Wikipedia articles |
|---|---|
| English | 74 |
| German | 64 |
| French | 58 |
| Spanish | 54 |
| Russian | 49 |
| Dutch | 48 |
| Italian | 42 |
| Polish | 39 |
| Indonesian | 38 |
| Japanese | 37 |
- There are 115 inscriptions that are the subject of a Wikipedia article. The most-documented is the Magna Carta, with articles in 94 languages.
#title:The most popular Memory of the World inscriptions by number of Wikipedia articles
SELECT ?item ?itemLabel ?itemDescription (COUNT(?site) AS ?count) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858. # Heritage designation: MotW
?site schema:about ?item .
FILTER(CONTAINS(str(?site), ".wikipedia.org/") )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?item ?itemLabel ?itemDescription
ORDER BY DESC(?count)
| Inscription | Description | Articles |
|---|---|---|
| Magna Carta (Q12519) | charter of rights agreed between King John of England and the nobility in 1215 | 94 |
| Rigveda (Q727413) | most ancient Veda of the Hindus | 92 |
| Phoenician script (Q26752) | abjad found in Canaanite and Aramaic inscriptions across the Mediterranean from the 11th–2nd centuries BCE | 89 |
| Declaration of the Rights of Man and of the Citizen (Q169759) | foundational document of the French Revolution | 72 |
| Treaty of Tordesillas (Q180897) | treaty | 62 |
| Bayeux Tapestry (Q187483) | embroidered wall-hanging art depicting the Norman invasion of England | 61 |
| The Wizard of Oz (Q193695) | 1939 movie based on the book by L. Frank Baum & Mass Mason | 51 |
| Tabula Peutingeriana (Q12767) | map of the road network in the Roman Empire | 48 |
| Book of Kells (Q204221) | 8th-century illuminated manuscript Gospel book, held in Trinity College, Dublin | 48 |
| Treaty of Waitangi (Q472802) | treaty signed on 6 February 1840 by representatives of the British Crown and various Māori chiefs from the North Island of New Zealand | 47 |
Wikisource transcriptions edit
- There are a total of 58 Wikisource pages (complete or partial transcriptions) in 27 different languages.
This query gives a count of the Wikisource pages in each language.
#title:Wikisource pages about specific Memory of the World inscriptions
SELECT ?langname (COUNT(?item) AS ?count) WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858. # Heritage designation: MotW
?site schema:about/wdt:P629? ?item ; schema:inLanguage ?langcode. FILTER(CONTAINS(str(?site), ".wikisource.org/") )
OPTIONAL { ?language wdt:P218 ?langcode; rdfs:label ?langlabel FILTER(lang(?langlabel) = "en") } # Convert short code to full language name
BIND(COALESCE(?langlabel, ?langcode) AS ?langname)
} GROUP BY ?langname
ORDER BY DESC(?count)
| Language | Wikisource pages |
|---|---|
| English | 7 |
| Chinese | 6 |
| Japanese | 5 |
| Korean | 5 |
| Spanish | 4 |
This query gives links to each Wikisource transcription, grouped by language.
#title:Wikisource transcriptions of specific Memory of the World inscriptions
SELECT ?langname ?itemLabel ?site WHERE {
?item p:P1435 ?s. ?s ps:P1435 wd:Q473858. # Heritage designation: MotW
?site schema:about/wdt:P629? ?item ; schema:inLanguage ?langcode. FILTER(CONTAINS(str(?site), ".wikisource.org/") )
OPTIONAL { ?language wdt:P218 ?langcode; rdfs:label ?langlabel FILTER(lang(?langlabel) = "en") } # Convert short code to full language name
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
BIND(COALESCE(?langlabel, ?langcode) AS ?langname)
}
ORDER BY ?langname