1850 és 1920 között született albán politikusok legalább öt wikilinkkel, de huwiki nélkülEdit

SELECT DISTINCT ?politik ?politikLabel ?politikDescription (COUNT(distinct ?sitelink) AS ?sitelinks) WHERE {
    ?politik wdt:P106 wd:Q82955 .
    ?politik wdt:P27 wd:Q222 .
    ?politik wdt:P569 ?birth .
    OPTIONAL { ?sitelink schema:about ?politik FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER (?birth < "1920-01-01T00:00:00Z"^^xsd:dateTime) .
    FILTER (?birth > "1850-01-01T00:00:00Z"^^xsd:dateTime) .
    FILTER NOT EXISTS { [] schema:about ?politik; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?politik ?politikLabel ?politikDescription
HAVING (?sitelinks > 4)
ORDER BY DESC (?sitelinks)

Try it!

2013 előtt elhunyt albánok legalább öt wikilinkkel, de huwiki nélkülEdit

SELECT DISTINCT ?alban ?albanLabel ?albanDescription (COUNT(distinct ?sitelink) AS ?sitelinks) WHERE {
    { ?alban wdt:P172 wd:Q179248 } UNION { ?alban wdt:P27 wd:Q222 }
    ?alban wdt:P570 ?death .
    OPTIONAL { ?sitelink schema:about ?alban FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER (?death < "2013-01-01T00:00:00Z"^^xsd:dateTime) .
    FILTER NOT EXISTS { [] schema:about ?alban; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?alban ?albanLabel ?albanDescription
HAVING (?sitelinks > 4)
ORDER BY DESC (?sitelinks)

Try it!

Huwikiből hiányzó albán témájú cikkekEdit

SELECT DISTINCT ?alban ?albanLabel ?albanDescription (COUNT(distinct ?sitelink) AS ?sitelinks) WHERE {
    { ?alban wdt:P172 wd:Q179248 } UNION { ?alban wdt:P27 wd:Q222 } UNION { ?alban wdt:P17 wd:Q222 } UNION { ?alban wdt:P495 wd:Q222 }
    OPTIONAL { ?sitelink schema:about ?alban FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") } .
    FILTER NOT EXISTS { [] schema:about ?alban; schema:isPartOf <https://hu.wikipedia.org/> } .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "hu,en" }
}
GROUP BY ?alban ?albanLabel ?albanDescription
HAVING (?sitelinks > 9)
ORDER BY DESC (?sitelinks)

Try it!