Stovariste
Joined 10 January 2015
Hi, I am stovarište – a man of letters.
Babel user information | ||||||||
---|---|---|---|---|---|---|---|---|
| ||||||||
Users by language |
Coding examples adapted from Wiljes, LukasCBossert, and Fingerhuth. Fore more information on NFDI, please check out Wikidata:WikiProject_NFDI. Enjoy!
Wikidata queries edit
maps edit
show a map of NFDI edit
#defaultView:Map
SELECT DISTINCT ?p ?pLabel ?affiliationType ?affiliationTypeLabel ?w ?wLabel ?geoLoc ?geoHead
# ?p:consortium, ?w:institution
WHERE
{
?p wdt:P31 wd:Q98270496 ;
p:P1416 ?statement .
?statement ps:P1416 ?w .
# type of affiliation
OPTIONAL { ?statement pq:P3831 ?affiliationType }
# location of institution
OPTIONAL { ?w wdt:P625 ?geoLoc }
# location of headquarters of institution
OPTIONAL { ?w wdt:P159/wdt:P625 ?geoHead }
# coalesce locations of institution and headquarters
BIND(COALESCE(?geoLoc, ?geoHead) AS ?geoLoc)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]" }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)
show a map of NFDI4Ing edit
#defaultView:Map
SELECT DISTINCT ?p ?pLabel ?affiliationType ?affiliationTypeLabel ?w ?wLabel ?geoLoc ?geoHead
# ?p:NFDI4Ing, ?w:institution
WHERE
{
wd:Q98380344 p:P1416 ?statement .
?p p:P1416 ?statement .
?statement ps:P1416 ?w .
# type of affiliation
OPTIONAL { ?statement pq:P3831 ?affiliationType }
# location of institution
OPTIONAL { ?w wdt:P625 ?geoLoc }
# location of headquarters of institution
OPTIONAL { ?w wdt:P159/wdt:P625 ?geoHead }
# coalesce locations of institution and headquarters
BIND(COALESCE(?geoLoc, ?geoHead) AS ?geoLoc)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]" }
} ORDER BY ASC(?pLabel) ASC(?affiliationTypeLabel) ASC(?wLabel)
test a map of NFDI in NRW edit
#defaultView:Map
SELECT DISTINCT ?p ?pLabel ?affiliationType ?affiliationTypeLabel ?w ?wLabel ?geoLoc ?geoHead
# ?p:consortium, ?w:institution
WHERE
{
?p wdt:P31 wd:Q98270496 ;
p:P1416 ?statement .
?statement ps:P1416 ?w .
# check out NRW only map reading four layers
# ?w (wdt:P131|wdt:P131/wdt:P131|wdt:P131/wdt:P131/wdt:P131|wdt:P131/wdt:P131/wdt:P131/wdt:P131) wd:Q1198
# check out NRW only map reading three layers
?w (wdt:P131|wdt:P131/wdt:P131|wdt:P131/wdt:P131/wdt:P131) wd:Q1198
# check out NRW only map reading two layers (spoiler: Münster is still missing!)
# ?w (wdt:P131|wdt:P131/wdt:P131) wd:Q1198
# check out NRW only map reading one layer (spoiler: Münster is missing!)
#?w wdt:P131 wd:Q1198
# type of affiliation
OPTIONAL { ?statement pq:P3831 ?affiliationType }
# location of institution
OPTIONAL { ?w wdt:P625 ?geoLoc }
# location of headquarters of institution
OPTIONAL { ?w (wdt:P159/wdt:P625) ?geoHead }
# coalesce locations of institution and headquarters
BIND(COALESCE(?geoLoc, ?geoHead) AS ?geoLoc)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]" }
} ORDER BY (?pLabel) (?affiliationTypeLabel) (?wLabel)
graphs edit
show me a graph of NFDI edit
#defaultView:Graph
SELECT ?consortium ?consortiumLabel ("EC0000" AS ?rgb) ?institution ?institutionLabel
# ("EC0000" AS ?rgb): consortium labels are shown in red
WHERE
{
?consortium wdt:P361 wd:Q61658497 .
?consortium wdt:P31 wd:Q98270496 .
OPTIONAL { ?consortium wdt:P1416 ?institution. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]". }
} ORDER BY (?consortiumLabel) (?institutionLabel)
show me a graph of NFDI4Ing edit
#defaultView:Graph
SELECT ?consortium ?consortiumLabel ("EC0000" AS ?rgb) ?w ?wLabel
# ("EC0000" AS ?rgb):consortium label shown in red, ?w:institution
WHERE
{
wd:Q98380344 p:P1416 ?statement .
?consortium p:P1416 ?statement .
?statement ps:P1416 ?w .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]". }
} ORDER BY (?wLabel)
lists edit
show me the list of organzations that are members of NFDI and/or NFDI e.V. edit
#defaultView:Table
SELECT DISTINCT ?w1 ?w1Label ?w ?wLabel ?affiliationTypeLabel ?p ?pLabel
WHERE
{
?w1 wdt:P463 ?w .
{ ?w wdt:P463 wd:Q105757481 . }
UNION {
?p wdt:P31 wd:Q98270496 .
?p p:P1416 ?statement .
?statement ps:P1416 ?w .
OPTIONAL { ?statement pq:P3831 ?affiliationType . }
}
FILTER NOT EXISTS {?w1 wdt:P31 wd:Q5}
SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en" . }
} ORDER BY ASC(?w1Label) ASC(?wLabel)
show me the list of organzations that are members of NFDI4Ing edit
#defaultView:Table
SELECT DISTINCT ?wsingular ?wsingularLabel ?affiliationTypeLabel ?p ?pLabel
WHERE {
wd:Q98380344 wdt:P1416 ?wsingular .
?p wdt:P31 wd:Q98270496 .
?p p:P1416 ?statement .
?statement ps:P1416 ?wsingular .
OPTIONAL { ?statement pq:P3831 ?affiliationType .}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],de,en" . }
}
ORDER BY ASC(?wsingularLabel) ASC(?pLabel)
housekeeping edit
NFDI institutions that lack a geo location edit
#defaultView:Table
SELECT DISTINCT ?p ?pLabel ?affiliationType ?affiliationTypeLabel ?w ?wLabel ?geoLoc ?geoHead
# ?p:consortium, ?w:institution
WHERE
{
?p wdt:P31 wd:Q98270496 ;
p:P1416 ?statement .
?statement ps:P1416 ?w .
# type of affiliation
OPTIONAL { ?statement pq:P3831 ?affiliationType }
# location of institution
OPTIONAL { ?w wdt:P625 ?geoLoc }
# location of headquarters of institution
OPTIONAL { ?w (wdt:P159/wdt:P625) ?geoHead }
FILTER NOT EXISTS { ?w wdt:P625 ?geoLoc }
FILTER NOT EXISTS { ?w (wdt:P159/wdt:P625) ?geoHead }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]" }
} ORDER BY (?pLabel) (?affiliationTypeLabel) (?wLabel)
NFDI institutions (and persons) that are linked as people edit
#defaultView:Table
SELECT DISTINCT ?p ?pLabel ?role ?roleLabel ?w ?wLabel
# ?p:consortium, ?w:person or institution
WHERE
{
?p wdt:P31 wd:Q98270496 ;
p:P710 ?statement .
?statement ps:P710 ?w .
# type of role
OPTIONAL { ?statement pq:P2868 ?role }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]" }
} ORDER BY (?roleLabel) (?pLabel) (?wLabel) # listing first institutions, then persons
NFDI people that lack an ORCID edit
#defaultView:Table
SELECT DISTINCT ?p ?pLabel ?role ?roleLabel ?w ?wLabel ?ORCID
# ?p:consortium, ?w:person
WHERE
{
?p wdt:P31 wd:Q98270496 ;
p:P710 ?statement .
?statement ps:P710 ?w .
# type of role
OPTIONAL { ?statement pq:P2868 ?role }
# ORCID
OPTIONAL { ?w wdt:P496 ?ORCID }
FILTER EXISTS { ?statement pq:P2868 ?role }
FILTER NOT EXISTS { ?w wdt:P496 ?ORCID }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]" }
} ORDER BY (?pLabel) (?roleLabel) (?wLabel)