Wikidata

Mfchris84

Joined 11 October 2013
Mfchris84 is part of Team #DieDatenlaube
Babel user information
de-N Dieser Benutzer spricht Deutsch als Muttersprache.
de-AT-N Dieser Benutzer spricht Österreichisches Deutsch als Muttersprache.
bar-5 Der Benutzer kå Boarisch asó guad wiara Muadersproochler.
nl-3 Deze gebruiker heeft gevorderde kennis van het Nederlands.
en-2 This user has intermediate knowledge of English.
fr-1 Cet utilisateur dispose de connaissances de base en français.
cs-1 Tento uživatel má základní znalosti češtiny.
hr-1 Ovaj suradnik ima osnovno znanje hrvatskog jezika.
sr-1 Овај корисник има основно знање српског језика.
grc-1 Ὅδε ὁ χρώμενος στοιχειώδη γνῶσιν τῆς ἀρχαίας ἑλληνικῆς ἔχει.
This user loves Wikidata.
This user is a member of the WikiProject Books.
This user adds items about citateable works quickly and easily with Zotero.
This user loves OpenRefine.
QuickStatements logoThis user uses QuickStatements.
This user is a property creator on Wikidata. (verify)
Users by language

Queries

edit

Topological map of Austrian railways

edit

Include all ajdacent stations (whether without any qualifier or only connecting service qualifier)

edit 
#defaultView:Map{"hide":["?coord1", "?coord2", "?line", "?rgb", "?coord1lon", "?coord1lat", "?coord2lon", "?coord2lat", "?str", "?stationType"]}
SELECT * WHERE {
  {
  VALUES ?stationType   { wd:Q55488 wd:Q55678 wd:Q4663385 wd:Q65464941 }
  ?comm1 wdt:P31 ?stationType ; 
         wdt:P17 wd:Q40 ;
         wdt:P625 ?coord1 ; wdt:P197 ?comm2.
  OPTIONAL { ?comm1 wdt:P582|wdt:P576 ?endtime1. }
  OPTIONAL { ?comm2 wdt:P582|wdt:P576 ?endtime2. }
  ?comm2 wdt:P625 ?coord2 .
  ?comm1 p:P625 [ ps:P625 [];  psv:P625 [ wikibase:geoLongitude ?coord1lon; wikibase:geoLatitude ?coord1lat; ] ].
  ?comm2 p:P625 [ ps:P625 [];  psv:P625 [ wikibase:geoLongitude ?coord2lon; wikibase:geoLatitude ?coord2lat; ] ].
  BIND(CONCAT('LINESTRING (', STR(?coord1lon), ' ', STR(?coord1lat), ',', STR(?coord2lon), ' ', STR(?coord2lat), ')') AS ?str) .
  BIND(STRDT(?str, geo:wktLiteral) AS ?line).
  BIND( IF(BOUND(?endtime1) || BOUND(?endtime2),"c2c2c2",  "ff0033")as ?rgb) 
  BIND( IF(BOUND(?endtime1) || BOUND(?endtime2),"decomissioned",  "in service")as ?layer) 
  ?comm1 rdfs:label ?comm1Label. FILTER(LANG(?comm1Label)="[AUTO_LANGUAGE]").
  ?comm2 rdfs:label ?comm2Label. FILTER(LANG(?comm2Label)="[AUTO_LANGUAGE]").
   }
}
Try it!

Adjacent Station with obligate connecting line and optional connecting service

edit 
#defaultView:Map{"hide":["?coord1", "?coord2", "?line", "?rgb", "?coord1lon", "?coord1lat", "?coord2lon", "?coord2lat", "?str", "?stationType"]}
SELECT * WHERE {
  {
  VALUES ?stationType   { wd:Q55488 wd:Q55678 wd:Q4663385 wd:Q65464941 }
  ?comm1 wdt:P31 ?stationType ; 
         wdt:P17 wd:Q40 ;
         wdt:P625 ?coord1 ; wdt:P197 ?comm2.
  OPTIONAL { ?comm1 wdt:P582|wdt:P576 ?endtime1. }
  OPTIONAL { ?comm2 wdt:P582|wdt:P576 ?endtime2. }
  ?comm2 wdt:P625 ?coord2 .
  ?comm1 p:P625 [ ps:P625 [];  psv:P625 [ wikibase:geoLongitude ?coord1lon; wikibase:geoLatitude ?coord1lat; ] ].
  ?comm2 p:P625 [ ps:P625 [];  psv:P625 [ wikibase:geoLongitude ?coord2lon; wikibase:geoLatitude ?coord2lat; ] ].
  ?comm1 p:P197 ?adjStmt1. ?adjStmt1 pq:P81 ?conLine1.  OPTIONAL { ?adjStmt1 pq:P1192 ?conService1. }
  BIND(CONCAT('LINESTRING (', STR(?coord1lon), ' ', STR(?coord1lat), ',', STR(?coord2lon), ' ', STR(?coord2lat), ')') AS ?str) .
  BIND(STRDT(?str, geo:wktLiteral) AS ?line).
  BIND( IF(BOUND(?endtime1) || BOUND(?endtime2),"c2c2c2",  "ff0033")as ?rgb) 
  BIND( IF(BOUND(?endtime1) || BOUND(?endtime2),"decomissioned",  "in service")as ?layer) 
  ?comm1 rdfs:label ?comm1Label. FILTER(LANG(?comm1Label)="[AUTO_LANGUAGE]").
  ?comm2 rdfs:label ?comm2Label. FILTER(LANG(?comm2Label)="[AUTO_LANGUAGE]").
   }
}
Try it!

List of all magazine (Q41298) with an article on German Wikipedia displaying ISSN (P236) and ZDB ID (P1042)

edit 
PREFIX schema: <http://schema.org/>

SELECT ?Zeitschrift ?ZeitschriftLabel ?ISSN ?ZDB ?article WHERE {
  ?article schema:about ?Zeitschrift.
  ?article schema:isPartOf <https://de.wikipedia.org/>.
  ?Zeitschrift (wdt:P31/wdt:P279*) wd:Q41298.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
  OPTIONAL { ?Zeitschrift wdt:P236 ?ISSN. }
  OPTIONAL { ?Zeitschrift wdt:P1042 ?ZDB. }
}
Try it!
edit 
#Orte mit HOV-Code und Beziehung zu anderen Normdateien
SELECT DISTINCT ?Orte ?OrteLabel ?HOV_Code ?extId ?extIdLabel ?externe_ID WHERE {
  ?Orte wdt:P7046 ?HOV_Code.
  OPTIONAL {
    ?Orte ?p ?externe_ID.
    ?extId wikibase:directClaim ?p;
      (wdt:P31/(wdt:P279*)) wd:Q18614948.
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?Orte
Try it!
edit 
SELECT DISTINCT ?Ort ?OrtLabel ?GOV ?GND (IRI(CONCAT("http://lobid.org/gnd/search?filter=%2B(type%3ATerritorialCorporateBodyOrAdministrativeUnit)+geographicAreaCode.id%3A%22http%3A%2F%2Fd-nb.info%2Fstandards%2Fvocab%2Fgnd%2Fgeographic-area-code%23XA-AT-3%22&q=",?OrtLabel,"&format=json")) AS ?lobidurl) WHERE {
  hint:Query hint:optimizer "None".
  ?Ort (wdt:P131+) wd:Q42497;
    (wdt:P31/(wdt:P279*)) wd:Q486972;
    wdt:P2503 ?GOV.
  FILTER(NOT EXISTS { ?Ort wdt:P227 ?GND. })
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de". }
}
Try it!

Austrian Newspaper

edit

Query Newspaper on ONB-Labs via SPARQL: ANNO-Sparql@labs.onb.ac.at

Filter on Labels: 

SELECT ?zeitung ?zeitungLabel WHERE {
  ?zeitung (wdt:P31) wd:Q41298.
  ?zeitung ?label "Arbeiterwille"@en.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

PAWS

edit

Run Sparql Queries in PAWS

MWAPI

edit

Kategorien (Eisenbahn)

edit

Abfrage nach den Kategorien auf de.wikipedia fuer ein bestimmtes Item-Set (Eisenbahnen in AT) 

SELECT ?cat ?title WHERE {
   ?Eisenbahn wdt:P31 wd:Q728937.
   ?Eisenbahn wdt:P17 wd:Q40.
   ?wikiLink schema:isPartOf <https://de.wikipedia.org/>;
                      schema:name ?title ;
                      schema:about ?Eisenbahn.
   SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:api "Categories" .
     bd:serviceParam wikibase:endpoint "de.wikipedia.org" .
     bd:serviceParam mwapi:titles ?title .
     #Output  
     ?cat wikibase:apiOutput mwapi:category .
  }

}
  LIMIT 500
Try it!

Gartenlaube

edit

Abfrage nach Gartenlaubeartikel im Zusammenspiel mit einer bestimmten WikisourceKategorie 

SELECT ?GartenlaubeArtikel ?cat ?wikisourcePage ?wikiLink  WHERE {
   ?GartenlaubeArtikel wdt:P1433 wd:Q655617.
   ?wikiLink schema:isPartOf <https://de.wikisource.org/>;
                      schema:name ?wikisourcePage ;
                      schema:about ?GartenlaubeArtikel.
   SERVICE wikibase:mwapi {
     bd:serviceParam wikibase:api "Categories" .
     bd:serviceParam wikibase:endpoint "de.wikisource.org" .
     bd:serviceParam mwapi:titles ?wikisourcePage .
     bd:serviceParam mwapi:clcategories "Kategorie:Gedicht".
     #Output  
     ?cat wikibase:apiOutput mwapi:category.     
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 10
Try it!

Vorlagen

edit

Vorlage:RISM

edit

Abfrage aller Items mit RISM-ID und deWikipedia-Artikel auf deren Wikipedia-Seiten die Vorlage:RISM nicht gesetzt ist. 

SELECT DISTINCT ?item ?deWP ?rism (CONCAT("[[:Template:RISM]]") AS ?VorlageRISM) WHERE {
  {
    SELECT ?item ?deWP ?rism  WHERE {
      ?item wdt:P5504 ?rism.
      ?deWP schema:about ?item;
        schema:isPartOf <https://de.wikipedia.org/>.
        OPTIONAL {
      SERVICE wikibase:mwapi {
     # in
     bd:serviceParam wikibase:endpoint "de.wikipedia.org";
                     wikibase:api "Generator";
                     mwapi:generator "embeddedin";
                     mwapi:geititle "Vorlage:RISM";
                     mwapi:geinamespace "0".
    
     # out
     ?rismItem wikibase:apiOutputItem mwapi:item.

    } 
    }
     
  }
  }
   FILTER(!bound(?rismItem))
}
Try it!

Vorlage:Watzl

edit

Abfrage sucht alle deWiki-Seiten auf denen die Vorlage:Watzl eingebunden ist und gibt die Tabelle mit den entsprechenden Items und einer etwaigen OesterreichWiki ID (P6228) retour. 

SELECT * WHERE {

  SERVICE wikibase:mwapi {
     # in
     bd:serviceParam wikibase:endpoint "de.wikipedia.org";
                     wikibase:api "Generator";
                     mwapi:generator "embeddedin";
                     mwapi:geititle "Vorlage:Watzl";
                     mwapi:geinamespace "0".
    
     # out
     ?member wikibase:apiOutput mwapi:title.
     ?ns wikibase:apiOutput "@ns".
     ?item wikibase:apiOutputItem mwapi:item.

  }
  OPTIONAL { ?item wdt:P6228 ?rwat. }
}
Try it!

Vorlage:AQID

edit 
SELECT * WHERE {

  SERVICE wikibase:mwapi {
     # in
     bd:serviceParam wikibase:endpoint "de.wikisource.org";
                     wikibase:api "Generator";
                     mwapi:generator "embeddedin";
                     mwapi:geititle "Vorlage:aqid";
                     mwapi:geinamespace "102".
    
     # out
     ?embeddingPage wikibase:apiOutput mwapi:title.
     #?ns wikibase:apiOutput "@ns".
     #?item wikibase:apiOutputItem mwapi:item.
     #?snippet wikibase:apiOutput "@snippet".
  }

}
Try it!

DieDatenlaube

edit

User:Mfchris84/DieDatenlaube

covid19

edit
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Mfchris84&oldid=2197647337"